git.squeep.com Git - akkoma/blob - lib/pleroma/config/deprecation_warnings.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Config.DeprecationWarnings do
   6   alias Pleroma.Config
   7
   8   require Logger
   9   alias Pleroma.Config
  10
  11   @type config_namespace() :: atom() | [atom()]
  12   @type config_map() :: {config_namespace(), config_namespace(), String.t()}
  13
  14   @mrf_config_map [
  15     {[:instance, :rewrite_policy], [:mrf, :policies],
  16      "\n* `config :pleroma, :instance, rewrite_policy` is now `config :pleroma, :mrf, policies`"},
  17     {[:instance, :mrf_transparency], [:mrf, :transparency],
  18      "\n* `config :pleroma, :instance, mrf_transparency` is now `config :pleroma, :mrf, transparency`"},
  19     {[:instance, :mrf_transparency_exclusions], [:mrf, :transparency_exclusions],
  20      "\n* `config :pleroma, :instance, mrf_transparency_exclusions` is now `config :pleroma, :mrf, transparency_exclusions`"}
  21   ]
  22
  23   def check_simple_policy_tuples do
  24     has_strings =
  25       Config.get([:mrf_simple])
  26       |> Enum.any?(fn {_, v} -> Enum.any?(v, &is_binary/1) end)
  27
  28     if has_strings do
  29       Logger.warn("""
  30       !!!DEPRECATION WARNING!!!
  31       Your config is using strings in the SimplePolicy configuration instead of tuples. They should work for now, but you are advised to change to the new configuration to prevent possible issues later:
  32
  33       ```
  34       config :pleroma, :mrf_simple,
  35         media_removal: ["instance.tld"],
  36         media_nsfw: ["instance.tld"],
  37         federated_timeline_removal: ["instance.tld"],
  38         report_removal: ["instance.tld"],
  39         reject: ["instance.tld"],
  40         followers_only: ["instance.tld"],
  41         accept: ["instance.tld"],
  42         avatar_removal: ["instance.tld"],
  43         banner_removal: ["instance.tld"],
  44         reject_deletes: ["instance.tld"]
  45       ```
  46
  47       Is now
  48
  49
  50       ```
  51       config :pleroma, :mrf_simple,
  52         media_removal: [{"instance.tld", "Reason for media removal"}],
  53         media_nsfw: [{"instance.tld", "Reason for media nsfw"}],
  54         federated_timeline_removal: [{"instance.tld", "Reason for federated timeline removal"}],
  55         report_removal: [{"instance.tld", "Reason for report removal"}],
  56         reject: [{"instance.tld", "Reason for reject"}],
  57         followers_only: [{"instance.tld", "Reason for followers only"}],
  58         accept: [{"instance.tld", "Reason for accept"}],
  59         avatar_removal: [{"instance.tld", "Reason for avatar removal"}],
  60         banner_removal: [{"instance.tld", "Reason for banner removal"}],
  61         reject_deletes: [{"instance.tld", "Reason for reject deletes"}]
  62       ```
  63       """)
  64
  65       new_config =
  66         Config.get([:mrf_simple])
  67         |> Enum.map(fn {k, v} ->
  68           {k,
  69            Enum.map(v, fn
  70              {instance, reason} -> {instance, reason}
  71              instance -> {instance, ""}
  72            end)}
  73         end)
  74
  75       Config.put([:mrf_simple], new_config)
  76
  77       :error
  78     else
  79       :ok
  80     end
  81   end
  82
  83   def check_quarantined_instances_tuples do
  84     has_strings = Config.get([:instance, :quarantined_instances]) |> Enum.any?(&is_binary/1)
  85
  86     if has_strings do
  87       Logger.warn("""
  88       !!!DEPRECATION WARNING!!!
  89       Your config is using strings in the quarantined_instances configuration instead of tuples. They should work for now, but you are advised to change to the new configuration to prevent possible issues later:
  90
  91       ```
  92       config :pleroma, :instance,
  93         quarantined_instances: ["instance.tld"]
  94       ```
  95
  96       Is now
  97
  98
  99       ```
 100       config :pleroma, :instance,
 101         quarantined_instances: [{"instance.tld", "Reason for quarantine"}]
 102       ```
 103       """)
 104
 105       new_config =
 106         Config.get([:instance, :quarantined_instances])
 107         |> Enum.map(fn
 108           {instance, reason} -> {instance, reason}
 109           instance -> {instance, ""}
 110         end)
 111
 112       Config.put([:instance, :quarantined_instances], new_config)
 113
 114       :error
 115     else
 116       :ok
 117     end
 118   end
 119
 120   def check_transparency_exclusions_tuples do
 121     has_strings = Config.get([:mrf, :transparency_exclusions]) |> Enum.any?(&is_binary/1)
 122
 123     if has_strings do
 124       Logger.warn("""
 125       !!!DEPRECATION WARNING!!!
 126       Your config is using strings in the transparency_exclusions configuration instead of tuples. They should work for now, but you are advised to change to the new configuration to prevent possible issues later:
 127
 128       ```
 129       config :pleroma, :mrf,
 130         transparency_exclusions: ["instance.tld"]
 131       ```
 132
 133       Is now
 134
 135
 136       ```
 137       config :pleroma, :mrf,
 138         transparency_exclusions: [{"instance.tld", "Reason to exlude transparency"}]
 139       ```
 140       """)
 141
 142       new_config =
 143         Config.get([:mrf, :transparency_exclusions])
 144         |> Enum.map(fn
 145           {instance, reason} -> {instance, reason}
 146           instance -> {instance, ""}
 147         end)
 148
 149       Config.put([:mrf, :transparency_exclusions], new_config)
 150
 151       :error
 152     else
 153       :ok
 154     end
 155   end
 156
 157   def check_hellthread_threshold do
 158     if Config.get([:mrf_hellthread, :threshold]) do
 159       Logger.warn("""
 160       !!!DEPRECATION WARNING!!!
 161       You are using the old configuration mechanism for the hellthread filter. Please check config.md.
 162       """)
 163
 164       :error
 165     else
 166       :ok
 167     end
 168   end
 169
 170   def warn do
 171     [
 172       check_hellthread_threshold(),
 173       check_old_mrf_config(),
 174       check_media_proxy_whitelist_config(),
 175       check_welcome_message_config(),
 176       check_activity_expiration_config(),
 177       check_remote_ip_plug_name(),
 178       check_uploders_s3_public_endpoint(),
 179       check_old_chat_shoutbox(),
 180       check_quarantined_instances_tuples(),
 181       check_transparency_exclusions_tuples(),
 182       check_simple_policy_tuples()
 183     ]
 184     |> Enum.reduce(:ok, fn
 185       :ok, :ok -> :ok
 186       _, _ -> :error
 187     end)
 188   end
 189
 190   def check_welcome_message_config do
 191     instance_config = Pleroma.Config.get([:instance])
 192
 193     use_old_config =
 194       Keyword.has_key?(instance_config, :welcome_user_nickname) or
 195         Keyword.has_key?(instance_config, :welcome_message)
 196
 197     if use_old_config do
 198       Logger.error("""
 199       !!!DEPRECATION WARNING!!!
 200       Your config is using the old namespace for Welcome messages configuration. You need to convert to the new namespace. e.g.,
 201       \n* `config :pleroma, :instance, welcome_user_nickname` and `config :pleroma, :instance, welcome_message` are now equal to:
 202       \n* `config :pleroma, :welcome, direct_message: [enabled: true, sender_nickname: "NICKNAME", message: "Your welcome message"]`"
 203       """)
 204
 205       :error
 206     else
 207       :ok
 208     end
 209   end
 210
 211   def check_old_mrf_config do
 212     warning_preface = """
 213     !!!DEPRECATION WARNING!!!
 214     Your config is using old namespaces for MRF configuration. They should work for now, but you are advised to change to new namespaces to prevent possible issues later:
 215     """
 216
 217     move_namespace_and_warn(@mrf_config_map, warning_preface)
 218   end
 219
 220   @spec move_namespace_and_warn([config_map()], String.t()) :: :ok | nil
 221   def move_namespace_and_warn(config_map, warning_preface) do
 222     warning =
 223       Enum.reduce(config_map, "", fn
 224         {old, new, err_msg}, acc ->
 225           old_config = Config.get(old)
 226
 227           if old_config do
 228             Config.put(new, old_config)
 229             acc <> err_msg
 230           else
 231             acc
 232           end
 233       end)
 234
 235     if warning == "" do
 236       :ok
 237     else
 238       Logger.warn(warning_preface <> warning)
 239       :error
 240     end
 241   end
 242
 243   @spec check_media_proxy_whitelist_config() :: :ok | nil
 244   def check_media_proxy_whitelist_config do
 245     whitelist = Config.get([:media_proxy, :whitelist])
 246
 247     if Enum.any?(whitelist, &(not String.starts_with?(&1, "http"))) do
 248       Logger.warn("""
 249       !!!DEPRECATION WARNING!!!
 250       Your config is using old format (only domain) for MediaProxy whitelist option. Setting should work for now, but you are advised to change format to scheme with port to prevent possible issues later.
 251       """)
 252
 253       :error
 254     else
 255       :ok
 256     end
 257   end
 258
 259   @spec check_activity_expiration_config() :: :ok | nil
 260   def check_activity_expiration_config do
 261     warning_preface = """
 262     !!!DEPRECATION WARNING!!!
 263       Your config is using old namespace for activity expiration configuration. Setting should work for now, but you are advised to change to new namespace to prevent possible issues later:
 264     """
 265
 266     move_namespace_and_warn(
 267       [
 268         {Pleroma.ActivityExpiration, Pleroma.Workers.PurgeExpiredActivity,
 269          "\n* `config :pleroma, Pleroma.ActivityExpiration` is now `config :pleroma, Pleroma.Workers.PurgeExpiredActivity`"}
 270       ],
 271       warning_preface
 272     )
 273   end
 274
 275   @spec check_remote_ip_plug_name() :: :ok | nil
 276   def check_remote_ip_plug_name do
 277     warning_preface = """
 278     !!!DEPRECATION WARNING!!!
 279     Your config is using old namespace for RemoteIp Plug. Setting should work for now, but you are advised to change to new namespace to prevent possible issues later:
 280     """
 281
 282     move_namespace_and_warn(
 283       [
 284         {Pleroma.Plugs.RemoteIp, Pleroma.Web.Plugs.RemoteIp,
 285          "\n* `config :pleroma, Pleroma.Plugs.RemoteIp` is now `config :pleroma, Pleroma.Web.Plugs.RemoteIp`"}
 286       ],
 287       warning_preface
 288     )
 289   end
 290
 291   @spec check_uploders_s3_public_endpoint() :: :ok | nil
 292   def check_uploders_s3_public_endpoint do
 293     s3_config = Pleroma.Config.get([Pleroma.Uploaders.S3])
 294
 295     use_old_config = Keyword.has_key?(s3_config, :public_endpoint)
 296
 297     if use_old_config do
 298       Logger.error("""
 299       !!!DEPRECATION WARNING!!!
 300       Your config is using the old setting for controlling the URL of media uploaded to your S3 bucket.\n
 301       Please make the following change at your earliest convenience.\n
 302       \n* `config :pleroma, Pleroma.Uploaders.S3, public_endpoint` is now equal to:
 303       \n* `config :pleroma, Pleroma.Upload, base_url`
 304       """)
 305
 306       :error
 307     else
 308       :ok
 309     end
 310   end
 311
 312   @spec check_old_chat_shoutbox() :: :ok | nil
 313   def check_old_chat_shoutbox do
 314     instance_config = Pleroma.Config.get([:instance])
 315     chat_config = Pleroma.Config.get([:chat]) || []
 316
 317     use_old_config =
 318       Keyword.has_key?(instance_config, :chat_limit) or
 319         Keyword.has_key?(chat_config, :enabled)
 320
 321     if use_old_config do
 322       Logger.error("""
 323       !!!DEPRECATION WARNING!!!
 324       Your config is using the old namespace for the Shoutbox configuration. You need to convert to the new namespace. e.g.,
 325       \n* `config :pleroma, :chat, enabled` and `config :pleroma, :instance, chat_limit` are now equal to:
 326       \n* `config :pleroma, :shout, enabled` and `config :pleroma, :shout, limit`
 327       """)
 328
 329       :error
 330     else
 331       :ok
 332     end
 333   end
 334 end