git.squeep.com Git - akkoma/blob - lib/pleroma/application.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Application do
   6   import Cachex.Spec
   7   use Application
   8   require Logger
   9
  10   @name Mix.Project.config()[:name]
  11   @version Mix.Project.config()[:version]
  12   @repository Mix.Project.config()[:source_url]
  13   @env Mix.env()
  14
  15   def name, do: @name
  16   def version, do: @version
  17   def named_version, do: @name <> " " <> @version
  18   def repository, do: @repository
  19
  20   def user_agent do
  21     case Pleroma.Config.get([:http, :user_agent], :default) do
  22       :default ->
  23         info = "#{Pleroma.Web.base_url()} <#{Pleroma.Config.get([:instance, :email], "")}>"
  24         named_version() <> "; " <> info
  25
  26       custom ->
  27         custom
  28     end
  29   end
  30
  31   # See http://elixir-lang.org/docs/stable/elixir/Application.html
  32   # for more information on OTP Applications
  33   def start(_type, _args) do
  34     Pleroma.Config.DeprecationWarnings.warn()
  35     setup_instrumenters()
  36     load_custom_modules()
  37
  38     # Define workers and child supervisors to be supervised
  39     children =
  40       [
  41         Pleroma.Repo,
  42         Pleroma.Scheduler,
  43         Pleroma.Config.TransferTask,
  44         Pleroma.Emoji,
  45         Pleroma.Captcha,
  46         Pleroma.Daemons.ScheduledActivityDaemon,
  47         Pleroma.Daemons.ActivityExpirationDaemon,
  48         Pleroma.Plugs.RateLimiter.Supervisor
  49       ] ++
  50         cachex_children() ++
  51         hackney_pool_children() ++
  52         [
  53           Pleroma.Stats,
  54           Pleroma.JobQueueMonitor,
  55           {Oban, Pleroma.Config.get(Oban)}
  56         ] ++
  57         task_children(@env) ++
  58         oauth_cleanup_child(oauth_cleanup_enabled?()) ++
  59         streamer_child(@env) ++
  60         chat_child(@env, chat_enabled?()) ++
  61         [
  62           Pleroma.Web.Endpoint,
  63           Pleroma.Gopher.Server
  64         ]
  65
  66     # See http://elixir-lang.org/docs/stable/elixir/Supervisor.html
  67     # for other strategies and supported options
  68     opts = [strategy: :one_for_one, name: Pleroma.Supervisor]
  69     Supervisor.start_link(children, opts)
  70   end
  71
  72   def load_custom_modules do
  73     dir = Pleroma.Config.get([:modules, :runtime_dir])
  74
  75     if dir && File.exists?(dir) do
  76       dir
  77       |> Pleroma.Utils.compile_dir()
  78       |> case do
  79         {:error, _errors, _warnings} ->
  80           raise "Invalid custom modules"
  81
  82         {:ok, modules, _warnings} ->
  83           if @env != :test do
  84             Enum.each(modules, fn mod ->
  85               Logger.info("Custom module loaded: #{inspect(mod)}")
  86             end)
  87           end
  88
  89           :ok
  90       end
  91     end
  92   end
  93
  94   defp setup_instrumenters do
  95     require Prometheus.Registry
  96
  97     if Application.get_env(:prometheus, Pleroma.Repo.Instrumenter) do
  98       :ok =
  99         :telemetry.attach(
 100           "prometheus-ecto",
 101           [:pleroma, :repo, :query],
 102           &Pleroma.Repo.Instrumenter.handle_event/4,
 103           %{}
 104         )
 105
 106       Pleroma.Repo.Instrumenter.setup()
 107     end
 108
 109     Pleroma.Web.Endpoint.MetricsExporter.setup()
 110     Pleroma.Web.Endpoint.PipelineInstrumenter.setup()
 111     Pleroma.Web.Endpoint.Instrumenter.setup()
 112   end
 113
 114   def enabled_hackney_pools do
 115     [:media] ++
 116       if Application.get_env(:tesla, :adapter) == Tesla.Adapter.Hackney do
 117         [:federation]
 118       else
 119         []
 120       end ++
 121       if Pleroma.Config.get([Pleroma.Upload, :proxy_remote]) do
 122         [:upload]
 123       else
 124         []
 125       end
 126   end
 127
 128   defp cachex_children do
 129     [
 130       build_cachex("used_captcha", ttl_interval: seconds_valid_interval()),
 131       build_cachex("user", default_ttl: 25_000, ttl_interval: 1000, limit: 2500),
 132       build_cachex("object", default_ttl: 25_000, ttl_interval: 1000, limit: 2500),
 133       build_cachex("rich_media", default_ttl: :timer.minutes(120), limit: 5000),
 134       build_cachex("scrubber", limit: 2500),
 135       build_cachex("idempotency", expiration: idempotency_expiration(), limit: 2500),
 136       build_cachex("web_resp", limit: 2500),
 137       build_cachex("emoji_packs", expiration: emoji_packs_expiration(), limit: 10),
 138       build_cachex("failed_proxy_url", limit: 2500)
 139     ]
 140   end
 141
 142   defp emoji_packs_expiration,
 143     do: expiration(default: :timer.seconds(5 * 60), interval: :timer.seconds(60))
 144
 145   defp idempotency_expiration,
 146     do: expiration(default: :timer.seconds(6 * 60 * 60), interval: :timer.seconds(60))
 147
 148   defp seconds_valid_interval,
 149     do: :timer.seconds(Pleroma.Config.get!([Pleroma.Captcha, :seconds_valid]))
 150
 151   defp build_cachex(type, opts),
 152     do: %{
 153       id: String.to_atom("cachex_" <> type),
 154       start: {Cachex, :start_link, [String.to_atom(type <> "_cache"), opts]},
 155       type: :worker
 156     }
 157
 158   defp chat_enabled?, do: Pleroma.Config.get([:chat, :enabled])
 159
 160   defp oauth_cleanup_enabled?,
 161     do: Pleroma.Config.get([:oauth2, :clean_expired_tokens], false)
 162
 163   defp streamer_child(:test), do: []
 164
 165   defp streamer_child(_) do
 166     [Pleroma.Web.Streamer.supervisor()]
 167   end
 168
 169   defp oauth_cleanup_child(true),
 170     do: [Pleroma.Web.OAuth.Token.CleanWorker]
 171
 172   defp oauth_cleanup_child(_), do: []
 173
 174   defp chat_child(:test, _), do: []
 175
 176   defp chat_child(_env, true) do
 177     [Pleroma.Web.ChatChannel.ChatChannelState]
 178   end
 179
 180   defp chat_child(_, _), do: []
 181
 182   defp hackney_pool_children do
 183     for pool <- enabled_hackney_pools() do
 184       options = Pleroma.Config.get([:hackney_pools, pool])
 185       :hackney_pool.child_spec(pool, options)
 186     end
 187   end
 188
 189   defp task_children(:test) do
 190     [
 191       %{
 192         id: :web_push_init,
 193         start: {Task, :start_link, [&Pleroma.Web.Push.init/0]},
 194         restart: :temporary
 195       }
 196     ]
 197   end
 198
 199   defp task_children(_) do
 200     [
 201       %{
 202         id: :web_push_init,
 203         start: {Task, :start_link, [&Pleroma.Web.Push.init/0]},
 204         restart: :temporary
 205       },
 206       %{
 207         id: :internal_fetch_init,
 208         start: {Task, :start_link, [&Pleroma.Web.ActivityPub.InternalFetchActor.init/0]},
 209         restart: :temporary
 210       }
 211     ]
 212   end
 213 end