git.squeep.com Git - akkoma/blob - lib/pleroma/application.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Application do
   6   use Application
   7
   8   import Cachex.Spec
   9
  10   alias Pleroma.Config
  11
  12   require Logger
  13
  14   @name Mix.Project.config()[:name]
  15   @version Mix.Project.config()[:version]
  16   @repository Mix.Project.config()[:source_url]
  17   @mix_env Mix.env()
  18
  19   def name, do: @name
  20   def version, do: @version
  21   def named_version, do: @name <> " " <> @version
  22   def repository, do: @repository
  23
  24   def user_agent do
  25     if Process.whereis(Pleroma.Web.Endpoint) do
  26       case Config.get([:http, :user_agent], :default) do
  27         :default ->
  28           info = "#{Pleroma.Web.Endpoint.url()} <#{Config.get([:instance, :email], "")}>"
  29           named_version() <> "; " <> info
  30
  31         custom ->
  32           custom
  33       end
  34     else
  35       # fallback, if endpoint is not started yet
  36       "Pleroma Data Loader"
  37     end
  38   end
  39
  40   # See http://elixir-lang.org/docs/stable/elixir/Application.html
  41   # for more information on OTP Applications
  42   def start(_type, _args) do
  43     # Scrubbers are compiled at runtime and therefore will cause a conflict
  44     # every time the application is restarted, so we disable module
  45     # conflicts at runtime
  46     Code.compiler_options(ignore_module_conflict: true)
  47     # Disable warnings_as_errors at runtime, it breaks Phoenix live reload
  48     # due to protocol consolidation warnings
  49     Code.compiler_options(warnings_as_errors: false)
  50     Pleroma.Telemetry.Logger.attach()
  51     Config.Holder.save_default()
  52     Pleroma.HTML.compile_scrubbers()
  53     Pleroma.Config.Oban.warn()
  54     Config.DeprecationWarnings.warn()
  55     Pleroma.Web.Plugs.HTTPSecurityPlug.warn_if_disabled()
  56     Pleroma.ApplicationRequirements.verify!()
  57     setup_instrumenters()
  58     load_custom_modules()
  59     Pleroma.Docs.JSON.compile()
  60     limiters_setup()
  61
  62     adapter = Application.get_env(:tesla, :adapter)
  63
  64     if match?({Tesla.Adapter.Finch, _}, adapter) do
  65       Logger.info("Starting Finch")
  66       Finch.start_link(name: MyFinch)
  67     end
  68
  69     if adapter == Tesla.Adapter.Gun do
  70       if version = Pleroma.OTPVersion.version() do
  71         [major, minor] =
  72           version
  73           |> String.split(".")
  74           |> Enum.map(&String.to_integer/1)
  75           |> Enum.take(2)
  76
  77         if (major == 22 and minor < 2) or major < 22 do
  78           raise "
  79             !!!OTP VERSION WARNING!!!
  80             You are using gun adapter with OTP version #{version}, which doesn't support correct handling of unordered certificates chains. Please update your Erlang/OTP to at least 22.2.
  81             "
  82         end
  83       else
  84         raise "
  85           !!!OTP VERSION WARNING!!!
  86           To support correct handling of unordered certificates chains - OTP version must be > 22.2.
  87           "
  88       end
  89     end
  90
  91     # Define workers and child supervisors to be supervised
  92     children =
  93       [
  94         Pleroma.Repo,
  95         Config.TransferTask,
  96         Pleroma.Emoji,
  97         Pleroma.Web.Plugs.RateLimiter.Supervisor
  98       ] ++
  99         cachex_children() ++
 100         http_children(adapter, @mix_env) ++
 101         [
 102           Pleroma.Stats,
 103           Pleroma.JobQueueMonitor,
 104           {Majic.Pool, [name: Pleroma.MajicPool, pool_size: Config.get([:majic_pool, :size], 2)]},
 105           {Oban, Config.get(Oban)},
 106           Pleroma.Web.Endpoint
 107         ] ++
 108         task_children(@mix_env) ++
 109         dont_run_in_test(@mix_env) ++
 110         shout_child(shout_enabled?())
 111
 112     # See http://elixir-lang.org/docs/stable/elixir/Supervisor.html
 113     # for other strategies and supported options
 114     opts = [strategy: :one_for_one, name: Pleroma.Supervisor]
 115     result = Supervisor.start_link(children, opts)
 116
 117     set_postgres_server_version()
 118
 119     result
 120   end
 121
 122   defp set_postgres_server_version do
 123     version =
 124       with %{rows: [[version]]} <- Ecto.Adapters.SQL.query!(Pleroma.Repo, "show server_version"),
 125            {num, _} <- Float.parse(version) do
 126         num
 127       else
 128         e ->
 129           Logger.warn(
 130             "Could not get the postgres version: #{inspect(e)}.\nSetting the default value of 9.6"
 131           )
 132
 133           9.6
 134       end
 135
 136     :persistent_term.put({Pleroma.Repo, :postgres_version}, version)
 137   end
 138
 139   def load_custom_modules do
 140     dir = Config.get([:modules, :runtime_dir])
 141
 142     if dir && File.exists?(dir) do
 143       dir
 144       |> Pleroma.Utils.compile_dir()
 145       |> case do
 146         {:error, _errors, _warnings} ->
 147           raise "Invalid custom modules"
 148
 149         {:ok, modules, _warnings} ->
 150           if @mix_env != :test do
 151             Enum.each(modules, fn mod ->
 152               Logger.info("Custom module loaded: #{inspect(mod)}")
 153             end)
 154           end
 155
 156           :ok
 157       end
 158     end
 159   end
 160
 161   defp setup_instrumenters do
 162     require Prometheus.Registry
 163
 164     if Application.get_env(:prometheus, Pleroma.Repo.Instrumenter) do
 165       :ok =
 166         :telemetry.attach(
 167           "prometheus-ecto",
 168           [:pleroma, :repo, :query],
 169           &Pleroma.Repo.Instrumenter.handle_event/4,
 170           %{}
 171         )
 172
 173       Pleroma.Repo.Instrumenter.setup()
 174     end
 175
 176     Pleroma.Web.Endpoint.MetricsExporter.setup()
 177     Pleroma.Web.Endpoint.PipelineInstrumenter.setup()
 178
 179     # Note: disabled until prometheus-phx is integrated into prometheus-phoenix:
 180     # Pleroma.Web.Endpoint.Instrumenter.setup()
 181     PrometheusPhx.setup()
 182   end
 183
 184   defp cachex_children do
 185     [
 186       build_cachex("used_captcha", ttl_interval: seconds_valid_interval()),
 187       build_cachex("user", default_ttl: 25_000, ttl_interval: 1000, limit: 2500),
 188       build_cachex("object", default_ttl: 25_000, ttl_interval: 1000, limit: 2500),
 189       build_cachex("rich_media", default_ttl: :timer.minutes(120), limit: 5000),
 190       build_cachex("scrubber", limit: 2500),
 191       build_cachex("idempotency", expiration: idempotency_expiration(), limit: 2500),
 192       build_cachex("web_resp", limit: 2500),
 193       build_cachex("emoji_packs", expiration: emoji_packs_expiration(), limit: 10),
 194       build_cachex("failed_proxy_url", limit: 2500),
 195       build_cachex("banned_urls", default_ttl: :timer.hours(24 * 30), limit: 5_000),
 196       build_cachex("chat_message_id_idempotency_key",
 197         expiration: chat_message_id_idempotency_key_expiration(),
 198         limit: 500_000
 199       )
 200     ]
 201   end
 202
 203   defp emoji_packs_expiration,
 204     do: expiration(default: :timer.seconds(5 * 60), interval: :timer.seconds(60))
 205
 206   defp idempotency_expiration,
 207     do: expiration(default: :timer.seconds(6 * 60 * 60), interval: :timer.seconds(60))
 208
 209   defp chat_message_id_idempotency_key_expiration,
 210     do: expiration(default: :timer.minutes(2), interval: :timer.seconds(60))
 211
 212   defp seconds_valid_interval,
 213     do: :timer.seconds(Config.get!([Pleroma.Captcha, :seconds_valid]))
 214
 215   @spec build_cachex(String.t(), keyword()) :: map()
 216   def build_cachex(type, opts),
 217     do: %{
 218       id: String.to_atom("cachex_" <> type),
 219       start: {Cachex, :start_link, [String.to_atom(type <> "_cache"), opts]},
 220       type: :worker
 221     }
 222
 223   defp shout_enabled?, do: Config.get([:shout, :enabled])
 224
 225   defp dont_run_in_test(env) when env in [:test, :benchmark], do: []
 226
 227   defp dont_run_in_test(_) do
 228     [
 229       {Registry,
 230        [
 231          name: Pleroma.Web.Streamer.registry(),
 232          keys: :duplicate,
 233          partitions: System.schedulers_online()
 234        ]}
 235     ] ++ background_migrators()
 236   end
 237
 238   defp background_migrators do
 239     [
 240       Pleroma.Migrators.HashtagsTableMigrator
 241     ]
 242   end
 243
 244   defp shout_child(true) do
 245     [
 246       Pleroma.Web.ShoutChannel.ShoutChannelState,
 247       {Phoenix.PubSub, [name: Pleroma.PubSub, adapter: Phoenix.PubSub.PG2]}
 248     ]
 249   end
 250
 251   defp shout_child(_), do: []
 252
 253   defp task_children(:test) do
 254     [
 255       %{
 256         id: :web_push_init,
 257         start: {Task, :start_link, [&Pleroma.Web.Push.init/0]},
 258         restart: :temporary
 259       }
 260     ]
 261   end
 262
 263   defp task_children(_) do
 264     [
 265       %{
 266         id: :web_push_init,
 267         start: {Task, :start_link, [&Pleroma.Web.Push.init/0]},
 268         restart: :temporary
 269       },
 270       %{
 271         id: :internal_fetch_init,
 272         start: {Task, :start_link, [&Pleroma.Web.ActivityPub.InternalFetchActor.init/0]},
 273         restart: :temporary
 274       }
 275     ]
 276   end
 277
 278   # start hackney and gun pools in tests
 279   defp http_children(_, :test) do
 280     http_children(Tesla.Adapter.Hackney, nil) ++ http_children(Tesla.Adapter.Gun, nil)
 281   end
 282
 283   defp http_children(Tesla.Adapter.Hackney, _) do
 284     pools = [:federation, :media]
 285
 286     pools =
 287       if Config.get([Pleroma.Upload, :proxy_remote]) do
 288         [:upload | pools]
 289       else
 290         pools
 291       end
 292
 293     for pool <- pools do
 294       options = Config.get([:hackney_pools, pool])
 295       :hackney_pool.child_spec(pool, options)
 296     end
 297   end
 298
 299   defp http_children(Tesla.Adapter.Gun, _) do
 300     Pleroma.Gun.ConnectionPool.children() ++
 301       [{Task, &Pleroma.HTTP.AdapterHelper.Gun.limiter_setup/0}]
 302   end
 303
 304   defp http_children(_, _), do: []
 305
 306   @spec limiters_setup() :: :ok
 307   def limiters_setup do
 308     config = Config.get(ConcurrentLimiter, [])
 309
 310     [Pleroma.Web.RichMedia.Helpers, Pleroma.Web.ActivityPub.MRF.MediaProxyWarmingPolicy]
 311     |> Enum.each(fn module ->
 312       mod_config = Keyword.get(config, module, [])
 313
 314       max_running = Keyword.get(mod_config, :max_running, 5)
 315       max_waiting = Keyword.get(mod_config, :max_waiting, 5)
 316
 317       ConcurrentLimiter.new(module, max_running, max_waiting)
 318     end)
 319   end
 320 end