git.squeep.com Git - akkoma/blob - lib/pleroma/user/info.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.User.Info do
   6   use Ecto.Schema
   7   import Ecto.Changeset
   8
   9   alias Pleroma.User.Info
  10
  11   @type t :: %__MODULE__{}
  12
  13   embedded_schema do
  14     field(:banner, :map, default: %{})
  15     field(:background, :map, default: %{})
  16     field(:source_data, :map, default: %{})
  17     field(:note_count, :integer, default: 0)
  18     field(:follower_count, :integer, default: 0)
  19     # Should be filled in only for remote users
  20     field(:following_count, :integer, default: nil)
  21     field(:locked, :boolean, default: false)
  22     field(:confirmation_pending, :boolean, default: false)
  23     field(:password_reset_pending, :boolean, default: false)
  24     field(:confirmation_token, :string, default: nil)
  25     field(:default_scope, :string, default: "public")
  26     field(:blocks, {:array, :string}, default: [])
  27     field(:domain_blocks, {:array, :string}, default: [])
  28     field(:mutes, {:array, :string}, default: [])
  29     field(:muted_reblogs, {:array, :string}, default: [])
  30     field(:muted_notifications, {:array, :string}, default: [])
  31     field(:subscribers, {:array, :string}, default: [])
  32     field(:deactivated, :boolean, default: false)
  33     field(:no_rich_text, :boolean, default: false)
  34     field(:ap_enabled, :boolean, default: false)
  35     field(:is_moderator, :boolean, default: false)
  36     field(:is_admin, :boolean, default: false)
  37     field(:show_role, :boolean, default: true)
  38     field(:keys, :string, default: nil)
  39     field(:settings, :map, default: nil)
  40     field(:magic_key, :string, default: nil)
  41     field(:uri, :string, default: nil)
  42     field(:topic, :string, default: nil)
  43     field(:hub, :string, default: nil)
  44     field(:salmon, :string, default: nil)
  45     field(:hide_followers_count, :boolean, default: false)
  46     field(:hide_follows_count, :boolean, default: false)
  47     field(:hide_followers, :boolean, default: false)
  48     field(:hide_follows, :boolean, default: false)
  49     field(:hide_favorites, :boolean, default: true)
  50     field(:pinned_activities, {:array, :string}, default: [])
  51     field(:email_notifications, :map, default: %{"digest" => false})
  52     field(:mascot, :map, default: nil)
  53     field(:emoji, {:array, :map}, default: [])
  54     field(:pleroma_settings_store, :map, default: %{})
  55     field(:fields, {:array, :map}, default: nil)
  56     field(:raw_fields, {:array, :map}, default: [])
  57     field(:discoverable, :boolean, default: false)
  58
  59     field(:notification_settings, :map,
  60       default: %{
  61         "followers" => true,
  62         "follows" => true,
  63         "non_follows" => true,
  64         "non_followers" => true
  65       }
  66     )
  67
  68     field(:skip_thread_containment, :boolean, default: false)
  69
  70     # Found in the wild
  71     # ap_id -> Where is this used?
  72     # bio -> Where is this used?
  73     # avatar -> Where is this used?
  74     # fqn -> Where is this used?
  75     # host -> Where is this used?
  76     # subject _> Where is this used?
  77   end
  78
  79   def set_activation_status(info, deactivated) do
  80     params = %{deactivated: deactivated}
  81
  82     info
  83     |> cast(params, [:deactivated])
  84     |> validate_required([:deactivated])
  85   end
  86
  87   def set_password_reset_pending(info, pending) do
  88     params = %{password_reset_pending: pending}
  89
  90     info
  91     |> cast(params, [:password_reset_pending])
  92     |> validate_required([:password_reset_pending])
  93   end
  94
  95   def update_notification_settings(info, settings) do
  96     settings =
  97       settings
  98       |> Enum.map(fn {k, v} -> {k, v in [true, "true", "True", "1"]} end)
  99       |> Map.new()
 100
 101     notification_settings =
 102       info.notification_settings
 103       |> Map.merge(settings)
 104       |> Map.take(["followers", "follows", "non_follows", "non_followers"])
 105
 106     params = %{notification_settings: notification_settings}
 107
 108     info
 109     |> cast(params, [:notification_settings])
 110     |> validate_required([:notification_settings])
 111   end
 112
 113   @doc """
 114   Update email notifications in the given User.Info struct.
 115
 116   Examples:
 117
 118       iex> update_email_notifications(%Pleroma.User.Info{email_notifications: %{"digest" => false}}, %{"digest" => true})
 119       %Pleroma.User.Info{email_notifications: %{"digest" => true}}
 120
 121   """
 122   @spec update_email_notifications(t(), map()) :: Ecto.Changeset.t()
 123   def update_email_notifications(info, settings) do
 124     email_notifications =
 125       info.email_notifications
 126       |> Map.merge(settings)
 127       |> Map.take(["digest"])
 128
 129     params = %{email_notifications: email_notifications}
 130     fields = [:email_notifications]
 131
 132     info
 133     |> cast(params, fields)
 134     |> validate_required(fields)
 135   end
 136
 137   def add_to_note_count(info, number) do
 138     set_note_count(info, info.note_count + number)
 139   end
 140
 141   def set_note_count(info, number) do
 142     params = %{note_count: Enum.max([0, number])}
 143
 144     info
 145     |> cast(params, [:note_count])
 146     |> validate_required([:note_count])
 147   end
 148
 149   def set_follower_count(info, number) do
 150     params = %{follower_count: Enum.max([0, number])}
 151
 152     info
 153     |> cast(params, [:follower_count])
 154     |> validate_required([:follower_count])
 155   end
 156
 157   def set_mutes(info, mutes) do
 158     params = %{mutes: mutes}
 159
 160     info
 161     |> cast(params, [:mutes])
 162     |> validate_required([:mutes])
 163   end
 164
 165   @spec set_notification_mutes(Changeset.t(), [String.t()], boolean()) :: Changeset.t()
 166   def set_notification_mutes(changeset, muted_notifications, notifications?) do
 167     if notifications? do
 168       put_change(changeset, :muted_notifications, muted_notifications)
 169       |> validate_required([:muted_notifications])
 170     else
 171       changeset
 172     end
 173   end
 174
 175   def set_blocks(info, blocks) do
 176     params = %{blocks: blocks}
 177
 178     info
 179     |> cast(params, [:blocks])
 180     |> validate_required([:blocks])
 181   end
 182
 183   def set_subscribers(info, subscribers) do
 184     params = %{subscribers: subscribers}
 185
 186     info
 187     |> cast(params, [:subscribers])
 188     |> validate_required([:subscribers])
 189   end
 190
 191   @spec add_to_mutes(Info.t(), String.t(), boolean()) :: Changeset.t()
 192   def add_to_mutes(info, muted, notifications?) do
 193     info
 194     |> set_mutes(Enum.uniq([muted | info.mutes]))
 195     |> set_notification_mutes(
 196       Enum.uniq([muted | info.muted_notifications]),
 197       notifications?
 198     )
 199   end
 200
 201   @spec remove_from_mutes(Info.t(), String.t()) :: Changeset.t()
 202   def remove_from_mutes(info, muted) do
 203     info
 204     |> set_mutes(List.delete(info.mutes, muted))
 205     |> set_notification_mutes(List.delete(info.muted_notifications, muted), true)
 206   end
 207
 208   def add_to_block(info, blocked) do
 209     set_blocks(info, Enum.uniq([blocked | info.blocks]))
 210   end
 211
 212   def remove_from_block(info, blocked) do
 213     set_blocks(info, List.delete(info.blocks, blocked))
 214   end
 215
 216   def add_to_subscribers(info, subscribed) do
 217     set_subscribers(info, Enum.uniq([subscribed | info.subscribers]))
 218   end
 219
 220   def remove_from_subscribers(info, subscribed) do
 221     set_subscribers(info, List.delete(info.subscribers, subscribed))
 222   end
 223
 224   def set_domain_blocks(info, domain_blocks) do
 225     params = %{domain_blocks: domain_blocks}
 226
 227     info
 228     |> cast(params, [:domain_blocks])
 229     |> validate_required([:domain_blocks])
 230   end
 231
 232   def add_to_domain_block(info, domain_blocked) do
 233     set_domain_blocks(info, Enum.uniq([domain_blocked | info.domain_blocks]))
 234   end
 235
 236   def remove_from_domain_block(info, domain_blocked) do
 237     set_domain_blocks(info, List.delete(info.domain_blocks, domain_blocked))
 238   end
 239
 240   def set_keys(info, keys) do
 241     params = %{keys: keys}
 242
 243     info
 244     |> cast(params, [:keys])
 245     |> validate_required([:keys])
 246   end
 247
 248   def remote_user_creation(info, params) do
 249     params =
 250       if Map.has_key?(params, :fields) do
 251         Map.put(params, :fields, Enum.map(params[:fields], &truncate_field/1))
 252       else
 253         params
 254       end
 255
 256     info
 257     |> cast(params, [
 258       :ap_enabled,
 259       :source_data,
 260       :banner,
 261       :locked,
 262       :magic_key,
 263       :uri,
 264       :hub,
 265       :topic,
 266       :salmon,
 267       :hide_followers,
 268       :hide_follows,
 269       :hide_followers_count,
 270       :hide_follows_count,
 271       :follower_count,
 272       :fields,
 273       :following_count,
 274       :discoverable
 275     ])
 276     |> validate_fields(true)
 277   end
 278
 279   def user_upgrade(info, params, remote? \\ false) do
 280     info
 281     |> cast(params, [
 282       :ap_enabled,
 283       :source_data,
 284       :banner,
 285       :locked,
 286       :magic_key,
 287       :follower_count,
 288       :following_count,
 289       :hide_follows,
 290       :fields,
 291       :hide_followers,
 292       :discoverable,
 293       :hide_followers_count,
 294       :hide_follows_count
 295     ])
 296     |> validate_fields(remote?)
 297   end
 298
 299   def profile_update(info, params) do
 300     info
 301     |> cast(params, [
 302       :locked,
 303       :no_rich_text,
 304       :default_scope,
 305       :banner,
 306       :hide_follows,
 307       :hide_followers,
 308       :hide_followers_count,
 309       :hide_follows_count,
 310       :hide_favorites,
 311       :background,
 312       :show_role,
 313       :skip_thread_containment,
 314       :fields,
 315       :raw_fields,
 316       :pleroma_settings_store,
 317       :discoverable
 318     ])
 319     |> validate_fields()
 320   end
 321
 322   def validate_fields(changeset, remote? \\ false) do
 323     limit_name = if remote?, do: :max_remote_account_fields, else: :max_account_fields
 324     limit = Pleroma.Config.get([:instance, limit_name], 0)
 325
 326     changeset
 327     |> validate_length(:fields, max: limit)
 328     |> validate_change(:fields, fn :fields, fields ->
 329       if Enum.all?(fields, &valid_field?/1) do
 330         []
 331       else
 332         [fields: "invalid"]
 333       end
 334     end)
 335   end
 336
 337   defp valid_field?(%{"name" => name, "value" => value}) do
 338     name_limit = Pleroma.Config.get([:instance, :account_field_name_length], 255)
 339     value_limit = Pleroma.Config.get([:instance, :account_field_value_length], 255)
 340
 341     is_binary(name) &&
 342       is_binary(value) &&
 343       String.length(name) <= name_limit &&
 344       String.length(value) <= value_limit
 345   end
 346
 347   defp valid_field?(_), do: false
 348
 349   defp truncate_field(%{"name" => name, "value" => value}) do
 350     {name, _chopped} =
 351       String.split_at(name, Pleroma.Config.get([:instance, :account_field_name_length], 255))
 352
 353     {value, _chopped} =
 354       String.split_at(value, Pleroma.Config.get([:instance, :account_field_value_length], 255))
 355
 356     %{"name" => name, "value" => value}
 357   end
 358
 359   @spec confirmation_changeset(Info.t(), keyword()) :: Changeset.t()
 360   def confirmation_changeset(info, opts) do
 361     need_confirmation? = Keyword.get(opts, :need_confirmation)
 362
 363     params =
 364       if need_confirmation? do
 365         %{
 366           confirmation_pending: true,
 367           confirmation_token: :crypto.strong_rand_bytes(32) |> Base.url_encode64()
 368         }
 369       else
 370         %{
 371           confirmation_pending: false,
 372           confirmation_token: nil
 373         }
 374       end
 375
 376     cast(info, params, [:confirmation_pending, :confirmation_token])
 377   end
 378
 379   def mastodon_settings_update(info, settings) do
 380     params = %{settings: settings}
 381
 382     info
 383     |> cast(params, [:settings])
 384     |> validate_required([:settings])
 385   end
 386
 387   def mascot_update(info, url) do
 388     params = %{mascot: url}
 389
 390     info
 391     |> cast(params, [:mascot])
 392     |> validate_required([:mascot])
 393   end
 394
 395   def set_source_data(info, source_data) do
 396     params = %{source_data: source_data}
 397
 398     info
 399     |> cast(params, [:source_data])
 400     |> validate_required([:source_data])
 401   end
 402
 403   def admin_api_update(info, params) do
 404     info
 405     |> cast(params, [
 406       :is_moderator,
 407       :is_admin,
 408       :show_role
 409     ])
 410   end
 411
 412   def add_pinnned_activity(info, %Pleroma.Activity{id: id}) do
 413     if id not in info.pinned_activities do
 414       max_pinned_statuses = Pleroma.Config.get([:instance, :max_pinned_statuses], 0)
 415       params = %{pinned_activities: info.pinned_activities ++ [id]}
 416
 417       info
 418       |> cast(params, [:pinned_activities])
 419       |> validate_length(:pinned_activities,
 420         max: max_pinned_statuses,
 421         message: "You have already pinned the maximum number of statuses"
 422       )
 423     else
 424       change(info)
 425     end
 426   end
 427
 428   def remove_pinnned_activity(info, %Pleroma.Activity{id: id}) do
 429     params = %{pinned_activities: List.delete(info.pinned_activities, id)}
 430
 431     cast(info, params, [:pinned_activities])
 432   end
 433
 434   def roles(%Info{is_moderator: is_moderator, is_admin: is_admin}) do
 435     %{
 436       admin: is_admin,
 437       moderator: is_moderator
 438     }
 439   end
 440
 441   def add_reblog_mute(info, ap_id) do
 442     params = %{muted_reblogs: info.muted_reblogs ++ [ap_id]}
 443
 444     cast(info, params, [:muted_reblogs])
 445   end
 446
 447   def remove_reblog_mute(info, ap_id) do
 448     params = %{muted_reblogs: List.delete(info.muted_reblogs, ap_id)}
 449
 450     cast(info, params, [:muted_reblogs])
 451   end
 452
 453   # ``fields`` is an array of mastodon profile field, containing ``{"name": "…", "value": "…"}``.
 454   # For example: [{"name": "Pronoun", "value": "she/her"}, …]
 455   def fields(%{fields: nil, source_data: %{"attachment" => attachment}}) do
 456     limit = Pleroma.Config.get([:instance, :max_remote_account_fields], 0)
 457
 458     attachment
 459     |> Enum.filter(fn %{"type" => t} -> t == "PropertyValue" end)
 460     |> Enum.map(fn fields -> Map.take(fields, ["name", "value"]) end)
 461     |> Enum.take(limit)
 462   end
 463
 464   def fields(%{fields: nil}), do: []
 465
 466   def fields(%{fields: fields}), do: fields
 467
 468   def follow_information_update(info, params) do
 469     info
 470     |> cast(params, [
 471       :hide_followers,
 472       :hide_follows,
 473       :follower_count,
 474       :following_count,
 475       :hide_followers_count,
 476       :hide_follows_count
 477     ])
 478   end
 479 end