git.squeep.com Git - akkoma/blob - lib/pleroma/pagination.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Pagination do
   6   @moduledoc """
   7   Implements Mastodon-compatible pagination.
   8   """
   9
  10   import Ecto.Query
  11   import Ecto.Changeset
  12
  13   alias Pleroma.Repo
  14
  15   @type type :: :keyset | :offset
  16
  17   @default_limit 20
  18   @max_limit 40
  19   @page_keys ["max_id", "min_id", "limit", "since_id", "order"]
  20
  21   def page_keys, do: @page_keys
  22
  23   @spec fetch_paginated(Ecto.Query.t(), map(), type(), atom() | nil) :: [Ecto.Schema.t()]
  24   def fetch_paginated(query, params, type \\ :keyset, table_binding \\ nil)
  25
  26   def fetch_paginated(query, %{"total" => true} = params, :keyset, table_binding) do
  27     total = Repo.aggregate(query, :count, :id)
  28
  29     %{
  30       total: total,
  31       items: fetch_paginated(query, Map.drop(params, ["total"]), :keyset, table_binding)
  32     }
  33   end
  34
  35   def fetch_paginated(query, params, :keyset, table_binding) do
  36     options = cast_params(params)
  37
  38     query
  39     |> paginate(options, :keyset, table_binding)
  40     |> Repo.all()
  41     |> enforce_order(options)
  42   end
  43
  44   def fetch_paginated(query, %{"total" => true} = params, :offset, table_binding) do
  45     total =
  46       query
  47       |> Ecto.Query.exclude(:left_join)
  48       |> Repo.aggregate(:count, :id)
  49
  50     %{
  51       total: total,
  52       items: fetch_paginated(query, Map.drop(params, ["total"]), :offset, table_binding)
  53     }
  54   end
  55
  56   def fetch_paginated(query, params, :offset, table_binding) do
  57     options = cast_params(params)
  58
  59     query
  60     |> paginate(options, :offset, table_binding)
  61     |> Repo.all()
  62   end
  63
  64   @spec paginate(Ecto.Query.t(), map(), type(), atom() | nil) :: [Ecto.Schema.t()]
  65   def paginate(query, options, method \\ :keyset, table_binding \\ nil)
  66
  67   def paginate(query, options, :keyset, table_binding) do
  68     query
  69     |> restrict(:min_id, options, table_binding)
  70     |> restrict(:since_id, options, table_binding)
  71     |> restrict(:max_id, options, table_binding)
  72     |> restrict(:order, options, table_binding)
  73     |> restrict(:limit, options, table_binding)
  74   end
  75
  76   def paginate(query, options, :offset, table_binding) do
  77     query
  78     |> restrict(:order, options, table_binding)
  79     |> restrict(:offset, options, table_binding)
  80     |> restrict(:limit, options, table_binding)
  81   end
  82
  83   defp cast_params(params) do
  84     param_types = %{
  85       min_id: :string,
  86       since_id: :string,
  87       max_id: :string,
  88       offset: :integer,
  89       limit: :integer,
  90       skip_order: :boolean
  91     }
  92
  93     params =
  94       Enum.reduce(params, %{}, fn
  95         {key, _value}, acc when is_atom(key) -> Map.drop(acc, [key])
  96         {key, value}, acc -> Map.put(acc, key, value)
  97       end)
  98
  99     changeset = cast({%{}, param_types}, params, Map.keys(param_types))
 100     changeset.changes
 101   end
 102
 103   defp restrict(query, :min_id, %{min_id: min_id}, table_binding) do
 104     where(query, [{q, table_position(query, table_binding)}], q.id > ^min_id)
 105   end
 106
 107   defp restrict(query, :since_id, %{since_id: since_id}, table_binding) do
 108     where(query, [{q, table_position(query, table_binding)}], q.id > ^since_id)
 109   end
 110
 111   defp restrict(query, :max_id, %{max_id: max_id}, table_binding) do
 112     where(query, [{q, table_position(query, table_binding)}], q.id < ^max_id)
 113   end
 114
 115   defp restrict(query, :order, %{skip_order: true}, _), do: query
 116
 117   defp restrict(query, :order, %{min_id: _}, table_binding) do
 118     order_by(
 119       query,
 120       [{u, table_position(query, table_binding)}],
 121       fragment("? asc nulls last", u.id)
 122     )
 123   end
 124
 125   defp restrict(query, :order, _options, table_binding) do
 126     order_by(
 127       query,
 128       [{u, table_position(query, table_binding)}],
 129       fragment("? desc nulls last", u.id)
 130     )
 131   end
 132
 133   defp restrict(query, :offset, %{offset: offset}, _table_binding) do
 134     offset(query, ^offset)
 135   end
 136
 137   defp restrict(query, :limit, options, _table_binding) do
 138     limit =
 139       case Map.get(options, :limit, @default_limit) do
 140         limit when limit < @max_limit -> limit
 141         _ -> @max_limit
 142       end
 143
 144     query
 145     |> limit(^limit)
 146   end
 147
 148   defp restrict(query, _, _, _), do: query
 149
 150   defp enforce_order(result, %{min_id: _}) do
 151     result
 152     |> Enum.reverse()
 153   end
 154
 155   defp enforce_order(result, _), do: result
 156
 157   defp table_position(%Ecto.Query{} = query, binding_name) do
 158     Map.get(query.aliases, binding_name, 0)
 159   end
 160
 161   defp table_position(_, _), do: 0
 162 end