git.squeep.com Git - akkoma/blob - lib/pleroma/application_requirements.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.ApplicationRequirements do
   6   @moduledoc """
   7   The module represents the collection of validations to runs before start server.
   8   """
   9
  10   defmodule VerifyError, do: defexception([:message])
  11
  12   import Ecto.Query
  13
  14   require Logger
  15
  16   @spec verify!() :: :ok | VerifyError.t()
  17   def verify! do
  18     :ok
  19     |> check_confirmation_accounts!
  20     |> check_migrations_applied!()
  21     |> check_rum!()
  22     |> handle_result()
  23   end
  24
  25   defp handle_result(:ok), do: :ok
  26   defp handle_result({:error, message}), do: raise(VerifyError, message: message)
  27
  28   # Checks account confirmation email
  29   #
  30   def check_confirmation_accounts!(:ok) do
  31     if Pleroma.Config.get([:instance, :account_activation_required]) &&
  32          not Pleroma.Config.get([Pleroma.Emails.Mailer, :enabled]) do
  33       Logger.error(
  34         "Account activation enabled, but no Mailer settings enabled.\nPlease set config :pleroma, :instance, account_activation_required: false\nOtherwise setup and enable Mailer."
  35       )
  36
  37       {:error,
  38        "Account activation enabled, but Mailer is disabled. Cannot send confirmation emails."}
  39     else
  40       :ok
  41     end
  42   end
  43
  44   def check_confirmation_accounts!(result), do: result
  45
  46   # Checks for pending migrations.
  47   #
  48   def check_migrations_applied!(:ok) do
  49     unless Pleroma.Config.get(
  50              [:i_am_aware_this_may_cause_data_loss, :disable_migration_check],
  51              false
  52            ) do
  53       {_, res, _} =
  54         Ecto.Migrator.with_repo(Pleroma.Repo, fn repo ->
  55           down_migrations =
  56             Ecto.Migrator.migrations(repo)
  57             |> Enum.reject(fn
  58               {:up, _, _} -> true
  59               {:down, _, _} -> false
  60             end)
  61
  62           if length(down_migrations) > 0 do
  63             down_migrations_text =
  64               Enum.map(down_migrations, fn {:down, id, name} -> "- #{name} (#{id})\n" end)
  65
  66             Logger.error(
  67               "The following migrations were not applied:\n#{down_migrations_text}If you want to start Pleroma anyway, set\nconfig :pleroma, :i_am_aware_this_may_cause_data_loss, disable_migration_check: true"
  68             )
  69
  70             {:error, "Unapplied Migrations detected"}
  71           else
  72             :ok
  73           end
  74         end)
  75
  76       res
  77     else
  78       :ok
  79     end
  80   end
  81
  82   def check_migrations_applied!(result), do: result
  83
  84   # Checks for settings of RUM indexes.
  85   #
  86   defp check_rum!(:ok) do
  87     {_, res, _} =
  88       Ecto.Migrator.with_repo(Pleroma.Repo, fn repo ->
  89         migrate =
  90           from(o in "columns",
  91             where: o.table_name == "objects",
  92             where: o.column_name == "fts_content"
  93           )
  94           |> repo.exists?(prefix: "information_schema")
  95
  96         setting = Pleroma.Config.get([:database, :rum_enabled], false)
  97
  98         do_check_rum!(setting, migrate)
  99       end)
 100
 101     res
 102   end
 103
 104   defp check_rum!(result), do: result
 105
 106   defp do_check_rum!(setting, migrate) do
 107     case {setting, migrate} do
 108       {true, false} ->
 109         Logger.error(
 110           "Use `RUM` index is enabled, but were not applied migrations for it.\nIf you want to start Pleroma anyway, set\nconfig :pleroma, :database, rum_enabled: false\nOtherwise apply the following migrations:\n`mix ecto.migrate --migrations-path priv/repo/optional_migrations/rum_indexing/`"
 111         )
 112
 113         {:error, "Unapplied RUM Migrations detected"}
 114
 115       {false, true} ->
 116         Logger.error(
 117           "Detected applied migrations to use `RUM` index, but `RUM` isn't enable in settings.\nIf you want to use `RUM`, set\nconfig :pleroma, :database, rum_enabled: true\nOtherwise roll `RUM` migrations back.\n`mix ecto.rollback --migrations-path priv/repo/optional_migrations/rum_indexing/`"
 118         )
 119
 120         {:error, "RUM Migrations detected"}
 121
 122       _ ->
 123         :ok
 124     end
 125   end
 126 end