git.squeep.com Git - akkoma/blob - lib/pleroma/user/import.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.User.Import do
   6   use Ecto.Schema
   7
   8   alias Pleroma.User
   9   alias Pleroma.Web.CommonAPI
  10   alias Pleroma.Workers.BackgroundWorker
  11
  12   require Logger
  13
  14   @spec perform(atom(), User.t(), list()) :: :ok | list() | {:error, any()}
  15   def perform(:mutes_import, %User{} = user, identifier) do
  16     with {:ok, %User{} = muted_user} <- User.get_or_fetch(identifier),
  17          {:ok, _} <- User.mute(user, muted_user) do
  18       muted_user
  19     else
  20       error -> handle_error(:mutes_import, identifier, error)
  21     end
  22   end
  23
  24   def perform(:blocks_import, %User{} = blocker, identifier) do
  25     with {:ok, %User{} = blocked} <- User.get_or_fetch(identifier),
  26          {:ok, _block} <- CommonAPI.block(blocker, blocked) do
  27       blocked
  28     else
  29       error -> handle_error(:blocks_import, identifier, error)
  30     end
  31   end
  32
  33   def perform(:follow_import, %User{} = follower, identifier) do
  34     with {:ok, %User{} = followed} <- User.get_or_fetch(identifier),
  35          {:ok, follower, followed} <- User.maybe_direct_follow(follower, followed),
  36          {:ok, _, _, _} <- CommonAPI.follow(follower, followed) do
  37       followed
  38     else
  39       error -> handle_error(:follow_import, identifier, error)
  40     end
  41   end
  42
  43   def perform(_, _, _), do: :ok
  44
  45   defp handle_error(op, user_id, error) do
  46     Logger.debug("#{op} failed for #{user_id} with: #{inspect(error)}")
  47     error
  48   end
  49
  50   defp enqueue_many(op, user, identifiers) do
  51     Enum.map(
  52       identifiers,
  53       fn identifier ->
  54         BackgroundWorker.enqueue(op, %{"user_id" => user.id, "identifier" => identifier})
  55       end
  56     )
  57   end
  58
  59   def blocks_import(%User{} = blocker, [_ | _] = identifiers) do
  60     enqueue_many("blocks_import", blocker, identifiers)
  61   end
  62
  63   def follow_import(%User{} = follower, [_ | _] = identifiers) do
  64     enqueue_many("follow_import", follower, identifiers)
  65   end
  66
  67   def mutes_import(%User{} = user, [_ | _] = identifiers) do
  68     enqueue_many("mutes_import", user, identifiers)
  69   end
  70 end