git.squeep.com Git - akkoma/blob - lib/pleroma/activity/search.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Activity.Search do
   6   alias Pleroma.Activity
   7   alias Pleroma.Object.Fetcher
   8   alias Pleroma.Pagination
   9   alias Pleroma.User
  10   alias Pleroma.Web.ActivityPub.Visibility
  11
  12   require Pleroma.Constants
  13
  14   import Ecto.Query
  15
  16   def search(user, search_query, options \\ []) do
  17     index_type = if Pleroma.Config.get([:database, :rum_enabled]), do: :rum, else: :gin
  18     limit = Enum.min([Keyword.get(options, :limit), 40])
  19     offset = Keyword.get(options, :offset, 0)
  20     author = Keyword.get(options, :author)
  21
  22     search_function =
  23       if :persistent_term.get({Pleroma.Repo, :postgres_version}) >= 11 do
  24         :websearch
  25       else
  26         :plain
  27       end
  28
  29     try do
  30       Activity
  31       |> Activity.with_preloaded_object()
  32       |> Activity.restrict_deactivated_users()
  33       |> restrict_public()
  34       |> query_with(index_type, search_query, search_function)
  35       |> maybe_restrict_local(user)
  36       |> maybe_restrict_author(author)
  37       |> maybe_restrict_blocked(user)
  38       |> Pagination.fetch_paginated(
  39         %{"offset" => offset, "limit" => limit, "skip_order" => index_type == :rum},
  40         :offset
  41       )
  42       |> maybe_fetch(user, search_query)
  43     rescue
  44       _ -> maybe_fetch([], user, search_query)
  45     end
  46   end
  47
  48   def maybe_restrict_author(query, %User{} = author) do
  49     Activity.Queries.by_author(query, author)
  50   end
  51
  52   def maybe_restrict_author(query, _), do: query
  53
  54   def maybe_restrict_blocked(query, %User{} = user) do
  55     Activity.Queries.exclude_authors(query, User.blocked_users_ap_ids(user))
  56   end
  57
  58   def maybe_restrict_blocked(query, _), do: query
  59
  60   defp restrict_public(q) do
  61     from([a, o] in q,
  62       where: fragment("?->>'type' = 'Create'", a.data),
  63       where: ^Pleroma.Constants.as_public() in a.recipients
  64     )
  65   end
  66
  67   defp query_with(q, :gin, search_query, :plain) do
  68     %{rows: [[tsc]]} =
  69       Ecto.Adapters.SQL.query!(
  70         Pleroma.Repo,
  71         "select current_setting('default_text_search_config')::regconfig::oid;"
  72       )
  73
  74     from([a, o] in q,
  75       where:
  76         fragment(
  77           "to_tsvector(?::oid::regconfig, ?->>'content') @@ plainto_tsquery(?)",
  78           ^tsc,
  79           o.data,
  80           ^search_query
  81         )
  82     )
  83   end
  84
  85   defp query_with(q, :gin, search_query, :websearch) do
  86     %{rows: [[tsc]]} =
  87       Ecto.Adapters.SQL.query!(
  88         Pleroma.Repo,
  89         "select current_setting('default_text_search_config')::regconfig::oid;"
  90       )
  91
  92     from([a, o] in q,
  93       where:
  94         fragment(
  95           "to_tsvector(?::oid::regconfig, ?->>'content') @@ websearch_to_tsquery(?)",
  96           ^tsc,
  97           o.data,
  98           ^search_query
  99         )
 100     )
 101   end
 102
 103   defp query_with(q, :rum, search_query, :plain) do
 104     from([a, o] in q,
 105       where:
 106         fragment(
 107           "? @@ plainto_tsquery(?)",
 108           o.fts_content,
 109           ^search_query
 110         ),
 111       order_by: [fragment("? <=> now()::date", o.inserted_at)]
 112     )
 113   end
 114
 115   defp query_with(q, :rum, search_query, :websearch) do
 116     from([a, o] in q,
 117       where:
 118         fragment(
 119           "? @@ websearch_to_tsquery(?)",
 120           o.fts_content,
 121           ^search_query
 122         ),
 123       order_by: [fragment("? <=> now()::date", o.inserted_at)]
 124     )
 125   end
 126
 127   defp maybe_restrict_local(q, user) do
 128     limit = Pleroma.Config.get([:instance, :limit_to_local_content], :unauthenticated)
 129
 130     case {limit, user} do
 131       {:all, _} -> restrict_local(q)
 132       {:unauthenticated, %User{}} -> q
 133       {:unauthenticated, _} -> restrict_local(q)
 134       {false, _} -> q
 135     end
 136   end
 137
 138   defp restrict_local(q), do: where(q, local: true)
 139
 140   defp maybe_fetch(activities, user, search_query) do
 141     with true <- Regex.match?(~r/https?:/, search_query),
 142          {:ok, object} <- Fetcher.fetch_object_from_id(search_query),
 143          %Activity{} = activity <- Activity.get_create_by_object_ap_id(object.data["id"]),
 144          true <- Visibility.visible_for_user?(activity, user) do
 145       [activity | activities]
 146     else
 147       _ -> activities
 148     end
 149   end
 150 end