git.squeep.com Git - akkoma/blob - lib/pleroma/pagination.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Pagination do
   6   @moduledoc """
   7   Implements Mastodon-compatible pagination.
   8   """
   9
  10   import Ecto.Query
  11   import Ecto.Changeset
  12
  13   alias Pleroma.Repo
  14
  15   @type type :: :keyset | :offset
  16
  17   @default_limit 20
  18   @max_limit 40
  19   @page_keys ["max_id", "min_id", "limit", "since_id", "order"]
  20
  21   def page_keys, do: @page_keys
  22
  23   @spec fetch_paginated(Ecto.Query.t(), map(), type(), atom() | nil) :: [Ecto.Schema.t()]
  24   def fetch_paginated(query, params, type \\ :keyset, table_binding \\ nil)
  25
  26   def fetch_paginated(query, %{total: true} = params, :keyset, table_binding) do
  27     total = Repo.aggregate(query, :count, :id)
  28
  29     %{
  30       total: total,
  31       items: fetch_paginated(query, Map.drop(params, [:total]), :keyset, table_binding)
  32     }
  33   end
  34
  35   def fetch_paginated(query, params, :keyset, table_binding) do
  36     options = cast_params(params)
  37
  38     query
  39     |> paginate(options, :keyset, table_binding)
  40     |> Repo.all()
  41     |> enforce_order(options)
  42   end
  43
  44   def fetch_paginated(query, %{total: true} = params, :offset, table_binding) do
  45     total =
  46       query
  47       |> Ecto.Query.exclude(:left_join)
  48       |> Repo.aggregate(:count, :id)
  49
  50     %{
  51       total: total,
  52       items: fetch_paginated(query, Map.drop(params, [:total]), :offset, table_binding)
  53     }
  54   end
  55
  56   def fetch_paginated(query, params, :offset, table_binding) do
  57     options = cast_params(params)
  58
  59     query
  60     |> paginate(options, :offset, table_binding)
  61     |> Repo.all()
  62   end
  63
  64   @spec paginate(Ecto.Query.t(), map(), type(), atom() | nil) :: [Ecto.Schema.t()]
  65   def paginate(query, options, method \\ :keyset, table_binding \\ nil)
  66
  67   def paginate(query, options, :keyset, table_binding) do
  68     query
  69     |> restrict(:min_id, options, table_binding)
  70     |> restrict(:since_id, options, table_binding)
  71     |> restrict(:max_id, options, table_binding)
  72     |> restrict(:order, options, table_binding)
  73     |> restrict(:limit, options, table_binding)
  74   end
  75
  76   def paginate(query, options, :offset, table_binding) do
  77     query
  78     |> restrict(:order, options, table_binding)
  79     |> restrict(:offset, options, table_binding)
  80     |> restrict(:limit, options, table_binding)
  81   end
  82
  83   defp cast_params(params) do
  84     param_types = %{
  85       min_id: :string,
  86       since_id: :string,
  87       max_id: :string,
  88       offset: :integer,
  89       limit: :integer,
  90       skip_order: :boolean
  91     }
  92
  93     changeset = cast({%{}, param_types}, params, Map.keys(param_types))
  94     changeset.changes
  95   end
  96
  97   defp restrict(query, :min_id, %{min_id: min_id}, table_binding) do
  98     where(query, [{q, table_position(query, table_binding)}], q.id > ^min_id)
  99   end
 100
 101   defp restrict(query, :since_id, %{since_id: since_id}, table_binding) do
 102     where(query, [{q, table_position(query, table_binding)}], q.id > ^since_id)
 103   end
 104
 105   defp restrict(query, :max_id, %{max_id: max_id}, table_binding) do
 106     where(query, [{q, table_position(query, table_binding)}], q.id < ^max_id)
 107   end
 108
 109   defp restrict(query, :order, %{skip_order: true}, _), do: query
 110
 111   defp restrict(query, :order, %{min_id: _}, table_binding) do
 112     order_by(
 113       query,
 114       [{u, table_position(query, table_binding)}],
 115       fragment("? asc nulls last", u.id)
 116     )
 117   end
 118
 119   defp restrict(query, :order, _options, table_binding) do
 120     order_by(
 121       query,
 122       [{u, table_position(query, table_binding)}],
 123       fragment("? desc nulls last", u.id)
 124     )
 125   end
 126
 127   defp restrict(query, :offset, %{offset: offset}, _table_binding) do
 128     offset(query, ^offset)
 129   end
 130
 131   defp restrict(query, :limit, options, _table_binding) do
 132     limit =
 133       case Map.get(options, :limit, @default_limit) do
 134         limit when limit < @max_limit -> limit
 135         _ -> @max_limit
 136       end
 137
 138     query
 139     |> limit(^limit)
 140   end
 141
 142   defp restrict(query, _, _, _), do: query
 143
 144   defp enforce_order(result, %{min_id: _}) do
 145     result
 146     |> Enum.reverse()
 147   end
 148
 149   defp enforce_order(result, _), do: result
 150
 151   defp table_position(%Ecto.Query{} = query, binding_name) do
 152     Map.get(query.aliases, binding_name, 0)
 153   end
 154
 155   defp table_position(_, _), do: 0
 156 end