git.squeep.com Git - akkoma/blob - lib/pleroma/activity/search.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Activity.Search do
   6   alias Pleroma.Activity
   7   alias Pleroma.Object.Fetcher
   8   alias Pleroma.Pagination
   9   alias Pleroma.User
  10   alias Pleroma.Web.ActivityPub.Visibility
  11
  12   require Pleroma.Constants
  13
  14   import Ecto.Query
  15
  16   def search(user, search_query, options \\ []) do
  17     index_type = if Pleroma.Config.get([:database, :rum_enabled]), do: :rum, else: :gin
  18     limit = Enum.min([Keyword.get(options, :limit), 40])
  19     offset = Keyword.get(options, :offset, 0)
  20     author = Keyword.get(options, :author)
  21
  22     Activity
  23     |> Activity.with_preloaded_object()
  24     |> Activity.restrict_deactivated_users()
  25     |> restrict_public()
  26     |> query_with(index_type, search_query)
  27     |> maybe_restrict_local(user)
  28     |> maybe_restrict_author(author)
  29     |> Pagination.fetch_paginated(%{"offset" => offset, "limit" => limit}, :offset)
  30     |> Map.get(:items)
  31     |> maybe_fetch(user, search_query)
  32   end
  33
  34   def maybe_restrict_author(query, %User{} = author) do
  35     from([a, o] in query,
  36       where: a.actor == ^author.ap_id
  37     )
  38   end
  39
  40   def maybe_restrict_author(query, _), do: query
  41
  42   defp restrict_public(q) do
  43     from([a, o] in q,
  44       where: fragment("?->>'type' = 'Create'", a.data),
  45       where: ^Pleroma.Constants.as_public() in a.recipients
  46     )
  47   end
  48
  49   defp query_with(q, :gin, search_query) do
  50     from([a, o] in q,
  51       where:
  52         fragment(
  53           "to_tsvector('english', ?->>'content') @@ plainto_tsquery('english', ?)",
  54           o.data,
  55           ^search_query
  56         )
  57     )
  58   end
  59
  60   defp query_with(q, :rum, search_query) do
  61     from([a, o] in q,
  62       where:
  63         fragment(
  64           "? @@ plainto_tsquery('english', ?)",
  65           o.fts_content,
  66           ^search_query
  67         ),
  68       order_by: [fragment("? <=> now()::date", o.inserted_at)]
  69     )
  70   end
  71
  72   defp maybe_restrict_local(q, user) do
  73     limit = Pleroma.Config.get([:instance, :limit_to_local_content], :unauthenticated)
  74
  75     case {limit, user} do
  76       {:all, _} -> restrict_local(q)
  77       {:unauthenticated, %User{}} -> q
  78       {:unauthenticated, _} -> restrict_local(q)
  79       {false, _} -> q
  80     end
  81   end
  82
  83   defp restrict_local(q), do: where(q, local: true)
  84
  85   defp maybe_fetch(activities, user, search_query) do
  86     with true <- Regex.match?(~r/https?:/, search_query),
  87          {:ok, object} <- Fetcher.fetch_object_from_id(search_query),
  88          %Activity{} = activity <- Activity.get_create_by_object_ap_id(object.data["id"]),
  89          true <- Visibility.visible_for_user?(activity, user) do
  90       activities ++ [activity]
  91     else
  92       _ -> activities
  93     end
  94   end
  95 end