git.squeep.com Git - akkoma/blob - lib/pleroma/application.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Application do
   6   use Application
   7
   8   import Cachex.Spec
   9
  10   alias Pleroma.Config
  11
  12   require Logger
  13
  14   @name Mix.Project.config()[:name]
  15   @version Mix.Project.config()[:version]
  16   @repository Mix.Project.config()[:source_url]
  17   @env Mix.env()
  18
  19   def name, do: @name
  20   def version, do: @version
  21   def named_version, do: @name <> " " <> @version
  22   def repository, do: @repository
  23
  24   def user_agent do
  25     case Config.get([:http, :user_agent], :default) do
  26       :default ->
  27         info = "#{Pleroma.Web.base_url()} <#{Config.get([:instance, :email], "")}>"
  28         named_version() <> "; " <> info
  29
  30       custom ->
  31         custom
  32     end
  33   end
  34
  35   # See http://elixir-lang.org/docs/stable/elixir/Application.html
  36   # for more information on OTP Applications
  37   def start(_type, _args) do
  38     Pleroma.HTML.compile_scrubbers()
  39     Config.DeprecationWarnings.warn()
  40     Pleroma.Plugs.HTTPSecurityPlug.warn_if_disabled()
  41     Pleroma.Repo.check_migrations_applied!()
  42     setup_instrumenters()
  43     load_custom_modules()
  44
  45     # Define workers and child supervisors to be supervised
  46     children =
  47       [
  48         Pleroma.Repo,
  49         Config.TransferTask,
  50         Pleroma.Emoji,
  51         Pleroma.Captcha,
  52         Pleroma.Plugs.RateLimiter.Supervisor
  53       ] ++
  54         cachex_children() ++
  55         http_pools_children(Config.get(:env)) ++
  56         [
  57           Pleroma.Stats,
  58           Pleroma.JobQueueMonitor,
  59           {Oban, Config.get(Oban)}
  60         ] ++
  61         task_children(@env) ++
  62         streamer_child(@env) ++
  63         chat_child(@env, chat_enabled?()) ++
  64         [
  65           Pleroma.Web.Endpoint,
  66           Pleroma.Gopher.Server
  67         ]
  68
  69     case Pleroma.OTPVersion.check_version() do
  70       :ok -> :ok
  71       {:error, version} -> raise "
  72         !!!OTP VERSION WARNING!!!
  73         You are using gun adapter with OTP version #{version}, which doesn't support correct handling of unordered certificates chains.
  74         "
  75       :undefined -> raise "
  76         !!!OTP VERSION WARNING!!!
  77         To support correct handling of unordered certificates chains - OTP version must be > 22.2.
  78         "
  79     end
  80
  81     # See http://elixir-lang.org/docs/stable/elixir/Supervisor.html
  82     # for other strategies and supported options
  83     opts = [strategy: :one_for_one, name: Pleroma.Supervisor]
  84     Supervisor.start_link(children, opts)
  85   end
  86
  87   def load_custom_modules do
  88     dir = Config.get([:modules, :runtime_dir])
  89
  90     if dir && File.exists?(dir) do
  91       dir
  92       |> Pleroma.Utils.compile_dir()
  93       |> case do
  94         {:error, _errors, _warnings} ->
  95           raise "Invalid custom modules"
  96
  97         {:ok, modules, _warnings} ->
  98           if @env != :test do
  99             Enum.each(modules, fn mod ->
 100               Logger.info("Custom module loaded: #{inspect(mod)}")
 101             end)
 102           end
 103
 104           :ok
 105       end
 106     end
 107   end
 108
 109   defp setup_instrumenters do
 110     require Prometheus.Registry
 111
 112     if Application.get_env(:prometheus, Pleroma.Repo.Instrumenter) do
 113       :ok =
 114         :telemetry.attach(
 115           "prometheus-ecto",
 116           [:pleroma, :repo, :query],
 117           &Pleroma.Repo.Instrumenter.handle_event/4,
 118           %{}
 119         )
 120
 121       Pleroma.Repo.Instrumenter.setup()
 122     end
 123
 124     Pleroma.Web.Endpoint.MetricsExporter.setup()
 125     Pleroma.Web.Endpoint.PipelineInstrumenter.setup()
 126     Pleroma.Web.Endpoint.Instrumenter.setup()
 127   end
 128
 129   defp cachex_children do
 130     [
 131       build_cachex("used_captcha", ttl_interval: seconds_valid_interval()),
 132       build_cachex("user", default_ttl: 25_000, ttl_interval: 1000, limit: 2500),
 133       build_cachex("object", default_ttl: 25_000, ttl_interval: 1000, limit: 2500),
 134       build_cachex("rich_media", default_ttl: :timer.minutes(120), limit: 5000),
 135       build_cachex("scrubber", limit: 2500),
 136       build_cachex("idempotency", expiration: idempotency_expiration(), limit: 2500),
 137       build_cachex("web_resp", limit: 2500),
 138       build_cachex("emoji_packs", expiration: emoji_packs_expiration(), limit: 10),
 139       build_cachex("failed_proxy_url", limit: 2500)
 140     ]
 141   end
 142
 143   defp emoji_packs_expiration,
 144     do: expiration(default: :timer.seconds(5 * 60), interval: :timer.seconds(60))
 145
 146   defp idempotency_expiration,
 147     do: expiration(default: :timer.seconds(6 * 60 * 60), interval: :timer.seconds(60))
 148
 149   defp seconds_valid_interval,
 150     do: :timer.seconds(Config.get!([Pleroma.Captcha, :seconds_valid]))
 151
 152   defp build_cachex(type, opts),
 153     do: %{
 154       id: String.to_atom("cachex_" <> type),
 155       start: {Cachex, :start_link, [String.to_atom(type <> "_cache"), opts]},
 156       type: :worker
 157     }
 158
 159   defp chat_enabled?, do: Config.get([:chat, :enabled])
 160
 161   defp streamer_child(:test), do: []
 162
 163   defp streamer_child(_) do
 164     [Pleroma.Web.Streamer.supervisor()]
 165   end
 166
 167   defp chat_child(_env, true) do
 168     [Pleroma.Web.ChatChannel.ChatChannelState]
 169   end
 170
 171   defp chat_child(_, _), do: []
 172
 173   defp task_children(:test) do
 174     [
 175       %{
 176         id: :web_push_init,
 177         start: {Task, :start_link, [&Pleroma.Web.Push.init/0]},
 178         restart: :temporary
 179       }
 180     ]
 181   end
 182
 183   defp task_children(_) do
 184     [
 185       %{
 186         id: :web_push_init,
 187         start: {Task, :start_link, [&Pleroma.Web.Push.init/0]},
 188         restart: :temporary
 189       },
 190       %{
 191         id: :internal_fetch_init,
 192         start: {Task, :start_link, [&Pleroma.Web.ActivityPub.InternalFetchActor.init/0]},
 193         restart: :temporary
 194       }
 195     ]
 196   end
 197
 198   # start hackney and gun pools in tests
 199   defp http_pools_children(:test) do
 200     hackney_options = Config.get([:hackney_pools, :federation])
 201     hackney_pool = :hackney_pool.child_spec(:federation, hackney_options)
 202     [hackney_pool, Pleroma.Pool.Supervisor]
 203   end
 204
 205   defp http_pools_children(_) do
 206     :tesla
 207     |> Application.get_env(:adapter)
 208     |> http_pools()
 209   end
 210
 211   defp http_pools(Tesla.Adapter.Hackney) do
 212     pools = [:federation, :media]
 213
 214     pools =
 215       if Config.get([Pleroma.Upload, :proxy_remote]) do
 216         [:upload | pools]
 217       else
 218         pools
 219       end
 220
 221     for pool <- pools do
 222       options = Config.get([:hackney_pools, pool])
 223       :hackney_pool.child_spec(pool, options)
 224     end
 225   end
 226
 227   defp http_pools(Tesla.Adapter.Gun), do: [Pleroma.Pool.Supervisor]
 228
 229   defp http_pools(_), do: []
 230 end