git.squeep.com Git - akkoma/blob - lib/pleroma/emoji/formatter.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Emoji.Formatter do
   6   alias Pleroma.Emoji
   7   alias Pleroma.HTML
   8   alias Pleroma.Web.MediaProxy
   9
  10   def emojify(text) do
  11     emojify(text, Emoji.get_all())
  12   end
  13
  14   def emojify(text, nil), do: text
  15
  16   def emojify(text, emoji, strip \\ false) do
  17     Enum.reduce(emoji, text, fn
  18       {_, %Emoji{safe_code: emoji, safe_file: file}}, text ->
  19         String.replace(text, ":#{emoji}:", prepare_emoji_html(emoji, file, strip))
  20
  21       {unsafe_emoji, unsafe_file}, text ->
  22         emoji = HTML.strip_tags(unsafe_emoji)
  23         file = HTML.strip_tags(unsafe_file)
  24         String.replace(text, ":#{emoji}:", prepare_emoji_html(emoji, file, strip))
  25     end)
  26     |> HTML.filter_tags()
  27   end
  28
  29   defp prepare_emoji_html(_emoji, _file, true), do: ""
  30
  31   defp prepare_emoji_html(emoji, file, _strip) do
  32     "<img class='emoji' alt='#{emoji}' title='#{emoji}' src='#{MediaProxy.url(file)}' />"
  33   end
  34
  35   def demojify(text) do
  36     emojify(text, Emoji.get_all(), true)
  37   end
  38
  39   def demojify(text, nil), do: text
  40
  41   @doc "Outputs a list of the emoji-shortcodes in a text"
  42   def get_emoji(text) when is_binary(text) do
  43     Enum.filter(Emoji.get_all(), fn {emoji, %Emoji{}} ->
  44       String.contains?(text, ":#{emoji}:")
  45     end)
  46   end
  47
  48   def get_emoji(_), do: []
  49
  50   @doc "Outputs a list of the emoji-Maps in a text"
  51   def get_emoji_map(text) when is_binary(text) do
  52     get_emoji(text)
  53     |> Enum.reduce(%{}, fn {name, %Emoji{file: file}}, acc ->
  54       Map.put(acc, name, "#{Pleroma.Web.Endpoint.static_url()}#{file}")
  55     end)
  56   end
  57
  58   def get_emoji_map(_), do: []
  59 end