git.squeep.com Git - akkoma/blob - lib/pleroma/config/transfer_task.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Config.TransferTask do
   6   use Task
   7
   8   alias Pleroma.Config
   9   alias Pleroma.ConfigDB
  10   alias Pleroma.Repo
  11
  12   require Logger
  13
  14   @type env() :: :test | :benchmark | :dev | :prod
  15
  16   defp reboot_time_keys,
  17     do: [
  18       {:pleroma, Oban},
  19       {:pleroma, :rate_limit},
  20       {:pleroma, :markup},
  21       {:pleroma, :streamer}
  22     ]
  23
  24   defp reboot_time_subkeys,
  25     do: [
  26       {:pleroma, Pleroma.Captcha, [:seconds_valid]},
  27       {:pleroma, Pleroma.Upload, [:proxy_remote]},
  28       {:pleroma, :instance, [:upload_limit]}
  29     ]
  30
  31   def start_link(restart_pleroma? \\ true) do
  32     load_and_update_env([], restart_pleroma?)
  33     if Config.get(:env) == :test, do: Ecto.Adapters.SQL.Sandbox.checkin(Repo)
  34     :ignore
  35   end
  36
  37   @spec load_and_update_env([ConfigDB.t()], boolean()) :: :ok
  38   def load_and_update_env(deleted_settings \\ [], restart_pleroma? \\ true) do
  39     with {_, true} <- {:configurable, Config.get(:configurable_from_database)} do
  40       # We need to restart applications for loaded settings take effect
  41       {logger, other} =
  42         (Repo.all(ConfigDB) ++ deleted_settings)
  43         |> Enum.map(&merge_with_default/1)
  44         |> Enum.split_with(fn {group, _, _, _} -> group == :logger end)
  45
  46       logger
  47       |> Enum.sort()
  48       |> Enum.each(&configure/1)
  49
  50       started_applications = Application.started_applications()
  51
  52       reject = [nil, :postgrex]
  53
  54       reject =
  55         if restart_pleroma? do
  56           reject
  57         else
  58           [:pleroma | reject]
  59         end
  60
  61       other
  62       |> Enum.map(&update/1)
  63       |> Enum.uniq()
  64       |> Enum.reject(&(&1 in reject))
  65       |> maybe_set_pleroma_last()
  66       |> Enum.each(&restart(started_applications, &1, Config.get(:env)))
  67
  68       :ok
  69     else
  70       {:configurable, false} -> Restarter.Pleroma.rebooted()
  71     end
  72   end
  73
  74   defp maybe_set_pleroma_last(apps) do
  75     # to be ensured that pleroma will be restarted last
  76     if :pleroma in apps do
  77       apps
  78       |> List.delete(:pleroma)
  79       |> List.insert_at(-1, :pleroma)
  80     else
  81       Restarter.Pleroma.rebooted()
  82       apps
  83     end
  84   end
  85
  86   defp merge_with_default(%{group: group, key: key, value: value} = setting) do
  87     default =
  88       if group == :pleroma do
  89         Config.get([key], Config.Holder.default_config(group, key))
  90       else
  91         Config.Holder.default_config(group, key)
  92       end
  93
  94     merged =
  95       cond do
  96         Ecto.get_meta(setting, :state) == :deleted -> default
  97         can_be_merged?(default, value) -> ConfigDB.merge_group(group, key, default, value)
  98         true -> value
  99       end
 100
 101     {group, key, value, merged}
 102   end
 103
 104   defp configure({_, :backends, _, merged}) do
 105     # removing current backends
 106     Enum.each(Application.get_env(:logger, :backends), &Logger.remove_backend/1)
 107
 108     Enum.each(merged, &Logger.add_backend/1)
 109
 110     :ok = update_env(:logger, :backends, merged)
 111   end
 112
 113   defp configure({_, key, _, merged}) when key in [:console, :ex_syslogger] do
 114     merged =
 115       if key == :console do
 116         put_in(merged[:format], merged[:format] <> "\n")
 117       else
 118         merged
 119       end
 120
 121     backend =
 122       if key == :ex_syslogger,
 123         do: {ExSyslogger, :ex_syslogger},
 124         else: key
 125
 126     Logger.configure_backend(backend, merged)
 127     :ok = update_env(:logger, key, merged)
 128   end
 129
 130   defp configure({_, key, _, merged}) do
 131     Logger.configure([{key, merged}])
 132     :ok = update_env(:logger, key, merged)
 133   end
 134
 135   defp update({group, key, value, merged}) do
 136     try do
 137       :ok = update_env(group, key, merged)
 138
 139       if group != :pleroma or pleroma_need_restart?(group, key, value), do: group
 140     rescue
 141       error ->
 142         error_msg =
 143           "updating env causes error, group: #{inspect(group)}, key: #{inspect(key)}, value: #{inspect(value)} error: #{inspect(error)}"
 144
 145         Logger.warn(error_msg)
 146
 147         nil
 148     end
 149   end
 150
 151   defp update_env(group, key, nil), do: Application.delete_env(group, key)
 152   defp update_env(group, key, value), do: Application.put_env(group, key, value)
 153
 154   @spec pleroma_need_restart?(atom(), atom(), any()) :: boolean()
 155   def pleroma_need_restart?(group, key, value) do
 156     group_and_key_need_reboot?(group, key) or group_and_subkey_need_reboot?(group, key, value)
 157   end
 158
 159   defp group_and_key_need_reboot?(group, key) do
 160     Enum.any?(reboot_time_keys(), fn {g, k} -> g == group and k == key end)
 161   end
 162
 163   defp group_and_subkey_need_reboot?(group, key, value) do
 164     Keyword.keyword?(value) and
 165       Enum.any?(reboot_time_subkeys(), fn {g, k, subkeys} ->
 166         g == group and k == key and
 167           Enum.any?(Keyword.keys(value), &(&1 in subkeys))
 168       end)
 169   end
 170
 171   defp restart(_, :pleroma, env), do: Restarter.Pleroma.restart_after_boot(env)
 172
 173   defp restart(started_applications, app, _) do
 174     with {^app, _, _} <- List.keyfind(started_applications, app, 0),
 175          :ok <- Application.stop(app) do
 176       :ok = Application.start(app)
 177     else
 178       nil ->
 179         Logger.warn("#{app} is not started.")
 180
 181       error ->
 182         error
 183         |> inspect()
 184         |> Logger.warn()
 185     end
 186   end
 187
 188   defp can_be_merged?(val1, val2) when is_list(val1) and is_list(val2) do
 189     Keyword.keyword?(val1) and Keyword.keyword?(val2)
 190   end
 191
 192   defp can_be_merged?(_val1, _val2), do: false
 193 end