git.squeep.com Git - akkoma/blob - lib/pleroma/config/transfer_task.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Config.TransferTask do
   6   use Task
   7
   8   alias Pleroma.Config
   9   alias Pleroma.ConfigDB
  10   alias Pleroma.Repo
  11
  12   require Logger
  13
  14   @type env() :: :test | :benchmark | :dev | :prod
  15
  16   defp reboot_time_keys,
  17     do: [
  18       {:pleroma, Oban},
  19       {:pleroma, :rate_limit},
  20       {:pleroma, :markup},
  21       {:pleroma, :streamer}
  22     ]
  23
  24   defp reboot_time_subkeys,
  25     do: [
  26       {:pleroma, Pleroma.Captcha, [:seconds_valid]},
  27       {:pleroma, Pleroma.Upload, [:proxy_remote]},
  28       {:pleroma, :instance, [:upload_limit]},
  29       {:pleroma, :http, [:pool_size]},
  30       {:pleroma, :http, [:proxy_url]}
  31     ]
  32
  33   def start_link(restart_pleroma? \\ true) do
  34     load_and_update_env([], restart_pleroma?)
  35     if Config.get(:env) == :test, do: Ecto.Adapters.SQL.Sandbox.checkin(Repo)
  36     :ignore
  37   end
  38
  39   @spec load_and_update_env([ConfigDB.t()], boolean()) :: :ok
  40   def load_and_update_env(deleted_settings \\ [], restart_pleroma? \\ true) do
  41     with {_, true} <- {:configurable, Config.get(:configurable_from_database)} do
  42       # We need to restart applications for loaded settings take effect
  43       {logger, other} =
  44         (Repo.all(ConfigDB) ++ deleted_settings)
  45         |> Enum.map(&merge_with_default/1)
  46         |> Enum.split_with(fn {group, _, _, _} -> group == :logger end)
  47
  48       logger
  49       |> Enum.sort()
  50       |> Enum.each(&configure/1)
  51
  52       started_applications = Application.started_applications()
  53
  54       reject = [nil, :postgrex]
  55
  56       reject =
  57         if restart_pleroma? do
  58           reject
  59         else
  60           [:pleroma | reject]
  61         end
  62
  63       other
  64       |> Enum.map(&update/1)
  65       |> Enum.uniq()
  66       |> Enum.reject(&(&1 in reject))
  67       |> maybe_set_pleroma_last()
  68       |> Enum.each(&restart(started_applications, &1, Config.get(:env)))
  69
  70       :ok
  71     else
  72       {:configurable, false} -> Restarter.Pleroma.rebooted()
  73     end
  74   end
  75
  76   defp maybe_set_pleroma_last(apps) do
  77     # to be ensured that pleroma will be restarted last
  78     if :pleroma in apps do
  79       apps
  80       |> List.delete(:pleroma)
  81       |> List.insert_at(-1, :pleroma)
  82     else
  83       Restarter.Pleroma.rebooted()
  84       apps
  85     end
  86   end
  87
  88   defp merge_with_default(%{group: group, key: key, value: value} = setting) do
  89     default =
  90       if group == :pleroma do
  91         Config.get([key], Config.Holder.default_config(group, key))
  92       else
  93         Config.Holder.default_config(group, key)
  94       end
  95
  96     merged =
  97       cond do
  98         Ecto.get_meta(setting, :state) == :deleted -> default
  99         can_be_merged?(default, value) -> ConfigDB.merge_group(group, key, default, value)
 100         true -> value
 101       end
 102
 103     {group, key, value, merged}
 104   end
 105
 106   defp configure({_, :backends, _, merged}) do
 107     # removing current backends
 108     Enum.each(Application.get_env(:logger, :backends), &Logger.remove_backend/1)
 109
 110     Enum.each(merged, &Logger.add_backend/1)
 111
 112     :ok = update_env(:logger, :backends, merged)
 113   end
 114
 115   defp configure({_, key, _, merged}) when key in [:console, :ex_syslogger] do
 116     merged =
 117       if key == :console do
 118         put_in(merged[:format], merged[:format] <> "\n")
 119       else
 120         merged
 121       end
 122
 123     backend =
 124       if key == :ex_syslogger,
 125         do: {ExSyslogger, :ex_syslogger},
 126         else: key
 127
 128     Logger.configure_backend(backend, merged)
 129     :ok = update_env(:logger, key, merged)
 130   end
 131
 132   defp configure({_, key, _, merged}) do
 133     Logger.configure([{key, merged}])
 134     :ok = update_env(:logger, key, merged)
 135   end
 136
 137   defp update({group, key, value, merged}) do
 138     try do
 139       :ok = update_env(group, key, merged)
 140
 141       if group != :pleroma or pleroma_need_restart?(group, key, value), do: group
 142     rescue
 143       error ->
 144         error_msg =
 145           "updating env causes error, group: #{inspect(group)}, key: #{inspect(key)}, value: #{inspect(value)} error: #{inspect(error)}"
 146
 147         Logger.warn(error_msg)
 148
 149         nil
 150     end
 151   end
 152
 153   defp update_env(group, key, nil), do: Application.delete_env(group, key)
 154   defp update_env(group, key, value), do: Application.put_env(group, key, value)
 155
 156   @spec pleroma_need_restart?(atom(), atom(), any()) :: boolean()
 157   def pleroma_need_restart?(group, key, value) do
 158     group_and_key_need_reboot?(group, key) or group_and_subkey_need_reboot?(group, key, value)
 159   end
 160
 161   defp group_and_key_need_reboot?(group, key) do
 162     Enum.any?(reboot_time_keys(), fn {g, k} -> g == group and k == key end)
 163   end
 164
 165   defp group_and_subkey_need_reboot?(group, key, value) do
 166     Keyword.keyword?(value) and
 167       Enum.any?(reboot_time_subkeys(), fn {g, k, subkeys} ->
 168         g == group and k == key and
 169           Enum.any?(Keyword.keys(value), &(&1 in subkeys))
 170       end)
 171   end
 172
 173   defp restart(_, :pleroma, env), do: Restarter.Pleroma.restart_after_boot(env)
 174
 175   defp restart(started_applications, app, _) do
 176     with {^app, _, _} <- List.keyfind(started_applications, app, 0),
 177          :ok <- Application.stop(app) do
 178       :ok = Application.start(app)
 179     else
 180       nil ->
 181         Logger.warn("#{app} is not started.")
 182
 183       error ->
 184         error
 185         |> inspect()
 186         |> Logger.warn()
 187     end
 188   end
 189
 190   defp can_be_merged?(val1, val2) when is_list(val1) and is_list(val2) do
 191     Keyword.keyword?(val1) and Keyword.keyword?(val2)
 192   end
 193
 194   defp can_be_merged?(_val1, _val2), do: false
 195 end