git.squeep.com Git - akkoma/blob - lib/pleroma/application.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Application do
   6   import Cachex.Spec
   7   use Application
   8   require Logger
   9
  10   @name Mix.Project.config()[:name]
  11   @version Mix.Project.config()[:version]
  12   @repository Mix.Project.config()[:source_url]
  13   @env Mix.env()
  14
  15   def name, do: @name
  16   def version, do: @version
  17   def named_version, do: @name <> " " <> @version
  18   def repository, do: @repository
  19
  20   def user_agent do
  21     case Pleroma.Config.get([:http, :user_agent], :default) do
  22       :default ->
  23         info = "#{Pleroma.Web.base_url()} <#{Pleroma.Config.get([:instance, :email], "")}>"
  24         named_version() <> "; " <> info
  25
  26       custom ->
  27         custom
  28     end
  29   end
  30
  31   # See http://elixir-lang.org/docs/stable/elixir/Application.html
  32   # for more information on OTP Applications
  33   def start(_type, _args) do
  34     Pleroma.HTML.compile_scrubbers()
  35     Pleroma.Config.DeprecationWarnings.warn()
  36     setup_instrumenters()
  37     load_custom_modules()
  38
  39     # Define workers and child supervisors to be supervised
  40     children =
  41       [
  42         Pleroma.Repo,
  43         Pleroma.Config.TransferTask,
  44         Pleroma.Emoji,
  45         Pleroma.Captcha,
  46         Pleroma.Plugs.RateLimiter.Supervisor
  47       ] ++
  48         cachex_children() ++
  49         hackney_pool_children() ++
  50         [
  51           Pleroma.Stats,
  52           Pleroma.JobQueueMonitor,
  53           {Oban, Pleroma.Config.get(Oban)}
  54         ] ++
  55         task_children(@env) ++
  56         streamer_child(@env) ++
  57         chat_child(@env, chat_enabled?()) ++
  58         [
  59           Pleroma.Web.Endpoint,
  60           Pleroma.Gopher.Server
  61         ]
  62
  63     # See http://elixir-lang.org/docs/stable/elixir/Supervisor.html
  64     # for other strategies and supported options
  65     opts = [strategy: :one_for_one, name: Pleroma.Supervisor]
  66     Supervisor.start_link(children, opts)
  67   end
  68
  69   def load_custom_modules do
  70     dir = Pleroma.Config.get([:modules, :runtime_dir])
  71
  72     if dir && File.exists?(dir) do
  73       dir
  74       |> Pleroma.Utils.compile_dir()
  75       |> case do
  76         {:error, _errors, _warnings} ->
  77           raise "Invalid custom modules"
  78
  79         {:ok, modules, _warnings} ->
  80           if @env != :test do
  81             Enum.each(modules, fn mod ->
  82               Logger.info("Custom module loaded: #{inspect(mod)}")
  83             end)
  84           end
  85
  86           :ok
  87       end
  88     end
  89   end
  90
  91   defp setup_instrumenters do
  92     require Prometheus.Registry
  93
  94     if Application.get_env(:prometheus, Pleroma.Repo.Instrumenter) do
  95       :ok =
  96         :telemetry.attach(
  97           "prometheus-ecto",
  98           [:pleroma, :repo, :query],
  99           &Pleroma.Repo.Instrumenter.handle_event/4,
 100           %{}
 101         )
 102
 103       Pleroma.Repo.Instrumenter.setup()
 104     end
 105
 106     Pleroma.Web.Endpoint.MetricsExporter.setup()
 107     Pleroma.Web.Endpoint.PipelineInstrumenter.setup()
 108     Pleroma.Web.Endpoint.Instrumenter.setup()
 109   end
 110
 111   def enabled_hackney_pools do
 112     [:media] ++
 113       if Application.get_env(:tesla, :adapter) == Tesla.Adapter.Hackney do
 114         [:federation]
 115       else
 116         []
 117       end ++
 118       if Pleroma.Config.get([Pleroma.Upload, :proxy_remote]) do
 119         [:upload]
 120       else
 121         []
 122       end
 123   end
 124
 125   defp cachex_children do
 126     [
 127       build_cachex("used_captcha", ttl_interval: seconds_valid_interval()),
 128       build_cachex("user", default_ttl: 25_000, ttl_interval: 1000, limit: 2500),
 129       build_cachex("object", default_ttl: 25_000, ttl_interval: 1000, limit: 2500),
 130       build_cachex("rich_media", default_ttl: :timer.minutes(120), limit: 5000),
 131       build_cachex("scrubber", limit: 2500),
 132       build_cachex("idempotency", expiration: idempotency_expiration(), limit: 2500),
 133       build_cachex("web_resp", limit: 2500),
 134       build_cachex("emoji_packs", expiration: emoji_packs_expiration(), limit: 10),
 135       build_cachex("failed_proxy_url", limit: 2500)
 136     ]
 137   end
 138
 139   defp emoji_packs_expiration,
 140     do: expiration(default: :timer.seconds(5 * 60), interval: :timer.seconds(60))
 141
 142   defp idempotency_expiration,
 143     do: expiration(default: :timer.seconds(6 * 60 * 60), interval: :timer.seconds(60))
 144
 145   defp seconds_valid_interval,
 146     do: :timer.seconds(Pleroma.Config.get!([Pleroma.Captcha, :seconds_valid]))
 147
 148   defp build_cachex(type, opts),
 149     do: %{
 150       id: String.to_atom("cachex_" <> type),
 151       start: {Cachex, :start_link, [String.to_atom(type <> "_cache"), opts]},
 152       type: :worker
 153     }
 154
 155   defp chat_enabled?, do: Pleroma.Config.get([:chat, :enabled])
 156
 157   defp streamer_child(:test), do: []
 158
 159   defp streamer_child(_) do
 160     [Pleroma.Web.Streamer.supervisor()]
 161   end
 162
 163   defp chat_child(_env, true) do
 164     [Pleroma.Web.ChatChannel.ChatChannelState]
 165   end
 166
 167   defp chat_child(_, _), do: []
 168
 169   defp hackney_pool_children do
 170     for pool <- enabled_hackney_pools() do
 171       options = Pleroma.Config.get([:hackney_pools, pool])
 172       :hackney_pool.child_spec(pool, options)
 173     end
 174   end
 175
 176   defp task_children(:test) do
 177     [
 178       %{
 179         id: :web_push_init,
 180         start: {Task, :start_link, [&Pleroma.Web.Push.init/0]},
 181         restart: :temporary
 182       }
 183     ]
 184   end
 185
 186   defp task_children(_) do
 187     [
 188       %{
 189         id: :web_push_init,
 190         start: {Task, :start_link, [&Pleroma.Web.Push.init/0]},
 191         restart: :temporary
 192       },
 193       %{
 194         id: :internal_fetch_init,
 195         start: {Task, :start_link, [&Pleroma.Web.ActivityPub.InternalFetchActor.init/0]},
 196         restart: :temporary
 197       }
 198     ]
 199   end
 200 end