git.squeep.com Git - akkoma/blob - lib/pleroma/config/deprecation_warnings.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Config.DeprecationWarnings do
   6   alias Pleroma.Config
   7
   8   require Logger
   9   alias Pleroma.Config
  10
  11   @type config_namespace() :: [atom()]
  12   @type config_map() :: {config_namespace(), config_namespace(), String.t()}
  13
  14   @mrf_config_map [
  15     {[:instance, :rewrite_policy], [:mrf, :policies],
  16      "\n* `config :pleroma, :instance, rewrite_policy` is now `config :pleroma, :mrf, policies`"},
  17     {[:instance, :mrf_transparency], [:mrf, :transparency],
  18      "\n* `config :pleroma, :instance, mrf_transparency` is now `config :pleroma, :mrf, transparency`"},
  19     {[:instance, :mrf_transparency_exclusions], [:mrf, :transparency_exclusions],
  20      "\n* `config :pleroma, :instance, mrf_transparency_exclusions` is now `config :pleroma, :mrf, transparency_exclusions`"}
  21   ]
  22
  23   def check_hellthread_threshold do
  24     if Config.get([:mrf_hellthread, :threshold]) do
  25       Logger.warn("""
  26       !!!DEPRECATION WARNING!!!
  27       You are using the old configuration mechanism for the hellthread filter. Please check config.md.
  28       """)
  29     end
  30   end
  31
  32   def mrf_user_allowlist do
  33     config = Config.get(:mrf_user_allowlist)
  34
  35     if config && Enum.any?(config, fn {k, _} -> is_atom(k) end) do
  36       rewritten =
  37         Enum.reduce(Config.get(:mrf_user_allowlist), Map.new(), fn {k, v}, acc ->
  38           Map.put(acc, to_string(k), v)
  39         end)
  40
  41       Config.put(:mrf_user_allowlist, rewritten)
  42
  43       Logger.error("""
  44       !!!DEPRECATION WARNING!!!
  45       As of Pleroma 2.0.7, the `mrf_user_allowlist` setting changed of format.
  46       Pleroma 2.1 will remove support for the old format. Please change your configuration to match this:
  47
  48       config :pleroma, :mrf_user_allowlist, #{inspect(rewritten, pretty: true)}
  49       """)
  50     end
  51   end
  52
  53   def warn do
  54     check_hellthread_threshold()
  55     mrf_user_allowlist()
  56     check_old_mrf_config()
  57   end
  58
  59   def check_old_mrf_config do
  60     warning_preface = """
  61     !!!DEPRECATION WARNING!!!
  62     Your config is using old namespaces for MRF configuration. They should work for now, but you are advised to change to new namespaces to prevent possible issues later:
  63     """
  64
  65     move_namespace_and_warn(@mrf_config_map, warning_preface)
  66   end
  67
  68   @spec move_namespace_and_warn([config_map()], String.t()) :: :ok
  69   def move_namespace_and_warn(config_map, warning_preface) do
  70     warning =
  71       Enum.reduce(config_map, "", fn
  72         {old, new, err_msg}, acc ->
  73           old_config = Config.get(old)
  74
  75           if old_config do
  76             Config.put(new, old_config)
  77             acc <> err_msg
  78           else
  79             acc
  80           end
  81       end)
  82
  83     if warning != "" do
  84       Logger.warn(warning_preface <> warning)
  85     end
  86   end
  87 end