git.squeep.com Git - akkoma/blob - lib/pleroma/config.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Config do
   6   defmodule Error do
   7     defexception [:message]
   8   end
   9
  10   def get(key), do: get(key, nil)
  11
  12   def get([key], default), do: get(key, default)
  13
  14   def get([_ | _] = path, default) do
  15     case fetch(path) do
  16       {:ok, value} -> value
  17       :error -> default
  18     end
  19   end
  20
  21   def get(key, default) do
  22     Application.get_env(:pleroma, key, default)
  23   end
  24
  25   def get!(key) do
  26     value = get(key, nil)
  27
  28     if value == nil do
  29       raise(Error, message: "Missing configuration value: #{inspect(key)}")
  30     else
  31       value
  32     end
  33   end
  34
  35   def fetch(key) when is_atom(key), do: fetch([key])
  36
  37   def fetch([root_key | keys]) do
  38     Enum.reduce_while(keys, Application.fetch_env(:pleroma, root_key), fn
  39       key, {:ok, config} when is_map(config) or is_list(config) ->
  40         case Access.fetch(config, key) do
  41           :error ->
  42             {:halt, :error}
  43
  44           value ->
  45             {:cont, value}
  46         end
  47
  48       _key, _config ->
  49         {:halt, :error}
  50     end)
  51   end
  52
  53   def put([key], value), do: put(key, value)
  54
  55   def put([parent_key | keys], value) do
  56     parent =
  57       Application.get_env(:pleroma, parent_key, [])
  58       |> put_in(keys, value)
  59
  60     Application.put_env(:pleroma, parent_key, parent)
  61   end
  62
  63   def put(key, value) do
  64     Application.put_env(:pleroma, key, value)
  65   end
  66
  67   def delete([key]), do: delete(key)
  68
  69   def delete([parent_key | keys] = path) do
  70     with {:ok, _} <- fetch(path) do
  71       {_, parent} =
  72         parent_key
  73         |> get()
  74         |> get_and_update_in(keys, fn _ -> :pop end)
  75
  76       Application.put_env(:pleroma, parent_key, parent)
  77     end
  78   end
  79
  80   def delete(key) do
  81     Application.delete_env(:pleroma, key)
  82   end
  83
  84   def restrict_unauthenticated_access?(resource, kind) do
  85     setting = get([:restrict_unauthenticated, resource, kind])
  86
  87     if setting in [nil, :if_instance_is_private] do
  88       !get!([:instance, :public])
  89     else
  90       setting
  91     end
  92   end
  93
  94   def oauth_consumer_strategies, do: get([:auth, :oauth_consumer_strategies], [])
  95
  96   def oauth_consumer_enabled?, do: oauth_consumer_strategies() != []
  97
  98   def enforce_oauth_admin_scope_usage?, do: !!get([:auth, :enforce_oauth_admin_scope_usage])
  99
 100   def oauth_admin_scopes(scopes) when is_list(scopes) do
 101     Enum.flat_map(
 102       scopes,
 103       fn scope ->
 104         ["admin:#{scope}"] ++
 105           if enforce_oauth_admin_scope_usage?(), do: [], else: [scope]
 106       end
 107     )
 108   end
 109 end