git.squeep.com Git - akkoma/blob - lib/pleroma/application.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Application do
   6   import Cachex.Spec
   7   use Application
   8   require Logger
   9
  10   @name Mix.Project.config()[:name]
  11   @version Mix.Project.config()[:version]
  12   @repository Mix.Project.config()[:source_url]
  13   @env Mix.env()
  14
  15   def name, do: @name
  16   def version, do: @version
  17   def named_version, do: @name <> " " <> @version
  18   def repository, do: @repository
  19
  20   def user_agent do
  21     case Pleroma.Config.get([:http, :user_agent], :default) do
  22       :default ->
  23         info = "#{Pleroma.Web.base_url()} <#{Pleroma.Config.get([:instance, :email], "")}>"
  24         named_version() <> "; " <> info
  25
  26       custom ->
  27         custom
  28     end
  29   end
  30
  31   # See http://elixir-lang.org/docs/stable/elixir/Application.html
  32   # for more information on OTP Applications
  33   def start(_type, _args) do
  34     Pleroma.HTML.compile_scrubbers()
  35     Pleroma.Config.DeprecationWarnings.warn()
  36     Pleroma.Repo.check_migrations_applied!()
  37     setup_instrumenters()
  38     load_custom_modules()
  39
  40     # Define workers and child supervisors to be supervised
  41     children =
  42       [
  43         Pleroma.Repo,
  44         Pleroma.Config.TransferTask,
  45         Pleroma.Emoji,
  46         Pleroma.Captcha,
  47         Pleroma.Plugs.RateLimiter.Supervisor
  48       ] ++
  49         cachex_children() ++
  50         hackney_pool_children() ++
  51         [
  52           Pleroma.Stats,
  53           Pleroma.JobQueueMonitor,
  54           {Oban, Pleroma.Config.get(Oban)}
  55         ] ++
  56         task_children(@env) ++
  57         streamer_child(@env) ++
  58         chat_child(@env, chat_enabled?()) ++
  59         [
  60           Pleroma.Web.Endpoint,
  61           Pleroma.Gopher.Server
  62         ]
  63
  64     # See http://elixir-lang.org/docs/stable/elixir/Supervisor.html
  65     # for other strategies and supported options
  66     opts = [strategy: :one_for_one, name: Pleroma.Supervisor]
  67     Supervisor.start_link(children, opts)
  68   end
  69
  70   def load_custom_modules do
  71     dir = Pleroma.Config.get([:modules, :runtime_dir])
  72
  73     if dir && File.exists?(dir) do
  74       dir
  75       |> Pleroma.Utils.compile_dir()
  76       |> case do
  77         {:error, _errors, _warnings} ->
  78           raise "Invalid custom modules"
  79
  80         {:ok, modules, _warnings} ->
  81           if @env != :test do
  82             Enum.each(modules, fn mod ->
  83               Logger.info("Custom module loaded: #{inspect(mod)}")
  84             end)
  85           end
  86
  87           :ok
  88       end
  89     end
  90   end
  91
  92   defp setup_instrumenters do
  93     require Prometheus.Registry
  94
  95     if Application.get_env(:prometheus, Pleroma.Repo.Instrumenter) do
  96       :ok =
  97         :telemetry.attach(
  98           "prometheus-ecto",
  99           [:pleroma, :repo, :query],
 100           &Pleroma.Repo.Instrumenter.handle_event/4,
 101           %{}
 102         )
 103
 104       Pleroma.Repo.Instrumenter.setup()
 105     end
 106
 107     Pleroma.Web.Endpoint.MetricsExporter.setup()
 108     Pleroma.Web.Endpoint.PipelineInstrumenter.setup()
 109     Pleroma.Web.Endpoint.Instrumenter.setup()
 110   end
 111
 112   def enabled_hackney_pools do
 113     [:media] ++
 114       if Application.get_env(:tesla, :adapter) == Tesla.Adapter.Hackney do
 115         [:federation]
 116       else
 117         []
 118       end ++
 119       if Pleroma.Config.get([Pleroma.Upload, :proxy_remote]) do
 120         [:upload]
 121       else
 122         []
 123       end
 124   end
 125
 126   defp cachex_children do
 127     [
 128       build_cachex("used_captcha", ttl_interval: seconds_valid_interval()),
 129       build_cachex("user", default_ttl: 25_000, ttl_interval: 1000, limit: 2500),
 130       build_cachex("object", default_ttl: 25_000, ttl_interval: 1000, limit: 2500),
 131       build_cachex("rich_media", default_ttl: :timer.minutes(120), limit: 5000),
 132       build_cachex("scrubber", limit: 2500),
 133       build_cachex("idempotency", expiration: idempotency_expiration(), limit: 2500),
 134       build_cachex("web_resp", limit: 2500),
 135       build_cachex("emoji_packs", expiration: emoji_packs_expiration(), limit: 10),
 136       build_cachex("failed_proxy_url", limit: 2500)
 137     ]
 138   end
 139
 140   defp emoji_packs_expiration,
 141     do: expiration(default: :timer.seconds(5 * 60), interval: :timer.seconds(60))
 142
 143   defp idempotency_expiration,
 144     do: expiration(default: :timer.seconds(6 * 60 * 60), interval: :timer.seconds(60))
 145
 146   defp seconds_valid_interval,
 147     do: :timer.seconds(Pleroma.Config.get!([Pleroma.Captcha, :seconds_valid]))
 148
 149   defp build_cachex(type, opts),
 150     do: %{
 151       id: String.to_atom("cachex_" <> type),
 152       start: {Cachex, :start_link, [String.to_atom(type <> "_cache"), opts]},
 153       type: :worker
 154     }
 155
 156   defp chat_enabled?, do: Pleroma.Config.get([:chat, :enabled])
 157
 158   defp streamer_child(:test), do: []
 159
 160   defp streamer_child(_) do
 161     [Pleroma.Web.Streamer.supervisor()]
 162   end
 163
 164   defp chat_child(_env, true) do
 165     [Pleroma.Web.ChatChannel.ChatChannelState]
 166   end
 167
 168   defp chat_child(_, _), do: []
 169
 170   defp hackney_pool_children do
 171     for pool <- enabled_hackney_pools() do
 172       options = Pleroma.Config.get([:hackney_pools, pool])
 173       :hackney_pool.child_spec(pool, options)
 174     end
 175   end
 176
 177   defp task_children(:test) do
 178     [
 179       %{
 180         id: :web_push_init,
 181         start: {Task, :start_link, [&Pleroma.Web.Push.init/0]},
 182         restart: :temporary
 183       }
 184     ]
 185   end
 186
 187   defp task_children(_) do
 188     [
 189       %{
 190         id: :web_push_init,
 191         start: {Task, :start_link, [&Pleroma.Web.Push.init/0]},
 192         restart: :temporary
 193       },
 194       %{
 195         id: :internal_fetch_init,
 196         start: {Task, :start_link, [&Pleroma.Web.ActivityPub.InternalFetchActor.init/0]},
 197         restart: :temporary
 198       }
 199     ]
 200   end
 201 end