git.squeep.com Git - akkoma/blob - lib/pleroma/application.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Application do
   6   import Cachex.Spec
   7   use Application
   8
   9   @name Mix.Project.config()[:name]
  10   @version Mix.Project.config()[:version]
  11   @repository Mix.Project.config()[:source_url]
  12   @env Mix.env()
  13
  14   def name, do: @name
  15   def version, do: @version
  16   def named_version, do: @name <> " " <> @version
  17   def repository, do: @repository
  18
  19   def user_agent do
  20     info = "#{Pleroma.Web.base_url()} <#{Pleroma.Config.get([:instance, :email], "")}>"
  21     named_version() <> "; " <> info
  22   end
  23
  24   # See http://elixir-lang.org/docs/stable/elixir/Application.html
  25   # for more information on OTP Applications
  26   def start(_type, _args) do
  27     Pleroma.Config.DeprecationWarnings.warn()
  28     setup_instrumenters()
  29
  30     # Define workers and child supervisors to be supervised
  31     children =
  32       [
  33         Pleroma.Repo,
  34         Pleroma.Scheduler,
  35         Pleroma.Config.TransferTask,
  36         Pleroma.Emoji,
  37         Pleroma.Captcha,
  38         Pleroma.FlakeId,
  39         Pleroma.Daemons.ScheduledActivityDaemon,
  40         Pleroma.Daemons.ActivityExpirationDaemon
  41       ] ++
  42         cachex_children() ++
  43         hackney_pool_children() ++
  44         [
  45           Pleroma.Stats,
  46           {Oban, Pleroma.Config.get(Oban)},
  47           %{
  48             id: :web_push_init,
  49             start: {Task, :start_link, [&Pleroma.Web.Push.init/0]},
  50             restart: :temporary
  51           },
  52           %{
  53             id: :federator_init,
  54             start: {Task, :start_link, [&Pleroma.Web.Federator.init/0]},
  55             restart: :temporary
  56           },
  57           %{
  58             id: :internal_fetch_init,
  59             start: {Task, :start_link, [&Pleroma.Web.ActivityPub.InternalFetchActor.init/0]},
  60             restart: :temporary
  61           }
  62         ] ++
  63         oauth_cleanup_child(oauth_cleanup_enabled?()) ++
  64         streamer_child(@env) ++
  65         chat_child(@env, chat_enabled?()) ++
  66         [
  67           Pleroma.Web.Endpoint,
  68           Pleroma.Gopher.Server
  69         ]
  70
  71     # See http://elixir-lang.org/docs/stable/elixir/Supervisor.html
  72     # for other strategies and supported options
  73     opts = [strategy: :one_for_one, name: Pleroma.Supervisor]
  74     Supervisor.start_link(children, opts)
  75   end
  76
  77   defp setup_instrumenters do
  78     require Prometheus.Registry
  79
  80     if Application.get_env(:prometheus, Pleroma.Repo.Instrumenter) do
  81       :ok =
  82         :telemetry.attach(
  83           "prometheus-ecto",
  84           [:pleroma, :repo, :query],
  85           &Pleroma.Repo.Instrumenter.handle_event/4,
  86           %{}
  87         )
  88
  89       Pleroma.Repo.Instrumenter.setup()
  90     end
  91
  92     Pleroma.Web.Endpoint.MetricsExporter.setup()
  93     Pleroma.Web.Endpoint.PipelineInstrumenter.setup()
  94     Pleroma.Web.Endpoint.Instrumenter.setup()
  95   end
  96
  97   def enabled_hackney_pools do
  98     [:media] ++
  99       if Application.get_env(:tesla, :adapter) == Tesla.Adapter.Hackney do
 100         [:federation]
 101       else
 102         []
 103       end ++
 104       if Pleroma.Config.get([Pleroma.Upload, :proxy_remote]) do
 105         [:upload]
 106       else
 107         []
 108       end
 109   end
 110
 111   defp cachex_children do
 112     [
 113       build_cachex("used_captcha", ttl_interval: seconds_valid_interval()),
 114       build_cachex("user", default_ttl: 25_000, ttl_interval: 1000, limit: 2500),
 115       build_cachex("object", default_ttl: 25_000, ttl_interval: 1000, limit: 2500),
 116       build_cachex("rich_media", default_ttl: :timer.minutes(120), limit: 5000),
 117       build_cachex("scrubber", limit: 2500),
 118       build_cachex("idempotency", expiration: idempotency_expiration(), limit: 2500),
 119       build_cachex("web_resp", limit: 2500)
 120     ]
 121   end
 122
 123   defp idempotency_expiration,
 124     do: expiration(default: :timer.seconds(6 * 60 * 60), interval: :timer.seconds(60))
 125
 126   defp seconds_valid_interval,
 127     do: :timer.seconds(Pleroma.Config.get!([Pleroma.Captcha, :seconds_valid]))
 128
 129   defp build_cachex(type, opts),
 130     do: %{
 131       id: String.to_atom("cachex_" <> type),
 132       start: {Cachex, :start_link, [String.to_atom(type <> "_cache"), opts]},
 133       type: :worker
 134     }
 135
 136   defp chat_enabled?, do: Pleroma.Config.get([:chat, :enabled])
 137
 138   defp oauth_cleanup_enabled?,
 139     do: Pleroma.Config.get([:oauth2, :clean_expired_tokens], false)
 140
 141   defp streamer_child(:test), do: []
 142
 143   defp streamer_child(_) do
 144     [Pleroma.Web.Streamer]
 145   end
 146
 147   defp oauth_cleanup_child(true),
 148     do: [Pleroma.Web.OAuth.Token.CleanWorker]
 149
 150   defp oauth_cleanup_child(_), do: []
 151
 152   defp chat_child(:test, _), do: []
 153
 154   defp chat_child(_env, true) do
 155     [Pleroma.Web.ChatChannel.ChatChannelState]
 156   end
 157
 158   defp chat_child(_, _), do: []
 159
 160   defp hackney_pool_children do
 161     for pool <- enabled_hackney_pools() do
 162       options = Pleroma.Config.get([:hackney_pools, pool])
 163       :hackney_pool.child_spec(pool, options)
 164     end
 165   end
 166 end