git.squeep.com Git - akkoma/blob - lib/pleroma/telemetry/logger.ex

   1 defmodule Pleroma.Telemetry.Logger do
   2   @moduledoc "Transforms Pleroma telemetry events to logs"
   3
   4   require Logger
   5
   6   @events [
   7     [:pleroma, :connection_pool, :reclaim, :start],
   8     [:pleroma, :connection_pool, :reclaim, :stop],
   9     [:pleroma, :connection_pool, :provision_failure],
  10     [:pleroma, :connection_pool, :client_death]
  11   ]
  12   def attach do
  13     :telemetry.attach_many("pleroma-logger", @events, &handle_event/4, [])
  14   end
  15
  16   # Passing anonymous functions instead of strings to logger is intentional,
  17   # that way strings won't be concatenated if the message is going to be thrown
  18   # out anyway due to higher log level configured
  19
  20   def handle_event(
  21         [:pleroma, :connection_pool, :reclaim, :start],
  22         _,
  23         %{max_connections: max_connections, reclaim_max: reclaim_max},
  24         _
  25       ) do
  26     Logger.debug(fn ->
  27       "Connection pool is exhausted (reached #{max_connections} connections). Starting idle connection cleanup to reclaim as much as #{
  28         reclaim_max
  29       } connections"
  30     end)
  31   end
  32
  33   def handle_event(
  34         [:pleroma, :connection_pool, :reclaim, :stop],
  35         %{reclaimed_count: 0},
  36         _,
  37         _
  38       ) do
  39     Logger.error(fn ->
  40       "Connection pool failed to reclaim any connections due to all of them being in use. It will have to drop requests for opening connections to new hosts"
  41     end)
  42   end
  43
  44   def handle_event(
  45         [:pleroma, :connection_pool, :reclaim, :stop],
  46         %{reclaimed_count: reclaimed_count},
  47         _,
  48         _
  49       ) do
  50     Logger.debug(fn -> "Connection pool cleaned up #{reclaimed_count} idle connections" end)
  51   end
  52
  53   def handle_event(
  54         [:pleroma, :connection_pool, :provision_failure],
  55         %{opts: [key | _]},
  56         _,
  57         _
  58       ) do
  59     Logger.error(fn ->
  60       "Connection pool had to refuse opening a connection to #{key} due to connection limit exhaustion"
  61     end)
  62   end
  63
  64   def handle_event(
  65         [:pleroma, :connection_pool, :client_death],
  66         %{client_pid: client_pid, reason: reason},
  67         %{key: key},
  68         _
  69       ) do
  70     Logger.warn(fn ->
  71       "Pool worker for #{key}: Client #{inspect(client_pid)} died before releasing the connection with #{
  72         inspect(reason)
  73       }"
  74     end)
  75   end
  76 end