git.squeep.com Git - akkoma/blob - lib/pleroma/config/deprecation_warnings.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Config.DeprecationWarnings do
   6   alias Pleroma.Config
   7
   8   require Logger
   9   alias Pleroma.Config
  10
  11   @type config_namespace() :: [atom()]
  12   @type config_map() :: {config_namespace(), config_namespace(), String.t()}
  13
  14   @mrf_config_map [
  15     {[:instance, :rewrite_policy], [:mrf, :policies],
  16      "\n* `config :pleroma, :instance, rewrite_policy` is now `config :pleroma, :mrf, policies`"},
  17     {[:instance, :mrf_transparency], [:mrf, :transparency],
  18      "\n* `config :pleroma, :instance, mrf_transparency` is now `config :pleroma, :mrf, transparency`"},
  19     {[:instance, :mrf_transparency_exclusions], [:mrf, :transparency_exclusions],
  20      "\n* `config :pleroma, :instance, mrf_transparency_exclusions` is now `config :pleroma, :mrf, transparency_exclusions`"}
  21   ]
  22
  23   def check_hellthread_threshold do
  24     if Config.get([:mrf_hellthread, :threshold]) do
  25       Logger.warn("""
  26       !!!DEPRECATION WARNING!!!
  27       You are using the old configuration mechanism for the hellthread filter. Please check config.md.
  28       """)
  29     end
  30   end
  31
  32   def mrf_user_allowlist do
  33     config = Config.get(:mrf_user_allowlist)
  34
  35     if config && Enum.any?(config, fn {k, _} -> is_atom(k) end) do
  36       rewritten =
  37         Enum.reduce(Config.get(:mrf_user_allowlist), Map.new(), fn {k, v}, acc ->
  38           Map.put(acc, to_string(k), v)
  39         end)
  40
  41       Config.put(:mrf_user_allowlist, rewritten)
  42
  43       Logger.error("""
  44       !!!DEPRECATION WARNING!!!
  45       As of Pleroma 2.0.7, the `mrf_user_allowlist` setting changed of format.
  46       Pleroma 2.1 will remove support for the old format. Please change your configuration to match this:
  47
  48       config :pleroma, :mrf_user_allowlist, #{inspect(rewritten, pretty: true)}
  49       """)
  50     end
  51   end
  52
  53   def warn do
  54     check_hellthread_threshold()
  55     mrf_user_allowlist()
  56     check_old_mrf_config()
  57     check_media_proxy_whitelist_config()
  58   end
  59
  60   def check_old_mrf_config do
  61     warning_preface = """
  62     !!!DEPRECATION WARNING!!!
  63     Your config is using old namespaces for MRF configuration. They should work for now, but you are advised to change to new namespaces to prevent possible issues later:
  64     """
  65
  66     move_namespace_and_warn(@mrf_config_map, warning_preface)
  67   end
  68
  69   @spec move_namespace_and_warn([config_map()], String.t()) :: :ok | nil
  70   def move_namespace_and_warn(config_map, warning_preface) do
  71     warning =
  72       Enum.reduce(config_map, "", fn
  73         {old, new, err_msg}, acc ->
  74           old_config = Config.get(old)
  75
  76           if old_config do
  77             Config.put(new, old_config)
  78             acc <> err_msg
  79           else
  80             acc
  81           end
  82       end)
  83
  84     if warning != "" do
  85       Logger.warn(warning_preface <> warning)
  86     end
  87   end
  88
  89   @spec check_media_proxy_whitelist_config() :: :ok | nil
  90   def check_media_proxy_whitelist_config do
  91     whitelist = Config.get([:media_proxy, :whitelist])
  92
  93     if Enum.any?(whitelist, &(not String.starts_with?(&1, "http"))) do
  94       Logger.warn("""
  95       !!!DEPRECATION WARNING!!!
  96       Your config is using old format (only domain) for MediaProxy whitelist option. Setting should work for now, but you are advised to change format to scheme with port to prevent possible issues later.
  97       """)
  98     end
  99   end
 100 end