git.squeep.com Git - akkoma/blob - lib/pleroma/http/adapter_helper/gun.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.HTTP.AdapterHelper.Gun do
   6   @behaviour Pleroma.HTTP.AdapterHelper
   7
   8   alias Pleroma.HTTP.AdapterHelper
   9   alias Pleroma.Pool.Connections
  10
  11   require Logger
  12
  13   @defaults [
  14     connect_timeout: 5_000,
  15     domain_lookup_timeout: 5_000,
  16     tls_handshake_timeout: 5_000,
  17     retry: 1,
  18     retry_timeout: 1000,
  19     await_up_timeout: 5_000
  20   ]
  21
  22   @spec options(keyword(), URI.t()) :: keyword()
  23   def options(connection_opts \\ [], %URI{} = uri) do
  24     formatted_proxy =
  25       Pleroma.Config.get([:http, :proxy_url], nil)
  26       |> AdapterHelper.format_proxy()
  27
  28     config_opts = Pleroma.Config.get([:http, :adapter], [])
  29
  30     @defaults
  31     |> Keyword.merge(config_opts)
  32     |> add_scheme_opts(uri)
  33     |> AdapterHelper.maybe_add_proxy(formatted_proxy)
  34     |> maybe_get_conn(uri, connection_opts)
  35   end
  36
  37   @spec after_request(keyword()) :: :ok
  38   def after_request(opts) do
  39     if opts[:conn] && opts[:body_as] != :chunks do
  40       Connections.checkout(opts[:conn], self(), :gun_connections)
  41     end
  42
  43     :ok
  44   end
  45
  46   defp add_scheme_opts(opts, %URI{scheme: "http"}), do: opts
  47
  48   defp add_scheme_opts(opts, %URI{scheme: "https"}) do
  49     opts
  50     |> Keyword.put(:certificates_verification, true)
  51     |> Keyword.put(:transport, :tls)
  52     |> Keyword.put(:tls_opts, log_level: :warning)
  53   end
  54
  55   defp maybe_get_conn(adapter_opts, uri, connection_opts) do
  56     {receive_conn?, opts} =
  57       adapter_opts
  58       |> Keyword.merge(connection_opts)
  59       |> Keyword.pop(:receive_conn, true)
  60
  61     if Connections.alive?(:gun_connections) and receive_conn? do
  62       try_to_get_conn(uri, opts)
  63     else
  64       opts
  65     end
  66   end
  67
  68   defp try_to_get_conn(uri, opts) do
  69     case Connections.checkin(uri, :gun_connections) do
  70       nil ->
  71         Logger.debug(
  72           "Gun connections pool checkin was not successful. Trying to open conn for next request."
  73         )
  74
  75         Task.start(fn -> Pleroma.Gun.Conn.open(uri, :gun_connections, opts) end)
  76         opts
  77
  78       conn when is_pid(conn) ->
  79         Logger.debug("received conn #{inspect(conn)} #{Connections.compose_uri_log(uri)}")
  80
  81         opts
  82         |> Keyword.put(:conn, conn)
  83         |> Keyword.put(:close_conn, false)
  84     end
  85   end
  86 end