git.squeep.com Git - akkoma/blob - lib/pleroma/config/transfer_task.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Config.TransferTask do
   6   use Task
   7
   8   alias Pleroma.Config
   9   alias Pleroma.ConfigDB
  10   alias Pleroma.Repo
  11
  12   require Logger
  13
  14   @type env() :: :test | :benchmark | :dev | :prod
  15
  16   defp reboot_time_keys,
  17     do: [
  18       {:pleroma, :hackney_pools},
  19       {:pleroma, :shout},
  20       {:pleroma, Oban},
  21       {:pleroma, :rate_limit},
  22       {:pleroma, :markup},
  23       {:pleroma, :streamer},
  24       {:pleroma, :pools},
  25       {:pleroma, :connections_pool}
  26     ]
  27
  28   defp reboot_time_subkeys,
  29     do: [
  30       {:pleroma, Pleroma.Captcha, [:seconds_valid]},
  31       {:pleroma, Pleroma.Upload, [:proxy_remote]},
  32       {:pleroma, :instance, [:upload_limit]}
  33     ]
  34
  35   def start_link(restart_pleroma? \\ true) do
  36     load_and_update_env([], restart_pleroma?)
  37     if Config.get(:env) == :test, do: Ecto.Adapters.SQL.Sandbox.checkin(Repo)
  38     :ignore
  39   end
  40
  41   @spec load_and_update_env([ConfigDB.t()], boolean()) :: :ok
  42   def load_and_update_env(deleted_settings \\ [], restart_pleroma? \\ true) do
  43     with {_, true} <- {:configurable, Config.get(:configurable_from_database)} do
  44       # We need to restart applications for loaded settings take effect
  45
  46       {logger, other} =
  47         (Repo.all(ConfigDB) ++ deleted_settings)
  48         |> Enum.map(&merge_with_default/1)
  49         |> Enum.split_with(fn {group, _, _, _} -> group in [:logger, :quack] end)
  50
  51       logger
  52       |> Enum.sort()
  53       |> Enum.each(&configure/1)
  54
  55       started_applications = Application.started_applications()
  56
  57       # TODO: some problem with prometheus after restart!
  58       reject = [nil, :prometheus, :postgrex]
  59
  60       reject =
  61         if restart_pleroma? do
  62           reject
  63         else
  64           [:pleroma | reject]
  65         end
  66
  67       other
  68       |> Enum.map(&update/1)
  69       |> Enum.uniq()
  70       |> Enum.reject(&(&1 in reject))
  71       |> maybe_set_pleroma_last()
  72       |> Enum.each(&restart(started_applications, &1, Config.get(:env)))
  73
  74       :ok
  75     else
  76       {:configurable, false} -> Restarter.Pleroma.rebooted()
  77     end
  78   end
  79
  80   defp maybe_set_pleroma_last(apps) do
  81     # to be ensured that pleroma will be restarted last
  82     if :pleroma in apps do
  83       apps
  84       |> List.delete(:pleroma)
  85       |> List.insert_at(-1, :pleroma)
  86     else
  87       Restarter.Pleroma.rebooted()
  88       apps
  89     end
  90   end
  91
  92   defp merge_with_default(%{group: group, key: key, value: value} = setting) do
  93     default = Config.Holder.default_config(group, key)
  94
  95     merged =
  96       cond do
  97         Ecto.get_meta(setting, :state) == :deleted -> default
  98         can_be_merged?(default, value) -> ConfigDB.merge_group(group, key, default, value)
  99         true -> value
 100       end
 101
 102     {group, key, value, merged}
 103   end
 104
 105   # change logger configuration in runtime, without restart
 106   defp configure({:quack, key, _, merged}) do
 107     Logger.configure_backend(Quack.Logger, [{key, merged}])
 108     :ok = update_env(:quack, key, merged)
 109   end
 110
 111   defp configure({_, :backends, _, merged}) do
 112     # removing current backends
 113     Enum.each(Application.get_env(:logger, :backends), &Logger.remove_backend/1)
 114
 115     Enum.each(merged, &Logger.add_backend/1)
 116
 117     :ok = update_env(:logger, :backends, merged)
 118   end
 119
 120   defp configure({_, key, _, merged}) when key in [:console, :ex_syslogger] do
 121     merged =
 122       if key == :console do
 123         put_in(merged[:format], merged[:format] <> "\n")
 124       else
 125         merged
 126       end
 127
 128     backend =
 129       if key == :ex_syslogger,
 130         do: {ExSyslogger, :ex_syslogger},
 131         else: key
 132
 133     Logger.configure_backend(backend, merged)
 134     :ok = update_env(:logger, key, merged)
 135   end
 136
 137   defp configure({_, key, _, merged}) do
 138     Logger.configure([{key, merged}])
 139     :ok = update_env(:logger, key, merged)
 140   end
 141
 142   defp update({group, key, value, merged}) do
 143     try do
 144       :ok = update_env(group, key, merged)
 145
 146       if group != :pleroma or pleroma_need_restart?(group, key, value), do: group
 147     rescue
 148       error ->
 149         error_msg =
 150           "updating env causes error, group: #{inspect(group)}, key: #{inspect(key)}, value: #{inspect(value)} error: #{inspect(error)}"
 151
 152         Logger.warn(error_msg)
 153
 154         nil
 155     end
 156   end
 157
 158   defp update_env(group, key, nil), do: Application.delete_env(group, key)
 159   defp update_env(group, key, value), do: Application.put_env(group, key, value)
 160
 161   @spec pleroma_need_restart?(atom(), atom(), any()) :: boolean()
 162   def pleroma_need_restart?(group, key, value) do
 163     group_and_key_need_reboot?(group, key) or group_and_subkey_need_reboot?(group, key, value)
 164   end
 165
 166   defp group_and_key_need_reboot?(group, key) do
 167     Enum.any?(reboot_time_keys(), fn {g, k} -> g == group and k == key end)
 168   end
 169
 170   defp group_and_subkey_need_reboot?(group, key, value) do
 171     Keyword.keyword?(value) and
 172       Enum.any?(reboot_time_subkeys(), fn {g, k, subkeys} ->
 173         g == group and k == key and
 174           Enum.any?(Keyword.keys(value), &(&1 in subkeys))
 175       end)
 176   end
 177
 178   defp restart(_, :pleroma, env), do: Restarter.Pleroma.restart_after_boot(env)
 179
 180   defp restart(started_applications, app, _) do
 181     with {^app, _, _} <- List.keyfind(started_applications, app, 0),
 182          :ok <- Application.stop(app) do
 183       :ok = Application.start(app)
 184     else
 185       nil ->
 186         Logger.warn("#{app} is not started.")
 187
 188       error ->
 189         error
 190         |> inspect()
 191         |> Logger.warn()
 192     end
 193   end
 194
 195   defp can_be_merged?(val1, val2) when is_list(val1) and is_list(val2) do
 196     Keyword.keyword?(val1) and Keyword.keyword?(val2)
 197   end
 198
 199   defp can_be_merged?(_val1, _val2), do: false
 200 end