git.squeep.com Git - akkoma/blob - lib/pleroma/application.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Application do
   6   import Cachex.Spec
   7   use Application
   8
   9   @name Mix.Project.config()[:name]
  10   @version Mix.Project.config()[:version]
  11   @repository Mix.Project.config()[:source_url]
  12   @env Mix.env()
  13
  14   def name, do: @name
  15   def version, do: @version
  16   def named_version, do: @name <> " " <> @version
  17   def repository, do: @repository
  18
  19   def user_agent do
  20     info = "#{Pleroma.Web.base_url()} <#{Pleroma.Config.get([:instance, :email], "")}>"
  21     named_version() <> "; " <> info
  22   end
  23
  24   # See http://elixir-lang.org/docs/stable/elixir/Application.html
  25   # for more information on OTP Applications
  26   def start(_type, _args) do
  27     Pleroma.Config.DeprecationWarnings.warn()
  28     setup_instrumenters()
  29
  30     # Define workers and child supervisors to be supervised
  31     children =
  32       [
  33         Pleroma.Repo,
  34         Pleroma.Config.TransferTask,
  35         Pleroma.Emoji,
  36         Pleroma.Captcha,
  37         Pleroma.Plugs.RateLimiter.Supervisor
  38       ] ++
  39         cachex_children() ++
  40         hackney_pool_children() ++
  41         [
  42           Pleroma.Stats,
  43           Pleroma.JobQueueMonitor,
  44           {Oban, Pleroma.Config.get(Oban)}
  45         ] ++
  46         task_children(@env) ++
  47         streamer_child(@env) ++
  48         chat_child(@env, chat_enabled?()) ++
  49         [
  50           Pleroma.Web.Endpoint,
  51           Pleroma.Gopher.Server
  52         ]
  53
  54     # See http://elixir-lang.org/docs/stable/elixir/Supervisor.html
  55     # for other strategies and supported options
  56     opts = [strategy: :one_for_one, name: Pleroma.Supervisor]
  57     Supervisor.start_link(children, opts)
  58   end
  59
  60   defp setup_instrumenters do
  61     require Prometheus.Registry
  62
  63     if Application.get_env(:prometheus, Pleroma.Repo.Instrumenter) do
  64       :ok =
  65         :telemetry.attach(
  66           "prometheus-ecto",
  67           [:pleroma, :repo, :query],
  68           &Pleroma.Repo.Instrumenter.handle_event/4,
  69           %{}
  70         )
  71
  72       Pleroma.Repo.Instrumenter.setup()
  73     end
  74
  75     Pleroma.Web.Endpoint.MetricsExporter.setup()
  76     Pleroma.Web.Endpoint.PipelineInstrumenter.setup()
  77     Pleroma.Web.Endpoint.Instrumenter.setup()
  78   end
  79
  80   def enabled_hackney_pools do
  81     [:media] ++
  82       if Application.get_env(:tesla, :adapter) == Tesla.Adapter.Hackney do
  83         [:federation]
  84       else
  85         []
  86       end ++
  87       if Pleroma.Config.get([Pleroma.Upload, :proxy_remote]) do
  88         [:upload]
  89       else
  90         []
  91       end
  92   end
  93
  94   defp cachex_children do
  95     [
  96       build_cachex("used_captcha", ttl_interval: seconds_valid_interval()),
  97       build_cachex("user", default_ttl: 25_000, ttl_interval: 1000, limit: 2500),
  98       build_cachex("object", default_ttl: 25_000, ttl_interval: 1000, limit: 2500),
  99       build_cachex("rich_media", default_ttl: :timer.minutes(120), limit: 5000),
 100       build_cachex("scrubber", limit: 2500),
 101       build_cachex("idempotency", expiration: idempotency_expiration(), limit: 2500),
 102       build_cachex("web_resp", limit: 2500),
 103       build_cachex("emoji_packs", expiration: emoji_packs_expiration(), limit: 10),
 104       build_cachex("failed_proxy_url", limit: 2500)
 105     ]
 106   end
 107
 108   defp emoji_packs_expiration,
 109     do: expiration(default: :timer.seconds(5 * 60), interval: :timer.seconds(60))
 110
 111   defp idempotency_expiration,
 112     do: expiration(default: :timer.seconds(6 * 60 * 60), interval: :timer.seconds(60))
 113
 114   defp seconds_valid_interval,
 115     do: :timer.seconds(Pleroma.Config.get!([Pleroma.Captcha, :seconds_valid]))
 116
 117   defp build_cachex(type, opts),
 118     do: %{
 119       id: String.to_atom("cachex_" <> type),
 120       start: {Cachex, :start_link, [String.to_atom(type <> "_cache"), opts]},
 121       type: :worker
 122     }
 123
 124   defp chat_enabled?, do: Pleroma.Config.get([:chat, :enabled])
 125
 126   defp streamer_child(:test), do: []
 127
 128   defp streamer_child(_) do
 129     [Pleroma.Web.Streamer.supervisor()]
 130   end
 131
 132   defp chat_child(:test, _), do: []
 133
 134   defp chat_child(_env, true) do
 135     [Pleroma.Web.ChatChannel.ChatChannelState]
 136   end
 137
 138   defp chat_child(_, _), do: []
 139
 140   defp hackney_pool_children do
 141     for pool <- enabled_hackney_pools() do
 142       options = Pleroma.Config.get([:hackney_pools, pool])
 143       :hackney_pool.child_spec(pool, options)
 144     end
 145   end
 146
 147   defp task_children(:test) do
 148     [
 149       %{
 150         id: :web_push_init,
 151         start: {Task, :start_link, [&Pleroma.Web.Push.init/0]},
 152         restart: :temporary
 153       }
 154     ]
 155   end
 156
 157   defp task_children(_) do
 158     [
 159       %{
 160         id: :web_push_init,
 161         start: {Task, :start_link, [&Pleroma.Web.Push.init/0]},
 162         restart: :temporary
 163       },
 164       %{
 165         id: :internal_fetch_init,
 166         start: {Task, :start_link, [&Pleroma.Web.ActivityPub.InternalFetchActor.init/0]},
 167         restart: :temporary
 168       }
 169     ]
 170   end
 171 end