git.squeep.com Git - akkoma/blob - lib/pleroma/migrators/hashtags_table_migrator.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Migrators.HashtagsTableMigrator do
   6   use GenServer
   7
   8   require Logger
   9
  10   import Ecto.Query
  11
  12   alias __MODULE__.State
  13   alias Pleroma.Config
  14   alias Pleroma.DataMigration
  15   alias Pleroma.Hashtag
  16   alias Pleroma.Object
  17   alias Pleroma.Repo
  18
  19   defdelegate state(), to: State, as: :get
  20   defdelegate put_stat(key, value), to: State, as: :put
  21   defdelegate increment_stat(key, increment), to: State, as: :increment
  22
  23   defdelegate data_migration(), to: DataMigration, as: :populate_hashtags_table
  24
  25   @reg_name {:global, __MODULE__}
  26
  27   def whereis, do: GenServer.whereis(@reg_name)
  28
  29   def start_link(_) do
  30     case whereis() do
  31       nil ->
  32         GenServer.start_link(__MODULE__, nil, name: @reg_name)
  33
  34       pid ->
  35         {:ok, pid}
  36     end
  37   end
  38
  39   @impl true
  40   def init(_) do
  41     {:ok, nil, {:continue, :init_state}}
  42   end
  43
  44   @impl true
  45   def handle_continue(:init_state, _state) do
  46     {:ok, _} = State.start_link(nil)
  47
  48     update_status(:init)
  49
  50     data_migration = data_migration()
  51     manual_migrations = Config.get([:instance, :manual_data_migrations], [])
  52
  53     cond do
  54       Config.get(:env) == :test ->
  55         update_status(:noop)
  56
  57       is_nil(data_migration) ->
  58         update_status(:halt, "Data migration does not exist.")
  59
  60       data_migration.state == :manual or data_migration.name in manual_migrations ->
  61         update_status(:noop, "Data migration is in manual execution state.")
  62
  63       data_migration.state == :complete ->
  64         handle_success(data_migration)
  65
  66       true ->
  67         send(self(), :migrate_hashtags)
  68     end
  69
  70     {:noreply, nil}
  71   end
  72
  73   @impl true
  74   def handle_info(:migrate_hashtags, state) do
  75     data_migration = data_migration()
  76
  77     persistent_data = Map.take(data_migration.data, ["max_processed_id"])
  78
  79     {:ok, data_migration} =
  80       DataMigration.update(data_migration, %{state: :running, data: persistent_data})
  81
  82     update_status(:running)
  83
  84     Logger.info("Starting transferring object embedded hashtags to `hashtags` table...")
  85
  86     max_processed_id = data_migration.data["max_processed_id"] || 0
  87
  88     # Note: most objects have Mention-type AS2 tags and no hashtags (but we can't filter them out)
  89     from(
  90       object in Object,
  91       left_join: hashtag in assoc(object, :hashtags),
  92       where: object.id > ^max_processed_id,
  93       where: is_nil(hashtag.id),
  94       where:
  95         fragment("(?)->'tag' IS NOT NULL AND (?)->'tag' != '[]'::jsonb", object.data, object.data),
  96       select: %{
  97         id: object.id,
  98         tag: fragment("(?)->'tag'", object.data)
  99       }
 100     )
 101     |> Repo.chunk_stream(100, :batches, timeout: :infinity)
 102     |> Stream.each(fn objects ->
 103       object_ids = Enum.map(objects, & &1.id)
 104
 105       failed_ids =
 106         objects
 107         |> Enum.map(&transfer_object_hashtags(&1))
 108         |> Enum.filter(&(elem(&1, 0) == :error))
 109         |> Enum.map(&elem(&1, 1))
 110
 111       for failed_id <- failed_ids do
 112         _ =
 113           Repo.query(
 114             "INSERT INTO data_migration_failed_ids(data_migration_id, record_id) " <>
 115               "VALUES ($1, $2) ON CONFLICT DO NOTHING;",
 116             [data_migration.id, failed_id]
 117           )
 118       end
 119
 120       _ =
 121         Repo.query(
 122           "DELETE FROM data_migration_failed_ids WHERE id = ANY($1)",
 123           [object_ids -- failed_ids]
 124         )
 125
 126       max_object_id = Enum.at(object_ids, -1)
 127
 128       put_stat(:max_processed_id, max_object_id)
 129       increment_stat(:processed_count, length(object_ids))
 130       increment_stat(:failed_count, length(failed_ids))
 131
 132       persist_stats(data_migration)
 133
 134       # A quick and dirty approach to controlling the load this background migration imposes
 135       sleep_interval = Config.get([:populate_hashtags_table, :sleep_interval_ms], 0)
 136       Process.sleep(sleep_interval)
 137     end)
 138     |> Stream.run()
 139
 140     with {:ok, %{rows: [[0]]}} <-
 141            Repo.query(
 142              "SELECT COUNT(record_id) FROM data_migration_failed_ids WHERE data_migration_id = $1;",
 143              [data_migration.id]
 144            ) do
 145       _ = DataMigration.update_state(data_migration, :complete)
 146
 147       handle_success(data_migration)
 148     else
 149       _ ->
 150         _ = DataMigration.update_state(data_migration, :failed)
 151
 152         update_status(:failed, "Please check data_migration_failed_ids records.")
 153     end
 154
 155     {:noreply, state}
 156   end
 157
 158   defp transfer_object_hashtags(object) do
 159     hashtags = Object.object_data_hashtags(%{"tag" => object.tag})
 160
 161     Repo.transaction(fn ->
 162       with {:ok, hashtag_records} <- Hashtag.get_or_create_by_names(hashtags) do
 163         for hashtag_record <- hashtag_records do
 164           with {:ok, _} <-
 165                  Repo.query(
 166                    "insert into hashtags_objects(hashtag_id, object_id) values ($1, $2);",
 167                    [hashtag_record.id, object.id]
 168                  ) do
 169             nil
 170           else
 171             {:error, e} ->
 172               error =
 173                 "ERROR: could not link object #{object.id} and hashtag " <>
 174                   "#{hashtag_record.id}: #{inspect(e)}"
 175
 176               Logger.error(error)
 177               Repo.rollback(object.id)
 178           end
 179         end
 180
 181         object.id
 182       else
 183         e ->
 184           error = "ERROR: could not create hashtags for object #{object.id}: #{inspect(e)}"
 185           Logger.error(error)
 186           Repo.rollback(object.id)
 187       end
 188     end)
 189   end
 190
 191   defp persist_stats(data_migration) do
 192     runner_state = Map.drop(state(), [:status])
 193     _ = DataMigration.update(data_migration, %{data: runner_state})
 194   end
 195
 196   defp handle_success(data_migration) do
 197     update_status(:complete)
 198
 199     cond do
 200       data_migration.feature_lock ->
 201         :noop
 202
 203       not is_nil(Config.improved_hashtag_timeline()) ->
 204         :noop
 205
 206       true ->
 207         Config.put(Config.improved_hashtag_timeline_path(), true)
 208         :ok
 209     end
 210   end
 211
 212   def failed_objects_query do
 213     from(o in Object)
 214     |> join(:inner, [o], dmf in fragment("SELECT * FROM data_migration_failed_ids"),
 215       on: dmf.record_id == o.id
 216     )
 217     |> where([_o, dmf], dmf.data_migration_id == ^data_migration().id)
 218     |> order_by([o], asc: o.id)
 219   end
 220
 221   def force_continue do
 222     send(whereis(), :migrate_hashtags)
 223   end
 224
 225   def force_restart do
 226     {:ok, _} = DataMigration.update(data_migration(), %{state: :pending, data: %{}})
 227     force_continue()
 228   end
 229
 230   defp update_status(status, message \\ nil) do
 231     put_stat(:status, status)
 232     put_stat(:message, message)
 233   end
 234 end