git.squeep.com Git - akkoma/blob - lib/pleroma/instances/instance.ex

   1 defmodule Pleroma.Instances.Instance do
   2   @moduledoc "Instance."
   3
   4   alias Pleroma.Instances
   5   alias Pleroma.Instances.Instance
   6
   7   use Ecto.Schema
   8
   9   import Ecto.{Query, Changeset}
  10
  11   alias Pleroma.Repo
  12
  13   schema "instances" do
  14     field(:host, :string)
  15     field(:unreachable_since, :naive_datetime)
  16     field(:reachability_checked_at, :naive_datetime)
  17
  18     timestamps()
  19   end
  20
  21   defdelegate host(url), to: Instances
  22
  23   def changeset(struct, params \\ %{}) do
  24     struct
  25     |> cast(params, [:host, :unreachable_since, :reachability_checked_at])
  26     |> validate_required([:host])
  27     |> unique_constraint(:host)
  28   end
  29
  30   def filter_reachable([]), do: []
  31
  32   def filter_reachable(urls) when is_list(urls) do
  33     hosts =
  34       urls
  35       |> Enum.map(&(&1 && host(&1)))
  36       |> Enum.filter(&(to_string(&1) != ""))
  37
  38     unreachable_hosts =
  39       Repo.all(
  40         from(i in Instance,
  41           where:
  42             i.host in ^hosts and i.unreachable_since <= ^Instances.reachability_time_threshold(),
  43           select: i.host
  44         )
  45       )
  46
  47     Enum.filter(urls, &(&1 && host(&1) not in unreachable_hosts))
  48   end
  49
  50   def reachable?(url) when is_binary(url) do
  51     !Repo.one(
  52       from(i in Instance,
  53         where:
  54           i.host == ^host(url) and i.unreachable_since <= ^Instances.reachability_time_threshold(),
  55         select: true
  56       )
  57     )
  58   end
  59
  60   def reachable?(_), do: true
  61
  62   def set_reachable(url) when is_binary(url) do
  63     with host <- host(url),
  64          %Instance{} = existing_record <- Repo.get_by(Instance, %{host: host}) do
  65       {:ok, _instance} =
  66         existing_record
  67         |> changeset(%{unreachable_since: nil, reachability_checked_at: DateTime.utc_now()})
  68         |> Repo.update()
  69     end
  70   end
  71
  72   def set_reachable(_), do: {0, :noop}
  73
  74   def set_unreachable(url, unreachable_since \\ nil)
  75
  76   def set_unreachable(url, unreachable_since) when is_binary(url) do
  77     unreachable_since = unreachable_since || DateTime.utc_now()
  78     host = host(url)
  79     existing_record = Repo.get_by(Instance, %{host: host})
  80
  81     changes = %{
  82       unreachable_since: unreachable_since,
  83       reachability_checked_at: NaiveDateTime.utc_now()
  84     }
  85
  86     if existing_record do
  87       update_changes =
  88         if existing_record.unreachable_since &&
  89              NaiveDateTime.compare(existing_record.unreachable_since, unreachable_since) != :gt,
  90            do: Map.delete(changes, :unreachable_since),
  91            else: changes
  92
  93       {:ok, _instance} =
  94         existing_record
  95         |> changeset(update_changes)
  96         |> Repo.update()
  97     else
  98       {:ok, _instance} =
  99         %Instance{}
 100         |> changeset(Map.put(changes, :host, host))
 101         |> Repo.insert()
 102     end
 103   end
 104
 105   def set_unreachable(_, _), do: {0, :noop}
 106 end