git.squeep.com Git - akkoma/blob - lib/pleroma/application.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Application do
   6   import Cachex.Spec
   7   use Application
   8
   9   @name Mix.Project.config()[:name]
  10   @version Mix.Project.config()[:version]
  11   @repository Mix.Project.config()[:source_url]
  12   @env Mix.env()
  13
  14   def name, do: @name
  15   def version, do: @version
  16   def named_version, do: @name <> " " <> @version
  17   def repository, do: @repository
  18
  19   def user_agent do
  20     info = "#{Pleroma.Web.base_url()} <#{Pleroma.Config.get([:instance, :email], "")}>"
  21     named_version() <> "; " <> info
  22   end
  23
  24   # See http://elixir-lang.org/docs/stable/elixir/Application.html
  25   # for more information on OTP Applications
  26   def start(_type, _args) do
  27     Pleroma.Config.DeprecationWarnings.warn()
  28     setup_instrumenters()
  29
  30     # Define workers and child supervisors to be supervised
  31     children =
  32       [
  33         Pleroma.Repo,
  34         Pleroma.Scheduler,
  35         Pleroma.Config.TransferTask,
  36         Pleroma.Emoji,
  37         Pleroma.Captcha,
  38         Pleroma.FlakeId,
  39         Pleroma.ScheduledActivityWorker
  40       ] ++
  41         cachex_children() ++
  42         hackney_pool_children() ++
  43         [
  44           Pleroma.Stats,
  45           {Oban, Application.get_env(:pleroma, Oban)},
  46           %{
  47             id: :web_push_init,
  48             start: {Task, :start_link, [&Pleroma.Web.Push.init/0]},
  49             restart: :temporary
  50           },
  51           %{
  52             id: :federator_init,
  53             start: {Task, :start_link, [&Pleroma.Web.Federator.init/0]},
  54             restart: :temporary
  55           },
  56           %{
  57             id: :internal_fetch_init,
  58             start: {Task, :start_link, [&Pleroma.Web.ActivityPub.InternalFetchActor.init/0]},
  59             restart: :temporary
  60           }
  61         ] ++
  62         oauth_cleanup_child(oauth_cleanup_enabled?()) ++
  63         streamer_child(@env) ++
  64         chat_child(@env, chat_enabled?()) ++
  65         [
  66           Pleroma.Web.Endpoint,
  67           Pleroma.Gopher.Server
  68         ]
  69
  70     # See http://elixir-lang.org/docs/stable/elixir/Supervisor.html
  71     # for other strategies and supported options
  72     opts = [strategy: :one_for_one, name: Pleroma.Supervisor]
  73     Supervisor.start_link(children, opts)
  74   end
  75
  76   defp setup_instrumenters do
  77     require Prometheus.Registry
  78
  79     if Application.get_env(:prometheus, Pleroma.Repo.Instrumenter) do
  80       :ok =
  81         :telemetry.attach(
  82           "prometheus-ecto",
  83           [:pleroma, :repo, :query],
  84           &Pleroma.Repo.Instrumenter.handle_event/4,
  85           %{}
  86         )
  87
  88       Pleroma.Repo.Instrumenter.setup()
  89     end
  90
  91     Pleroma.Web.Endpoint.MetricsExporter.setup()
  92     Pleroma.Web.Endpoint.PipelineInstrumenter.setup()
  93     Pleroma.Web.Endpoint.Instrumenter.setup()
  94   end
  95
  96   def enabled_hackney_pools do
  97     [:media] ++
  98       if Application.get_env(:tesla, :adapter) == Tesla.Adapter.Hackney do
  99         [:federation]
 100       else
 101         []
 102       end ++
 103       if Pleroma.Config.get([Pleroma.Upload, :proxy_remote]) do
 104         [:upload]
 105       else
 106         []
 107       end
 108   end
 109
 110   defp cachex_children do
 111     [
 112       build_cachex("used_captcha", ttl_interval: seconds_valid_interval()),
 113       build_cachex("user", default_ttl: 25_000, ttl_interval: 1000, limit: 2500),
 114       build_cachex("object", default_ttl: 25_000, ttl_interval: 1000, limit: 2500),
 115       build_cachex("rich_media", default_ttl: :timer.minutes(120), limit: 5000),
 116       build_cachex("scrubber", limit: 2500),
 117       build_cachex("idempotency", expiration: idempotency_expiration(), limit: 2500)
 118     ]
 119   end
 120
 121   defp idempotency_expiration,
 122     do: expiration(default: :timer.seconds(6 * 60 * 60), interval: :timer.seconds(60))
 123
 124   defp seconds_valid_interval,
 125     do: :timer.seconds(Pleroma.Config.get!([Pleroma.Captcha, :seconds_valid]))
 126
 127   defp build_cachex(type, opts),
 128     do: %{
 129       id: String.to_atom("cachex_" <> type),
 130       start: {Cachex, :start_link, [String.to_atom(type <> "_cache"), opts]},
 131       type: :worker
 132     }
 133
 134   defp chat_enabled?, do: Pleroma.Config.get([:chat, :enabled])
 135
 136   defp oauth_cleanup_enabled?,
 137     do: Pleroma.Config.get([:oauth2, :clean_expired_tokens], false)
 138
 139   defp streamer_child(:test), do: []
 140
 141   defp streamer_child(_) do
 142     [Pleroma.Web.Streamer]
 143   end
 144
 145   defp oauth_cleanup_child(true),
 146     do: [Pleroma.Web.OAuth.Token.CleanWorker]
 147
 148   defp oauth_cleanup_child(_), do: []
 149
 150   defp chat_child(:test, _), do: []
 151
 152   defp chat_child(_env, true) do
 153     [Pleroma.Web.ChatChannel.ChatChannelState]
 154   end
 155
 156   defp chat_child(_, _), do: []
 157
 158   defp hackney_pool_children do
 159     for pool <- enabled_hackney_pools() do
 160       options = Pleroma.Config.get([:hackney_pools, pool])
 161       :hackney_pool.child_spec(pool, options)
 162     end
 163   end
 164 end