git.squeep.com Git - akkoma/blob - lib/pleroma/application.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Application do
   6   use Application
   7
   8   import Cachex.Spec
   9
  10   alias Pleroma.Config
  11
  12   require Logger
  13
  14   @name Mix.Project.config()[:name]
  15   @version Mix.Project.config()[:version]
  16   @repository Mix.Project.config()[:source_url]
  17   @mix_env Mix.env()
  18
  19   def name, do: @name
  20   def version, do: @version
  21   def named_version, do: @name <> " " <> @version
  22   def repository, do: @repository
  23
  24   def user_agent do
  25     if Process.whereis(Pleroma.Web.Endpoint) do
  26       case Config.get([:http, :user_agent], :default) do
  27         :default ->
  28           info = "#{Pleroma.Web.Endpoint.url()} <#{Config.get([:instance, :email], "")}>"
  29           named_version() <> "; " <> info
  30
  31         custom ->
  32           custom
  33       end
  34     else
  35       # fallback, if endpoint is not started yet
  36       "Pleroma Data Loader"
  37     end
  38   end
  39
  40   # See http://elixir-lang.org/docs/stable/elixir/Application.html
  41   # for more information on OTP Applications
  42   def start(_type, _args) do
  43     # Scrubbers are compiled at runtime and therefore will cause a conflict
  44     # every time the application is restarted, so we disable module
  45     # conflicts at runtime
  46     Code.compiler_options(ignore_module_conflict: true)
  47     # Disable warnings_as_errors at runtime, it breaks Phoenix live reload
  48     # due to protocol consolidation warnings
  49     Code.compiler_options(warnings_as_errors: false)
  50     Config.Holder.save_default()
  51     Pleroma.HTML.compile_scrubbers()
  52     Pleroma.Config.Oban.warn()
  53     Config.DeprecationWarnings.warn()
  54     Pleroma.Web.Plugs.HTTPSecurityPlug.warn_if_disabled()
  55     Pleroma.ApplicationRequirements.verify!()
  56     setup_instrumenters()
  57     load_custom_modules()
  58     Pleroma.Docs.JSON.compile()
  59     limiters_setup()
  60
  61     # Define workers and child supervisors to be supervised
  62     children =
  63       [
  64         Pleroma.Repo,
  65         Config.TransferTask,
  66         Pleroma.Emoji,
  67         Pleroma.Web.Plugs.RateLimiter.Supervisor
  68       ] ++
  69         cachex_children() ++
  70         http_children() ++
  71         [
  72           Pleroma.Stats,
  73           Pleroma.JobQueueMonitor,
  74           {Majic.Pool, [name: Pleroma.MajicPool, pool_size: Config.get([:majic_pool, :size], 2)]},
  75           {Oban, Config.get(Oban)},
  76           Pleroma.Web.Endpoint
  77         ] ++
  78         elasticsearch_children() ++
  79         task_children(@mix_env) ++
  80         dont_run_in_test(@mix_env) ++
  81         shout_child(shout_enabled?())
  82
  83     # See http://elixir-lang.org/docs/stable/elixir/Supervisor.html
  84     # for other strategies and supported options
  85     opts = [strategy: :one_for_one, name: Pleroma.Supervisor]
  86     result = Supervisor.start_link(children, opts)
  87
  88     set_postgres_server_version()
  89
  90     result
  91   end
  92
  93   defp set_postgres_server_version do
  94     version =
  95       with %{rows: [[version]]} <- Ecto.Adapters.SQL.query!(Pleroma.Repo, "show server_version"),
  96            {num, _} <- Float.parse(version) do
  97         num
  98       else
  99         e ->
 100           Logger.warn(
 101             "Could not get the postgres version: #{inspect(e)}.\nSetting the default value of 9.6"
 102           )
 103
 104           9.6
 105       end
 106
 107     :persistent_term.put({Pleroma.Repo, :postgres_version}, version)
 108   end
 109
 110   def load_custom_modules do
 111     dir = Config.get([:modules, :runtime_dir])
 112
 113     if dir && File.exists?(dir) do
 114       dir
 115       |> Pleroma.Utils.compile_dir()
 116       |> case do
 117         {:error, _errors, _warnings} ->
 118           raise "Invalid custom modules"
 119
 120         {:ok, modules, _warnings} ->
 121           if @mix_env != :test do
 122             Enum.each(modules, fn mod ->
 123               Logger.info("Custom module loaded: #{inspect(mod)}")
 124             end)
 125           end
 126
 127           :ok
 128       end
 129     end
 130   end
 131
 132   defp setup_instrumenters do
 133     require Prometheus.Registry
 134
 135     if Application.get_env(:prometheus, Pleroma.Repo.Instrumenter) do
 136       :ok =
 137         :telemetry.attach(
 138           "prometheus-ecto",
 139           [:pleroma, :repo, :query],
 140           &Pleroma.Repo.Instrumenter.handle_event/4,
 141           %{}
 142         )
 143
 144       Pleroma.Repo.Instrumenter.setup()
 145     end
 146
 147     Pleroma.Web.Endpoint.MetricsExporter.setup()
 148     Pleroma.Web.Endpoint.PipelineInstrumenter.setup()
 149
 150     # Note: disabled until prometheus-phx is integrated into prometheus-phoenix:
 151     # Pleroma.Web.Endpoint.Instrumenter.setup()
 152     PrometheusPhx.setup()
 153   end
 154
 155   defp cachex_children do
 156     [
 157       build_cachex("used_captcha", ttl_interval: seconds_valid_interval()),
 158       build_cachex("user", default_ttl: 25_000, ttl_interval: 1000, limit: 2500),
 159       build_cachex("object", default_ttl: 25_000, ttl_interval: 1000, limit: 2500),
 160       build_cachex("rich_media", default_ttl: :timer.minutes(120), limit: 5000),
 161       build_cachex("scrubber", limit: 2500),
 162       build_cachex("idempotency", expiration: idempotency_expiration(), limit: 2500),
 163       build_cachex("web_resp", limit: 2500),
 164       build_cachex("emoji_packs", expiration: emoji_packs_expiration(), limit: 10),
 165       build_cachex("failed_proxy_url", limit: 2500),
 166       build_cachex("banned_urls", default_ttl: :timer.hours(24 * 30), limit: 5_000),
 167       build_cachex("chat_message_id_idempotency_key",
 168         expiration: chat_message_id_idempotency_key_expiration(),
 169         limit: 500_000
 170       )
 171     ]
 172   end
 173
 174   defp emoji_packs_expiration,
 175     do: expiration(default: :timer.seconds(5 * 60), interval: :timer.seconds(60))
 176
 177   defp idempotency_expiration,
 178     do: expiration(default: :timer.seconds(6 * 60 * 60), interval: :timer.seconds(60))
 179
 180   defp chat_message_id_idempotency_key_expiration,
 181     do: expiration(default: :timer.minutes(2), interval: :timer.seconds(60))
 182
 183   defp seconds_valid_interval,
 184     do: :timer.seconds(Config.get!([Pleroma.Captcha, :seconds_valid]))
 185
 186   @spec build_cachex(String.t(), keyword()) :: map()
 187   def build_cachex(type, opts),
 188     do: %{
 189       id: String.to_atom("cachex_" <> type),
 190       start: {Cachex, :start_link, [String.to_atom(type <> "_cache"), opts]},
 191       type: :worker
 192     }
 193
 194   defp shout_enabled?, do: Config.get([:shout, :enabled])
 195
 196   defp dont_run_in_test(env) when env in [:test, :benchmark], do: []
 197
 198   defp dont_run_in_test(_) do
 199     [
 200       {Registry,
 201        [
 202          name: Pleroma.Web.Streamer.registry(),
 203          keys: :duplicate,
 204          partitions: System.schedulers_online()
 205        ]}
 206     ] ++ background_migrators()
 207   end
 208
 209   defp background_migrators do
 210     [
 211       Pleroma.Migrators.HashtagsTableMigrator
 212     ]
 213   end
 214
 215   defp shout_child(true) do
 216     [
 217       Pleroma.Web.ShoutChannel.ShoutChannelState,
 218       {Phoenix.PubSub, [name: Pleroma.PubSub, adapter: Phoenix.PubSub.PG2]}
 219     ]
 220   end
 221
 222   defp shout_child(_), do: []
 223
 224   defp task_children(:test) do
 225     [
 226       %{
 227         id: :web_push_init,
 228         start: {Task, :start_link, [&Pleroma.Web.Push.init/0]},
 229         restart: :temporary
 230       }
 231     ]
 232   end
 233
 234   defp task_children(_) do
 235     [
 236       %{
 237         id: :web_push_init,
 238         start: {Task, :start_link, [&Pleroma.Web.Push.init/0]},
 239         restart: :temporary
 240       },
 241       %{
 242         id: :internal_fetch_init,
 243         start: {Task, :start_link, [&Pleroma.Web.ActivityPub.InternalFetchActor.init/0]},
 244         restart: :temporary
 245       }
 246     ]
 247   end
 248
 249   def elasticsearch_children do
 250     config = Config.get([Pleroma.Search, :module])
 251
 252     if config == Pleroma.Search.Elasticsearch do
 253       [Pleroma.Search.Elasticsearch.Cluster]
 254     else
 255       []
 256     end
 257   end
 258
 259   @spec limiters_setup() :: :ok
 260   def limiters_setup do
 261     config = Config.get(ConcurrentLimiter, [])
 262
 263     [
 264       Pleroma.Web.RichMedia.Helpers,
 265       Pleroma.Web.ActivityPub.MRF.MediaProxyWarmingPolicy,
 266       Pleroma.Search
 267     ]
 268     |> Enum.each(fn module ->
 269       mod_config = Keyword.get(config, module, [])
 270
 271       max_running = Keyword.get(mod_config, :max_running, 5)
 272       max_waiting = Keyword.get(mod_config, :max_waiting, 5)
 273
 274       ConcurrentLimiter.new(module, max_running, max_waiting)
 275     end)
 276   end
 277
 278   defp http_children do
 279     config =
 280       [:http, :adapter]
 281       |> Config.get([])
 282       |> Keyword.put(:name, MyFinch)
 283
 284     [{Finch, config}]
 285   end
 286 end