git.squeep.com Git - akkoma/blob - lib/pleroma/user.ex

   1 defmodule Pleroma.User do
   2   use Ecto.Schema
   3
   4   import Ecto.{Changeset, Query}
   5   alias Pleroma.{Repo, User, Object, Web, Activity, Notification}
   6   alias Comeonin.Pbkdf2
   7   alias Pleroma.Formatter
   8   alias Pleroma.Web.CommonAPI.Utils, as: CommonUtils
   9   alias Pleroma.Web.{OStatus, Websub, OAuth}
  10   alias Pleroma.Web.ActivityPub.{Utils, ActivityPub}
  11
  12   @type t :: %__MODULE__{}
  13
  14   @email_regex ~r/^[a-zA-Z0-9.!#$%&'*+\/=?^_`{|}~-]+@[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?(?:\.[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?)*$/
  15
  16   @strict_local_nickname_regex ~r/^[a-zA-Z\d]+$/
  17   @extended_local_nickname_regex ~r/^[a-zA-Z\d_-]+$/
  18
  19   schema "users" do
  20     field(:bio, :string)
  21     field(:email, :string)
  22     field(:name, :string)
  23     field(:nickname, :string)
  24     field(:password_hash, :string)
  25     field(:password, :string, virtual: true)
  26     field(:password_confirmation, :string, virtual: true)
  27     field(:following, {:array, :string}, default: [])
  28     field(:ap_id, :string)
  29     field(:avatar, :map)
  30     field(:local, :boolean, default: true)
  31     field(:follower_address, :string)
  32     field(:search_distance, :float, virtual: true)
  33     field(:tags, {:array, :string}, default: [])
  34     field(:last_refreshed_at, :naive_datetime)
  35     has_many(:notifications, Notification)
  36     embeds_one(:info, Pleroma.User.Info)
  37
  38     timestamps()
  39   end
  40
  41   def avatar_url(user) do
  42     case user.avatar do
  43       %{"url" => [%{"href" => href} | _]} -> href
  44       _ -> "#{Web.base_url()}/images/avi.png"
  45     end
  46   end
  47
  48   def banner_url(user) do
  49     case user.info.banner do
  50       %{"url" => [%{"href" => href} | _]} -> href
  51       _ -> "#{Web.base_url()}/images/banner.png"
  52     end
  53   end
  54
  55   def profile_url(%User{info: %{source_data: %{"url" => url}}}), do: url
  56   def profile_url(%User{ap_id: ap_id}), do: ap_id
  57   def profile_url(_), do: nil
  58
  59   def ap_id(%User{nickname: nickname}) do
  60     "#{Web.base_url()}/users/#{nickname}"
  61   end
  62
  63   def ap_followers(%User{} = user) do
  64     "#{ap_id(user)}/followers"
  65   end
  66
  67   def follow_changeset(struct, params \\ %{}) do
  68     struct
  69     |> cast(params, [:following])
  70     |> validate_required([:following])
  71   end
  72
  73   def user_info(%User{} = user) do
  74     oneself = if user.local, do: 1, else: 0
  75
  76     %{
  77       following_count: length(user.following) - oneself,
  78       note_count: user.info.note_count,
  79       follower_count: user.info.follower_count,
  80       locked: user.info.locked,
  81       default_scope: user.info.default_scope
  82     }
  83   end
  84
  85   def remote_user_creation(params) do
  86     params =
  87       params
  88       |> Map.put(:info, params[:info] || %{})
  89
  90     info_cng = User.Info.remote_user_creation(%User.Info{}, params[:info])
  91
  92     changes =
  93       %User{}
  94       |> cast(params, [:bio, :name, :ap_id, :nickname, :avatar])
  95       |> validate_required([:name, :ap_id])
  96       |> unique_constraint(:nickname)
  97       |> validate_format(:nickname, @email_regex)
  98       |> validate_length(:bio, max: 5000)
  99       |> validate_length(:name, max: 100)
 100       |> put_change(:local, false)
 101       |> put_embed(:info, info_cng)
 102
 103     if changes.valid? do
 104       case info_cng.changes[:source_data] do
 105         %{"followers" => followers} ->
 106           changes
 107           |> put_change(:follower_address, followers)
 108
 109         _ ->
 110           followers = User.ap_followers(%User{nickname: changes.changes[:nickname]})
 111
 112           changes
 113           |> put_change(:follower_address, followers)
 114       end
 115     else
 116       changes
 117     end
 118   end
 119
 120   def update_changeset(struct, params \\ %{}) do
 121     struct
 122     |> cast(params, [:bio, :name, :avatar])
 123     |> unique_constraint(:nickname)
 124     |> validate_format(:nickname, local_nickname_regex())
 125     |> validate_length(:bio, max: 5000)
 126     |> validate_length(:name, min: 1, max: 100)
 127   end
 128
 129   def upgrade_changeset(struct, params \\ %{}) do
 130     params =
 131       params
 132       |> Map.put(:last_refreshed_at, NaiveDateTime.utc_now())
 133
 134     info_cng =
 135       struct.info
 136       |> User.Info.user_upgrade(params[:info])
 137
 138     struct
 139     |> cast(params, [:bio, :name, :follower_address, :avatar, :last_refreshed_at])
 140     |> unique_constraint(:nickname)
 141     |> validate_format(:nickname, local_nickname_regex())
 142     |> validate_length(:bio, max: 5000)
 143     |> validate_length(:name, max: 100)
 144     |> put_embed(:info, info_cng)
 145   end
 146
 147   def password_update_changeset(struct, params) do
 148     changeset =
 149       struct
 150       |> cast(params, [:password, :password_confirmation])
 151       |> validate_required([:password, :password_confirmation])
 152       |> validate_confirmation(:password)
 153
 154     OAuth.Token.delete_user_tokens(struct)
 155     OAuth.Authorization.delete_user_authorizations(struct)
 156
 157     if changeset.valid? do
 158       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 159
 160       changeset
 161       |> put_change(:password_hash, hashed)
 162     else
 163       changeset
 164     end
 165   end
 166
 167   def reset_password(user, data) do
 168     update_and_set_cache(password_update_changeset(user, data))
 169   end
 170
 171   def register_changeset(struct, params \\ %{}) do
 172     changeset =
 173       struct
 174       |> cast(params, [:bio, :email, :name, :nickname, :password, :password_confirmation])
 175       |> validate_required([:email, :name, :nickname, :password, :password_confirmation])
 176       |> validate_confirmation(:password)
 177       |> unique_constraint(:email)
 178       |> unique_constraint(:nickname)
 179       |> validate_format(:nickname, local_nickname_regex())
 180       |> validate_format(:email, @email_regex)
 181       |> validate_length(:bio, max: 1000)
 182       |> validate_length(:name, min: 1, max: 100)
 183       |> put_change(:info, %Pleroma.User.Info{})
 184
 185     if changeset.valid? do
 186       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 187       ap_id = User.ap_id(%User{nickname: changeset.changes[:nickname]})
 188       followers = User.ap_followers(%User{nickname: changeset.changes[:nickname]})
 189
 190       changeset
 191       |> put_change(:password_hash, hashed)
 192       |> put_change(:ap_id, ap_id)
 193       |> put_change(:following, [followers])
 194       |> put_change(:follower_address, followers)
 195     else
 196       changeset
 197     end
 198   end
 199
 200   def needs_update?(%User{local: true}), do: false
 201
 202   def needs_update?(%User{local: false, last_refreshed_at: nil}), do: true
 203
 204   def needs_update?(%User{local: false} = user) do
 205     NaiveDateTime.diff(NaiveDateTime.utc_now(), user.last_refreshed_at) >= 86400
 206   end
 207
 208   def needs_update?(_), do: true
 209
 210   def maybe_direct_follow(%User{} = follower, %User{local: true, info: %{locked: true}}) do
 211     {:ok, follower}
 212   end
 213
 214   def maybe_direct_follow(%User{} = follower, %User{local: true} = followed) do
 215     follow(follower, followed)
 216   end
 217
 218   def maybe_direct_follow(%User{} = follower, %User{} = followed) do
 219     if not User.ap_enabled?(followed) do
 220       follow(follower, followed)
 221     else
 222       {:ok, follower}
 223     end
 224   end
 225
 226   def maybe_follow(%User{} = follower, %User{info: _info} = followed) do
 227     if not following?(follower, followed) do
 228       follow(follower, followed)
 229     else
 230       {:ok, follower}
 231     end
 232   end
 233
 234   def follow(%User{} = follower, %User{info: info} = followed) do
 235     user_config = Application.get_env(:pleroma, :user)
 236     deny_follow_blocked = Keyword.get(user_config, :deny_follow_blocked)
 237
 238     ap_followers = followed.follower_address
 239
 240     cond do
 241       following?(follower, followed) or info.deactivated ->
 242         {:error, "Could not follow user: #{followed.nickname} is already on your list."}
 243
 244       deny_follow_blocked and blocks?(followed, follower) ->
 245         {:error, "Could not follow user: #{followed.nickname} blocked you."}
 246
 247       true ->
 248         if !followed.local && follower.local && !ap_enabled?(followed) do
 249           Websub.subscribe(follower, followed)
 250         end
 251
 252         following =
 253           [ap_followers | follower.following]
 254           |> Enum.uniq()
 255
 256         follower =
 257           follower
 258           |> follow_changeset(%{following: following})
 259           |> update_and_set_cache
 260
 261         {:ok, _} = update_follower_count(followed)
 262
 263         follower
 264     end
 265   end
 266
 267   def unfollow(%User{} = follower, %User{} = followed) do
 268     ap_followers = followed.follower_address
 269
 270     if following?(follower, followed) and follower.ap_id != followed.ap_id do
 271       following =
 272         follower.following
 273         |> List.delete(ap_followers)
 274
 275       {:ok, follower} =
 276         follower
 277         |> follow_changeset(%{following: following})
 278         |> update_and_set_cache
 279
 280       {:ok, followed} = update_follower_count(followed)
 281
 282       {:ok, follower, Utils.fetch_latest_follow(follower, followed)}
 283     else
 284       {:error, "Not subscribed!"}
 285     end
 286   end
 287
 288   @spec following?(User.t(), User.t()) :: boolean
 289   def following?(%User{} = follower, %User{} = followed) do
 290     Enum.member?(follower.following, followed.follower_address)
 291   end
 292
 293   def locked?(%User{} = user) do
 294     user.info.locked || false
 295   end
 296
 297   def get_by_ap_id(ap_id) do
 298     Repo.get_by(User, ap_id: ap_id)
 299   end
 300
 301   def update_and_set_cache(changeset) do
 302     with {:ok, user} <- Repo.update(changeset) do
 303       Cachex.put(:user_cache, "ap_id:#{user.ap_id}", user)
 304       Cachex.put(:user_cache, "nickname:#{user.nickname}", user)
 305       Cachex.put(:user_cache, "user_info:#{user.id}", user_info(user))
 306       {:ok, user}
 307     else
 308       e -> e
 309     end
 310   end
 311
 312   def invalidate_cache(user) do
 313     Cachex.del(:user_cache, "ap_id:#{user.ap_id}")
 314     Cachex.del(:user_cache, "nickname:#{user.nickname}")
 315     Cachex.del(:user_cache, "user_info:#{user.id}")
 316   end
 317
 318   def get_cached_by_ap_id(ap_id) do
 319     key = "ap_id:#{ap_id}"
 320     Cachex.fetch!(:user_cache, key, fn _ -> get_by_ap_id(ap_id) end)
 321   end
 322
 323   def get_cached_by_nickname(nickname) do
 324     key = "nickname:#{nickname}"
 325     Cachex.fetch!(:user_cache, key, fn _ -> get_or_fetch_by_nickname(nickname) end)
 326   end
 327
 328   def get_by_nickname(nickname) do
 329     Repo.get_by(User, nickname: nickname)
 330   end
 331
 332   def get_by_nickname_or_email(nickname_or_email) do
 333     case user = Repo.get_by(User, nickname: nickname_or_email) do
 334       %User{} -> user
 335       nil -> Repo.get_by(User, email: nickname_or_email)
 336     end
 337   end
 338
 339   def get_cached_user_info(user) do
 340     key = "user_info:#{user.id}"
 341     Cachex.fetch!(:user_cache, key, fn _ -> user_info(user) end)
 342   end
 343
 344   def fetch_by_nickname(nickname) do
 345     ap_try = ActivityPub.make_user_from_nickname(nickname)
 346
 347     case ap_try do
 348       {:ok, user} -> {:ok, user}
 349       _ -> OStatus.make_user(nickname)
 350     end
 351   end
 352
 353   def get_or_fetch_by_nickname(nickname) do
 354     with %User{} = user <- get_by_nickname(nickname) do
 355       user
 356     else
 357       _e ->
 358         with [_nick, _domain] <- String.split(nickname, "@"),
 359              {:ok, user} <- fetch_by_nickname(nickname) do
 360           user
 361         else
 362           _e -> nil
 363         end
 364     end
 365   end
 366
 367   def get_followers_query(%User{id: id, follower_address: follower_address}) do
 368     from(
 369       u in User,
 370       where: fragment("? <@ ?", ^[follower_address], u.following),
 371       where: u.id != ^id
 372     )
 373   end
 374
 375   def get_followers(user) do
 376     q = get_followers_query(user)
 377
 378     {:ok, Repo.all(q)}
 379   end
 380
 381   def get_friends_query(%User{id: id, following: following}) do
 382     from(
 383       u in User,
 384       where: u.follower_address in ^following,
 385       where: u.id != ^id
 386     )
 387   end
 388
 389   def get_friends(user) do
 390     q = get_friends_query(user)
 391
 392     {:ok, Repo.all(q)}
 393   end
 394
 395   def get_follow_requests_query(%User{} = user) do
 396     from(
 397       a in Activity,
 398       where:
 399         fragment(
 400           "? ->> 'type' = 'Follow'",
 401           a.data
 402         ),
 403       where:
 404         fragment(
 405           "? ->> 'state' = 'pending'",
 406           a.data
 407         ),
 408       where:
 409         fragment(
 410           "? @> ?",
 411           a.data,
 412           ^%{"object" => user.ap_id}
 413         )
 414     )
 415   end
 416
 417   def get_follow_requests(%User{} = user) do
 418     q = get_follow_requests_query(user)
 419     reqs = Repo.all(q)
 420
 421     users =
 422       Enum.map(reqs, fn req -> req.actor end)
 423       |> Enum.uniq()
 424       |> Enum.map(fn ap_id -> get_by_ap_id(ap_id) end)
 425       |> Enum.filter(fn u -> !following?(u, user) end)
 426
 427     {:ok, users}
 428   end
 429
 430   def increase_note_count(%User{} = user) do
 431     info_cng = User.Info.add_to_note_count(user.info, 1)
 432
 433     cng =
 434       change(user)
 435       |> put_embed(:info, info_cng)
 436
 437     update_and_set_cache(cng)
 438   end
 439
 440   def decrease_note_count(%User{} = user) do
 441     info_cng = User.Info.add_to_note_count(user.info, -1)
 442
 443     cng =
 444       change(user)
 445       |> put_embed(:info, info_cng)
 446
 447     update_and_set_cache(cng)
 448   end
 449
 450   def update_note_count(%User{} = user) do
 451     note_count_query =
 452       from(
 453         a in Object,
 454         where: fragment("?->>'actor' = ? and ?->>'type' = 'Note'", a.data, ^user.ap_id, a.data),
 455         select: count(a.id)
 456       )
 457
 458     note_count = Repo.one(note_count_query)
 459
 460     info_cng = User.Info.set_note_count(user.info, note_count)
 461
 462     cng =
 463       change(user)
 464       |> put_embed(:info, info_cng)
 465
 466     update_and_set_cache(cng)
 467   end
 468
 469   def update_follower_count(%User{} = user) do
 470     follower_count_query =
 471       from(
 472         u in User,
 473         where: ^user.follower_address in u.following,
 474         where: u.id != ^user.id,
 475         select: count(u.id)
 476       )
 477
 478     follower_count = Repo.one(follower_count_query)
 479
 480     info_cng =
 481       user.info
 482       |> User.Info.set_follower_count(follower_count)
 483
 484     cng =
 485       change(user)
 486       |> put_embed(:info, info_cng)
 487
 488     update_and_set_cache(cng)
 489   end
 490
 491   def get_users_from_set_query(ap_ids, false) do
 492     from(
 493       u in User,
 494       where: u.ap_id in ^ap_ids
 495     )
 496   end
 497
 498   def get_users_from_set_query(ap_ids, true) do
 499     query = get_users_from_set_query(ap_ids, false)
 500
 501     from(
 502       u in query,
 503       where: u.local == true
 504     )
 505   end
 506
 507   def get_users_from_set(ap_ids, local_only \\ true) do
 508     get_users_from_set_query(ap_ids, local_only)
 509     |> Repo.all()
 510   end
 511
 512   def get_recipients_from_activity(%Activity{recipients: to}) do
 513     query =
 514       from(
 515         u in User,
 516         where: u.ap_id in ^to,
 517         or_where: fragment("? && ?", u.following, ^to)
 518       )
 519
 520     query = from(u in query, where: u.local == true)
 521
 522     Repo.all(query)
 523   end
 524
 525   def search(query, resolve \\ false) do
 526     # strip the beginning @ off if there is a query
 527     query = String.trim_leading(query, "@")
 528
 529     if resolve do
 530       User.get_or_fetch_by_nickname(query)
 531     end
 532
 533     inner =
 534       from(
 535         u in User,
 536         select_merge: %{
 537           search_distance:
 538             fragment(
 539               "? <-> (? || ?)",
 540               ^query,
 541               u.nickname,
 542               u.name
 543             )
 544         },
 545         where: not is_nil(u.nickname)
 546       )
 547
 548     q =
 549       from(
 550         s in subquery(inner),
 551         order_by: s.search_distance,
 552         limit: 20
 553       )
 554
 555     Repo.all(q)
 556   end
 557
 558   def block(blocker, %User{ap_id: ap_id} = blocked) do
 559     # sever any follow relationships to prevent leaks per activitypub (Pleroma issue #213)
 560     blocker =
 561       if following?(blocker, blocked) do
 562         {:ok, blocker, _} = unfollow(blocker, blocked)
 563         blocker
 564       else
 565         blocker
 566       end
 567
 568     if following?(blocked, blocker) do
 569       unfollow(blocked, blocker)
 570     end
 571
 572     info_cng =
 573       blocker.info
 574       |> User.Info.add_to_block(ap_id)
 575
 576     cng =
 577       change(blocker)
 578       |> put_embed(:info, info_cng)
 579
 580     update_and_set_cache(cng)
 581   end
 582
 583   # helper to handle the block given only an actor's AP id
 584   def block(blocker, %{ap_id: ap_id}) do
 585     block(blocker, User.get_by_ap_id(ap_id))
 586   end
 587
 588   def unblock(blocker, %{ap_id: ap_id}) do
 589     info_cng =
 590       blocker.info
 591       |> User.Info.remove_from_block(ap_id)
 592
 593     cng =
 594       change(blocker)
 595       |> put_embed(:info, info_cng)
 596
 597     update_and_set_cache(cng)
 598   end
 599
 600   def blocks?(user, %{ap_id: ap_id}) do
 601     blocks = user.info.blocks
 602     domain_blocks = user.info.domain_blocks
 603     %{host: host} = URI.parse(ap_id)
 604
 605     Enum.member?(blocks, ap_id) ||
 606       Enum.any?(domain_blocks, fn domain ->
 607         host == domain
 608       end)
 609   end
 610
 611   def block_domain(user, domain) do
 612     info_cng =
 613       user.info
 614       |> User.Info.add_to_domain_block(domain)
 615
 616     cng =
 617       change(user)
 618       |> put_embed(:info, info_cng)
 619
 620     update_and_set_cache(cng)
 621   end
 622
 623   def unblock_domain(user, domain) do
 624     info_cng =
 625       user.info
 626       |> User.Info.remove_from_domain_block(domain)
 627
 628     cng =
 629       change(user)
 630       |> put_embed(:info, info_cng)
 631
 632     update_and_set_cache(cng)
 633   end
 634
 635   def local_user_query() do
 636     from(
 637       u in User,
 638       where: u.local == true,
 639       where: not is_nil(u.nickname)
 640     )
 641   end
 642
 643   def moderator_user_query() do
 644     from(
 645       u in User,
 646       where: u.local == true,
 647       where: fragment("?->'is_moderator' @> 'true'", u.info)
 648     )
 649   end
 650
 651   def deactivate(%User{} = user, status \\ true) do
 652     info_cng = User.Info.set_activation_status(user.info, status)
 653
 654     cng =
 655       change(user)
 656       |> put_embed(:info, info_cng)
 657
 658     update_and_set_cache(cng)
 659   end
 660
 661   def delete(%User{} = user) do
 662     {:ok, user} = User.deactivate(user)
 663
 664     # Remove all relationships
 665     {:ok, followers} = User.get_followers(user)
 666
 667     followers
 668     |> Enum.each(fn follower -> User.unfollow(follower, user) end)
 669
 670     {:ok, friends} = User.get_friends(user)
 671
 672     friends
 673     |> Enum.each(fn followed -> User.unfollow(user, followed) end)
 674
 675     query = from(a in Activity, where: a.actor == ^user.ap_id)
 676
 677     Repo.all(query)
 678     |> Enum.each(fn activity ->
 679       case activity.data["type"] do
 680         "Create" ->
 681           ActivityPub.delete(Object.normalize(activity.data["object"]))
 682
 683         # TODO: Do something with likes, follows, repeats.
 684         _ ->
 685           "Doing nothing"
 686       end
 687     end)
 688
 689     {:ok, user}
 690   end
 691
 692   def html_filter_policy(%User{info: %{no_rich_text: true}}) do
 693     Pleroma.HTML.Scrubber.TwitterText
 694   end
 695
 696   def html_filter_policy(_), do: nil
 697
 698   def get_or_fetch_by_ap_id(ap_id) do
 699     user = get_by_ap_id(ap_id)
 700
 701     if !is_nil(user) and !User.needs_update?(user) do
 702       user
 703     else
 704       ap_try = ActivityPub.make_user_from_ap_id(ap_id)
 705
 706       case ap_try do
 707         {:ok, user} ->
 708           user
 709
 710         _ ->
 711           case OStatus.make_user(ap_id) do
 712             {:ok, user} -> user
 713             _ -> {:error, "Could not fetch by AP id"}
 714           end
 715       end
 716     end
 717   end
 718
 719   def get_or_create_instance_user do
 720     relay_uri = "#{Pleroma.Web.Endpoint.url()}/relay"
 721
 722     if user = get_by_ap_id(relay_uri) do
 723       user
 724     else
 725       changes =
 726         %User{info: %User.Info{}}
 727         |> cast(%{}, [:ap_id, :nickname, :local])
 728         |> put_change(:ap_id, relay_uri)
 729         |> put_change(:nickname, nil)
 730         |> put_change(:local, true)
 731         |> put_change(:follower_address, relay_uri <> "/followers")
 732
 733       {:ok, user} = Repo.insert(changes)
 734       user
 735     end
 736   end
 737
 738   # AP style
 739   def public_key_from_info(%{
 740         source_data: %{"publicKey" => %{"publicKeyPem" => public_key_pem}}
 741       }) do
 742     key =
 743       public_key_pem
 744       |> :public_key.pem_decode()
 745       |> hd()
 746       |> :public_key.pem_entry_decode()
 747
 748     {:ok, key}
 749   end
 750
 751   # OStatus Magic Key
 752   def public_key_from_info(%{magic_key: magic_key}) do
 753     {:ok, Pleroma.Web.Salmon.decode_key(magic_key)}
 754   end
 755
 756   def get_public_key_for_ap_id(ap_id) do
 757     with %User{} = user <- get_or_fetch_by_ap_id(ap_id),
 758          {:ok, public_key} <- public_key_from_info(user.info) do
 759       {:ok, public_key}
 760     else
 761       _ -> :error
 762     end
 763   end
 764
 765   defp blank?(""), do: nil
 766   defp blank?(n), do: n
 767
 768   def insert_or_update_user(data) do
 769     data =
 770       data
 771       |> Map.put(:name, blank?(data[:name]) || data[:nickname])
 772
 773     cs = User.remote_user_creation(data)
 774
 775     Repo.insert(cs, on_conflict: :replace_all, conflict_target: :nickname)
 776   end
 777
 778   def ap_enabled?(%User{local: true}), do: true
 779   def ap_enabled?(%User{info: info}), do: info.ap_enabled
 780   def ap_enabled?(_), do: false
 781
 782   @doc "Gets or fetch a user by uri or nickname."
 783   @spec get_or_fetch(String.t()) :: User.t()
 784   def get_or_fetch("http" <> _host = uri), do: get_or_fetch_by_ap_id(uri)
 785   def get_or_fetch(nickname), do: get_or_fetch_by_nickname(nickname)
 786
 787   # wait a period of time and return newest version of the User structs
 788   # this is because we have synchronous follow APIs and need to simulate them
 789   # with an async handshake
 790   def wait_and_refresh(_, %User{local: true} = a, %User{local: true} = b) do
 791     with %User{} = a <- Repo.get(User, a.id),
 792          %User{} = b <- Repo.get(User, b.id) do
 793       {:ok, a, b}
 794     else
 795       _e ->
 796         :error
 797     end
 798   end
 799
 800   def wait_and_refresh(timeout, %User{} = a, %User{} = b) do
 801     with :ok <- :timer.sleep(timeout),
 802          %User{} = a <- Repo.get(User, a.id),
 803          %User{} = b <- Repo.get(User, b.id) do
 804       {:ok, a, b}
 805     else
 806       _e ->
 807         :error
 808     end
 809   end
 810
 811   def parse_bio(bio, user \\ %User{info: %{source_data: %{}}})
 812   def parse_bio(nil, _user), do: ""
 813   def parse_bio(bio, _user) when bio == "", do: bio
 814
 815   def parse_bio(bio, user) do
 816     mentions = Formatter.parse_mentions(bio)
 817     tags = Formatter.parse_tags(bio)
 818
 819     emoji =
 820       (user.info.source_data["tag"] || [])
 821       |> Enum.filter(fn %{"type" => t} -> t == "Emoji" end)
 822       |> Enum.map(fn %{"icon" => %{"url" => url}, "name" => name} ->
 823         {String.trim(name, ":"), url}
 824       end)
 825
 826     bio
 827     |> CommonUtils.format_input(mentions, tags, "text/plain")
 828     |> Formatter.emojify(emoji)
 829   end
 830
 831   def tag(user_identifiers, tags) when is_list(user_identifiers) do
 832     Repo.transaction(fn ->
 833       for user_identifier <- user_identifiers, do: tag(user_identifier, tags)
 834     end)
 835   end
 836
 837   def tag(nickname, tags) when is_binary(nickname),
 838     do: tag(User.get_by_nickname(nickname), tags)
 839
 840   def tag(%User{} = user, tags),
 841     do: update_tags(user, Enum.uniq((user.tags || []) ++ normalize_tags(tags)))
 842
 843   def untag(user_identifiers, tags) when is_list(user_identifiers) do
 844     Repo.transaction(fn ->
 845       for user_identifier <- user_identifiers, do: untag(user_identifier, tags)
 846     end)
 847   end
 848
 849   def untag(nickname, tags) when is_binary(nickname),
 850     do: untag(User.get_by_nickname(nickname), tags)
 851
 852   def untag(%User{} = user, tags),
 853     do: update_tags(user, (user.tags || []) -- normalize_tags(tags))
 854
 855   defp update_tags(%User{} = user, new_tags) do
 856     {:ok, updated_user} =
 857       user
 858       |> change(%{tags: new_tags})
 859       |> Repo.update()
 860
 861     updated_user
 862   end
 863
 864   defp normalize_tags(tags) do
 865     [tags]
 866     |> List.flatten()
 867     |> Enum.map(&String.downcase(&1))
 868   end
 869
 870   defp local_nickname_regex() do
 871     if Pleroma.Config.get([:instance, :extended_nickname_format]) do
 872       @extended_local_nickname_regex
 873     else
 874       @strict_local_nickname_regex
 875     end
 876   end
 877 end