git.squeep.com Git - akkoma/blob - lib/pleroma/notification.ex

   1 defmodule Pleroma.Notification do
   2   use Ecto.Schema
   3   alias Pleroma.{User, Activity, Notification, Repo}
   4   import Ecto.Query
   5
   6   schema "notifications" do
   7     field :seen, :boolean, default: false
   8     belongs_to :user, Pleroma.User
   9     belongs_to :activity, Pleroma.Activity
  10
  11     timestamps()
  12   end
  13
  14   # TODO: Make generic and unify (see activity_pub.ex)
  15   defp restrict_max(query, %{"max_id" => max_id}) do
  16     from activity in query, where: activity.id < ^max_id
  17   end
  18   defp restrict_max(query, _), do: query
  19
  20   defp restrict_since(query, %{"since_id" => since_id}) do
  21     from activity in query, where: activity.id > ^since_id
  22   end
  23   defp restrict_since(query, _), do: query
  24
  25   def for_user(user, opts \\ %{}) do
  26     query = from n in Notification,
  27       where: n.user_id == ^user.id,
  28       order_by: [desc: n.id],
  29       preload: [:activity],
  30       limit: 20
  31
  32     query = query
  33     |> restrict_since(opts)
  34     |> restrict_max(opts)
  35
  36     Repo.all(query)
  37   end
  38
  39   def get(%{id: user_id} = _user, id) do
  40     query = from n in Notification,
  41       where: n.id == ^id,
  42       preload: [:activity]
  43
  44     notification = Repo.one(query)
  45     case notification do
  46       %{user_id: ^user_id} ->
  47         {:ok, notification}
  48       _ ->
  49         {:error, "Cannot get notification"}
  50     end
  51   end
  52
  53   def clear(user) do
  54     query = from n in Notification,
  55       where: n.user_id == ^user.id
  56
  57     Repo.delete_all(query)
  58   end
  59
  60   def dismiss(%{id: user_id} = _user, id) do
  61     notification = Repo.get(Notification, id)
  62     case notification do
  63       %{user_id: ^user_id} ->
  64         Repo.delete(notification)
  65       _ ->
  66         {:error, "Cannot dismiss notification"}
  67     end
  68   end
  69
  70   def create_notifications(%Activity{id: _, data: %{"to" => _, "type" => type}} = activity) when type in ["Create", "Like", "Announce", "Follow"] do
  71     users = User.get_notified_from_activity(activity)
  72
  73     notifications = Enum.map(users, fn (user) -> create_notification(activity, user) end)
  74     {:ok, notifications}
  75   end
  76   def create_notifications(_), do: {:ok, []}
  77
  78   # TODO move to sql, too.
  79   def create_notification(%Activity{} = activity, %User{} = user) do
  80     unless User.blocks?(user, %{ap_id: activity.data["actor"]}) do
  81       notification = %Notification{user_id: user.id, activity: activity}
  82       {:ok, notification} = Repo.insert(notification)
  83       Pleroma.Web.Streamer.stream("user", notification)
  84       notification
  85     end
  86   end
  87 end
  88