git.squeep.com Git - akkoma/blob - lib/pleroma/application.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Application do
   6   import Cachex.Spec
   7   use Application
   8
   9   @name Mix.Project.config()[:name]
  10   @version Mix.Project.config()[:version]
  11   @repository Mix.Project.config()[:source_url]
  12   @env Mix.env()
  13
  14   def name, do: @name
  15   def version, do: @version
  16   def named_version, do: @name <> " " <> @version
  17   def repository, do: @repository
  18
  19   def user_agent do
  20     case Pleroma.Config.get([:http, :user_agent], :default) do
  21       :default ->
  22         info = "#{Pleroma.Web.base_url()} <#{Pleroma.Config.get([:instance, :email], "")}>"
  23         named_version() <> "; " <> info
  24
  25       custom ->
  26         custom
  27     end
  28   end
  29
  30   # See http://elixir-lang.org/docs/stable/elixir/Application.html
  31   # for more information on OTP Applications
  32   def start(_type, _args) do
  33     Pleroma.HTML.compile_scrubbers()
  34     Pleroma.Config.DeprecationWarnings.warn()
  35     setup_instrumenters()
  36
  37     # Define workers and child supervisors to be supervised
  38     children =
  39       [
  40         Pleroma.Repo,
  41         Pleroma.Scheduler,
  42         Pleroma.Config.TransferTask,
  43         Pleroma.Emoji,
  44         Pleroma.Captcha,
  45         Pleroma.Daemons.ScheduledActivityDaemon,
  46         Pleroma.Daemons.ActivityExpirationDaemon,
  47         Pleroma.Plugs.RateLimiter.Supervisor
  48       ] ++
  49         cachex_children() ++
  50         hackney_pool_children() ++
  51         [
  52           Pleroma.Stats,
  53           Pleroma.JobQueueMonitor,
  54           {Oban, Pleroma.Config.get(Oban)}
  55         ] ++
  56         task_children(@env) ++
  57         oauth_cleanup_child(oauth_cleanup_enabled?()) ++
  58         streamer_child(@env) ++
  59         chat_child(@env, chat_enabled?()) ++
  60         [
  61           Pleroma.Web.Endpoint,
  62           Pleroma.Gopher.Server
  63         ]
  64
  65     # See http://elixir-lang.org/docs/stable/elixir/Supervisor.html
  66     # for other strategies and supported options
  67     opts = [strategy: :one_for_one, name: Pleroma.Supervisor]
  68     Supervisor.start_link(children, opts)
  69   end
  70
  71   defp setup_instrumenters do
  72     require Prometheus.Registry
  73
  74     if Application.get_env(:prometheus, Pleroma.Repo.Instrumenter) do
  75       :ok =
  76         :telemetry.attach(
  77           "prometheus-ecto",
  78           [:pleroma, :repo, :query],
  79           &Pleroma.Repo.Instrumenter.handle_event/4,
  80           %{}
  81         )
  82
  83       Pleroma.Repo.Instrumenter.setup()
  84     end
  85
  86     Pleroma.Web.Endpoint.MetricsExporter.setup()
  87     Pleroma.Web.Endpoint.PipelineInstrumenter.setup()
  88     Pleroma.Web.Endpoint.Instrumenter.setup()
  89   end
  90
  91   def enabled_hackney_pools do
  92     [:media] ++
  93       if Application.get_env(:tesla, :adapter) == Tesla.Adapter.Hackney do
  94         [:federation]
  95       else
  96         []
  97       end ++
  98       if Pleroma.Config.get([Pleroma.Upload, :proxy_remote]) do
  99         [:upload]
 100       else
 101         []
 102       end
 103   end
 104
 105   defp cachex_children do
 106     [
 107       build_cachex("used_captcha", ttl_interval: seconds_valid_interval()),
 108       build_cachex("user", default_ttl: 25_000, ttl_interval: 1000, limit: 2500),
 109       build_cachex("object", default_ttl: 25_000, ttl_interval: 1000, limit: 2500),
 110       build_cachex("rich_media", default_ttl: :timer.minutes(120), limit: 5000),
 111       build_cachex("scrubber", limit: 2500),
 112       build_cachex("idempotency", expiration: idempotency_expiration(), limit: 2500),
 113       build_cachex("web_resp", limit: 2500),
 114       build_cachex("emoji_packs", expiration: emoji_packs_expiration(), limit: 10),
 115       build_cachex("failed_proxy_url", limit: 2500)
 116     ]
 117   end
 118
 119   defp emoji_packs_expiration,
 120     do: expiration(default: :timer.seconds(5 * 60), interval: :timer.seconds(60))
 121
 122   defp idempotency_expiration,
 123     do: expiration(default: :timer.seconds(6 * 60 * 60), interval: :timer.seconds(60))
 124
 125   defp seconds_valid_interval,
 126     do: :timer.seconds(Pleroma.Config.get!([Pleroma.Captcha, :seconds_valid]))
 127
 128   defp build_cachex(type, opts),
 129     do: %{
 130       id: String.to_atom("cachex_" <> type),
 131       start: {Cachex, :start_link, [String.to_atom(type <> "_cache"), opts]},
 132       type: :worker
 133     }
 134
 135   defp chat_enabled?, do: Pleroma.Config.get([:chat, :enabled])
 136
 137   defp oauth_cleanup_enabled?,
 138     do: Pleroma.Config.get([:oauth2, :clean_expired_tokens], false)
 139
 140   defp streamer_child(:test), do: []
 141
 142   defp streamer_child(_) do
 143     [Pleroma.Web.Streamer.supervisor()]
 144   end
 145
 146   defp oauth_cleanup_child(true),
 147     do: [Pleroma.Web.OAuth.Token.CleanWorker]
 148
 149   defp oauth_cleanup_child(_), do: []
 150
 151   defp chat_child(_env, true) do
 152     [Pleroma.Web.ChatChannel.ChatChannelState]
 153   end
 154
 155   defp chat_child(_, _), do: []
 156
 157   defp hackney_pool_children do
 158     for pool <- enabled_hackney_pools() do
 159       options = Pleroma.Config.get([:hackney_pools, pool])
 160       :hackney_pool.child_spec(pool, options)
 161     end
 162   end
 163
 164   defp task_children(:test) do
 165     [
 166       %{
 167         id: :web_push_init,
 168         start: {Task, :start_link, [&Pleroma.Web.Push.init/0]},
 169         restart: :temporary
 170       }
 171     ]
 172   end
 173
 174   defp task_children(_) do
 175     [
 176       %{
 177         id: :web_push_init,
 178         start: {Task, :start_link, [&Pleroma.Web.Push.init/0]},
 179         restart: :temporary
 180       },
 181       %{
 182         id: :internal_fetch_init,
 183         start: {Task, :start_link, [&Pleroma.Web.ActivityPub.InternalFetchActor.init/0]},
 184         restart: :temporary
 185       }
 186     ]
 187   end
 188 end