git.squeep.com Git - akkoma/blob - lib/pleroma/marker.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Marker do
   6   use Ecto.Schema
   7
   8   import Ecto.Changeset
   9   import Ecto.Query
  10
  11   alias Ecto.Multi
  12   alias Pleroma.Repo
  13   alias Pleroma.User
  14   alias __MODULE__
  15
  16   @timelines ["notifications"]
  17
  18   schema "markers" do
  19     field(:last_read_id, :string, default: "")
  20     field(:timeline, :string, default: "")
  21     field(:lock_version, :integer, default: 0)
  22     field(:unread_count, :integer, default: 0)
  23
  24     belongs_to(:user, User, type: FlakeId.Ecto.CompatType)
  25     timestamps()
  26   end
  27
  28   def get_markers(user, timelines \\ []) do
  29     Repo.all(get_query(user, timelines))
  30   end
  31
  32   def upsert(%User{} = user, attrs) do
  33     attrs
  34     |> Map.take(@timelines)
  35     |> Enum.reduce(Multi.new(), fn {timeline, timeline_attrs}, multi ->
  36       marker =
  37         user
  38         |> get_marker(timeline)
  39         |> changeset(timeline_attrs)
  40
  41       Multi.insert(multi, timeline, marker,
  42         returning: true,
  43         on_conflict: {:replace, [:last_read_id, :unread_count]},
  44         conflict_target: [:user_id, :timeline]
  45       )
  46     end)
  47     |> Repo.transaction()
  48   end
  49
  50   @spec multi_set_unread_count(Multi.t(), User.t(), String.t()) :: Multi.t()
  51   def multi_set_unread_count(multi, %User{} = user, "notifications") do
  52     multi
  53     |> Multi.run(:counters, fn _repo, _changes ->
  54       {:ok, Repo.one(Pleroma.Notification.notifications_info_query(user))}
  55     end)
  56     |> Multi.insert(
  57       :marker,
  58       fn %{counters: attrs} ->
  59         %Marker{timeline: "notifications", user_id: user.id}
  60         |> struct(attrs)
  61         |> Ecto.Changeset.change()
  62       end,
  63       returning: true,
  64       on_conflict: {:replace, [:last_read_id, :unread_count]},
  65       conflict_target: [:user_id, :timeline]
  66     )
  67   end
  68
  69   def multi_set_unread_count(multi, _, _), do: multi
  70
  71   defp get_marker(user, timeline) do
  72     case Repo.find_resource(get_query(user, timeline)) do
  73       {:ok, marker} -> %__MODULE__{marker | user: user}
  74       _ -> %__MODULE__{timeline: timeline, user_id: user.id}
  75     end
  76   end
  77
  78   @doc false
  79   defp changeset(marker, attrs) do
  80     marker
  81     |> cast(attrs, [:last_read_id, :unread_count])
  82     |> validate_required([:user_id, :timeline, :last_read_id])
  83     |> validate_inclusion(:timeline, @timelines)
  84   end
  85
  86   defp by_timeline(query, timeline) do
  87     from(m in query, where: m.timeline in ^List.wrap(timeline))
  88   end
  89
  90   defp by_user_id(query, id), do: from(m in query, where: m.user_id == ^id)
  91
  92   defp get_query(user, timelines) do
  93     __MODULE__
  94     |> by_user_id(user.id)
  95     |> by_timeline(timelines)
  96   end
  97 end