git.squeep.com Git - akkoma/blob - lib/pleroma/mime.ex

   1 defmodule Pleroma.MIME do
   2   @moduledoc """
   3   Returns the mime-type of a binary and optionally a normalized file-name.
   4   """
   5   @default "application/octet-stream"
   6   @read_bytes 31
   7
   8   @spec file_mime_type(String.t()) ::
   9           {:ok, content_type :: String.t(), filename :: String.t()} | {:error, any()} | :error
  10   def file_mime_type(path, filename) do
  11     with {:ok, content_type} <- file_mime_type(path),
  12          filename <- fix_extension(filename, content_type) do
  13       {:ok, content_type, filename}
  14     end
  15   end
  16
  17   @spec file_mime_type(String.t()) :: {:ok, String.t()} | {:error, any()} | :error
  18   def file_mime_type(filename) do
  19     File.open(filename, [:read], fn f ->
  20       check_mime_type(IO.binread(f, @read_bytes))
  21     end)
  22   end
  23
  24   def bin_mime_type(binary, filename) do
  25     with {:ok, content_type} <- bin_mime_type(binary),
  26          filename <- fix_extension(filename, content_type) do
  27       {:ok, content_type, filename}
  28     end
  29   end
  30
  31   @spec bin_mime_type(binary()) :: {:ok, String.t()} | :error
  32   def bin_mime_type(<<head::binary-size(@read_bytes), _::binary>>) do
  33     {:ok, check_mime_type(head)}
  34   end
  35
  36   def mime_type(<<_::binary>>), do: {:ok, @default}
  37
  38   def bin_mime_type(_), do: :error
  39
  40   defp fix_extension(filename, content_type) do
  41     parts = String.split(filename, ".")
  42
  43     new_filename =
  44       if length(parts) > 1 do
  45         Enum.drop(parts, -1) |> Enum.join(".")
  46       else
  47         Enum.join(parts)
  48       end
  49
  50     cond do
  51       content_type == "application/octet-stream" ->
  52         filename
  53
  54       ext = List.first(MIME.extensions(content_type)) ->
  55         new_filename <> "." <> ext
  56
  57       true ->
  58         Enum.join([new_filename, String.split(content_type, "/") |> List.last()], ".")
  59     end
  60   end
  61
  62   defp check_mime_type(<<0x89, 0x50, 0x4E, 0x47, 0x0D, 0x0A, 0x1A, 0x0A, _::binary>>) do
  63     "image/png"
  64   end
  65
  66   defp check_mime_type(<<0x47, 0x49, 0x46, 0x38, _, 0x61, _::binary>>) do
  67     "image/gif"
  68   end
  69
  70   defp check_mime_type(<<0xFF, 0xD8, 0xFF, _::binary>>) do
  71     "image/jpeg"
  72   end
  73
  74   defp check_mime_type(<<0x1A, 0x45, 0xDF, 0xA3, _::binary>>) do
  75     "video/webm"
  76   end
  77
  78   defp check_mime_type(<<0x00, 0x00, 0x00, _, 0x66, 0x74, 0x79, 0x70, _::binary>>) do
  79     "video/mp4"
  80   end
  81
  82   defp check_mime_type(<<0x49, 0x44, 0x33, _::binary>>) do
  83     "audio/mpeg"
  84   end
  85
  86   defp check_mime_type(<<255, 251, _, 68, 0, 0, 0, 0, _::binary>>) do
  87     "audio/mpeg"
  88   end
  89
  90   defp check_mime_type(
  91          <<0x4F, 0x67, 0x67, 0x53, 0x00, 0x02, 0x00, 0x00, _::size(160), 0x80, 0x74, 0x68, 0x65,
  92            0x6F, 0x72, 0x61, _::binary>>
  93        ) do
  94     "video/ogg"
  95   end
  96
  97   defp check_mime_type(<<0x4F, 0x67, 0x67, 0x53, 0x00, 0x02, 0x00, 0x00, _::binary>>) do
  98     "audio/ogg"
  99   end
 100
 101   defp check_mime_type(<<0x52, 0x49, 0x46, 0x46, _::binary>>) do
 102     "audio/wav"
 103   end
 104
 105   defp check_mime_type(_) do
 106     @default
 107   end
 108 end