git.squeep.com Git - akkoma/blob - lib/mix/tasks/pleroma/user.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Mix.Tasks.Pleroma.User do
   6   use Mix.Task
   7   import Mix.Pleroma
   8   alias Ecto.Changeset
   9   alias Pleroma.User
  10   alias Pleroma.UserInviteToken
  11   alias Pleroma.Web.ActivityPub.Builder
  12   alias Pleroma.Web.ActivityPub.Pipeline
  13
  14   @shortdoc "Manages Pleroma users"
  15   @moduledoc File.read!("docs/administration/CLI_tasks/user.md")
  16
  17   def run(["new", nickname, email | rest]) do
  18     {options, [], []} =
  19       OptionParser.parse(
  20         rest,
  21         strict: [
  22           name: :string,
  23           bio: :string,
  24           password: :string,
  25           moderator: :boolean,
  26           admin: :boolean,
  27           assume_yes: :boolean
  28         ],
  29         aliases: [
  30           y: :assume_yes
  31         ]
  32       )
  33
  34     name = Keyword.get(options, :name, nickname)
  35     bio = Keyword.get(options, :bio, "")
  36
  37     {password, generated_password?} =
  38       case Keyword.get(options, :password) do
  39         nil ->
  40           {:crypto.strong_rand_bytes(16) |> Base.encode64(), true}
  41
  42         password ->
  43           {password, false}
  44       end
  45
  46     moderator? = Keyword.get(options, :moderator, false)
  47     admin? = Keyword.get(options, :admin, false)
  48     assume_yes? = Keyword.get(options, :assume_yes, false)
  49
  50     shell_info("""
  51     A user will be created with the following information:
  52       - nickname: #{nickname}
  53       - email: #{email}
  54       - password: #{if(generated_password?, do: "[generated; a reset link will be created]", else: password)}
  55       - name: #{name}
  56       - bio: #{bio}
  57       - moderator: #{if(moderator?, do: "true", else: "false")}
  58       - admin: #{if(admin?, do: "true", else: "false")}
  59     """)
  60
  61     proceed? = assume_yes? or shell_prompt("Continue?", "n") in ~w(Yn Y y)
  62
  63     if proceed? do
  64       start_pleroma()
  65
  66       params = %{
  67         nickname: nickname,
  68         email: email,
  69         password: password,
  70         password_confirmation: password,
  71         name: name,
  72         bio: bio
  73       }
  74
  75       changeset = User.register_changeset(%User{}, params, is_confirmed: true)
  76       {:ok, _user} = User.register(changeset)
  77
  78       shell_info("User #{nickname} created")
  79
  80       if moderator? do
  81         run(["set", nickname, "--moderator"])
  82       end
  83
  84       if admin? do
  85         run(["set", nickname, "--admin"])
  86       end
  87
  88       if generated_password? do
  89         run(["reset_password", nickname])
  90       end
  91     else
  92       shell_info("User will not be created.")
  93     end
  94   end
  95
  96   def run(["rm", nickname]) do
  97     start_pleroma()
  98
  99     with %User{local: true} = user <- User.get_cached_by_nickname(nickname),
 100          {:ok, delete_data, _} <- Builder.delete(user, user.ap_id),
 101          {:ok, _delete, _} <- Pipeline.common_pipeline(delete_data, local: true) do
 102       shell_info("User #{nickname} deleted.")
 103     else
 104       _ -> shell_error("No local user #{nickname}")
 105     end
 106   end
 107
 108   def run(["reset_password", nickname]) do
 109     start_pleroma()
 110
 111     with %User{local: true} = user <- User.get_cached_by_nickname(nickname),
 112          {:ok, token} <- Pleroma.PasswordResetToken.create_token(user) do
 113       shell_info("Generated password reset token for #{user.nickname}")
 114
 115       IO.puts("URL: #{Pleroma.Web.Router.Helpers.reset_password_url(Pleroma.Web.Endpoint,
 116       :reset,
 117       token.token)}")
 118     else
 119       _ ->
 120         shell_error("No local user #{nickname}")
 121     end
 122   end
 123
 124   def run(["reset_mfa", nickname]) do
 125     start_pleroma()
 126
 127     with %User{local: true} = user <- User.get_cached_by_nickname(nickname),
 128          {:ok, _token} <- Pleroma.MFA.disable(user) do
 129       shell_info("Multi-Factor Authentication disabled for #{user.nickname}")
 130     else
 131       _ ->
 132         shell_error("No local user #{nickname}")
 133     end
 134   end
 135
 136   def run(["activate", nickname]) do
 137     start_pleroma()
 138
 139     with %User{} = user <- User.get_cached_by_nickname(nickname),
 140          false <- user.is_active do
 141       User.set_activation(user, true)
 142       :timer.sleep(500)
 143
 144       shell_info("Successfully activated #{nickname}")
 145     else
 146       true ->
 147         shell_info("User #{nickname} already activated")
 148
 149       _ ->
 150         shell_error("No user #{nickname}")
 151     end
 152   end
 153
 154   def run(["deactivate", nickname]) do
 155     start_pleroma()
 156
 157     with %User{} = user <- User.get_cached_by_nickname(nickname),
 158          true <- user.is_active do
 159       User.set_activation(user, false)
 160       :timer.sleep(500)
 161
 162       user = User.get_cached_by_id(user.id)
 163
 164       if Enum.empty?(Enum.filter(User.get_friends(user), & &1.local)) do
 165         shell_info("Successfully deactivated #{nickname} and unsubscribed all local followers")
 166       end
 167     else
 168       false ->
 169         shell_info("User #{nickname} already deactivated")
 170
 171       _ ->
 172         shell_error("No user #{nickname}")
 173     end
 174   end
 175
 176   def run(["deactivate_all_from_instance", instance]) do
 177     start_pleroma()
 178
 179     Pleroma.User.Query.build(%{nickname: "@#{instance}"})
 180     |> Pleroma.Repo.chunk_stream(500, :batches)
 181     |> Stream.each(fn users ->
 182       users
 183       |> Enum.each(fn user ->
 184         run(["deactivate", user.nickname])
 185       end)
 186     end)
 187     |> Stream.run()
 188   end
 189
 190   def run(["set", nickname | rest]) do
 191     start_pleroma()
 192
 193     {options, [], []} =
 194       OptionParser.parse(
 195         rest,
 196         strict: [
 197           admin: :boolean,
 198           confirmed: :boolean,
 199           locked: :boolean,
 200           moderator: :boolean
 201         ]
 202       )
 203
 204     with %User{local: true} = user <- User.get_cached_by_nickname(nickname) do
 205       user =
 206         case Keyword.get(options, :admin) do
 207           nil -> user
 208           value -> set_admin(user, value)
 209         end
 210
 211       user =
 212         case Keyword.get(options, :confirmed) do
 213           nil -> user
 214           value -> set_confirmation(user, value)
 215         end
 216
 217       user =
 218         case Keyword.get(options, :locked) do
 219           nil -> user
 220           value -> set_locked(user, value)
 221         end
 222
 223       _user =
 224         case Keyword.get(options, :moderator) do
 225           nil -> user
 226           value -> set_moderator(user, value)
 227         end
 228     else
 229       _ ->
 230         shell_error("No local user #{nickname}")
 231     end
 232   end
 233
 234   def run(["tag", nickname | tags]) do
 235     start_pleroma()
 236
 237     with %User{} = user <- User.get_cached_by_nickname(nickname) do
 238       user = user |> User.tag(tags)
 239
 240       shell_info("Tags of #{user.nickname}: #{inspect(user.tags)}")
 241     else
 242       _ ->
 243         shell_error("Could not change user tags for #{nickname}")
 244     end
 245   end
 246
 247   def run(["untag", nickname | tags]) do
 248     start_pleroma()
 249
 250     with %User{} = user <- User.get_cached_by_nickname(nickname) do
 251       user = user |> User.untag(tags)
 252
 253       shell_info("Tags of #{user.nickname}: #{inspect(user.tags)}")
 254     else
 255       _ ->
 256         shell_error("Could not change user tags for #{nickname}")
 257     end
 258   end
 259
 260   def run(["invite" | rest]) do
 261     {options, [], []} =
 262       OptionParser.parse(rest,
 263         strict: [
 264           expires_at: :string,
 265           max_use: :integer
 266         ]
 267       )
 268
 269     options =
 270       options
 271       |> Keyword.update(:expires_at, {:ok, nil}, fn
 272         nil -> {:ok, nil}
 273         val -> Date.from_iso8601(val)
 274       end)
 275       |> Enum.into(%{})
 276
 277     start_pleroma()
 278
 279     with {:ok, val} <- options[:expires_at],
 280          options = Map.put(options, :expires_at, val),
 281          {:ok, invite} <- UserInviteToken.create_invite(options) do
 282       shell_info("Generated user invite token " <> String.replace(invite.invite_type, "_", " "))
 283
 284       url =
 285         Pleroma.Web.Router.Helpers.redirect_url(
 286           Pleroma.Web.Endpoint,
 287           :registration_page,
 288           invite.token
 289         )
 290
 291       IO.puts(url)
 292     else
 293       error ->
 294         shell_error("Could not create invite token: #{inspect(error)}")
 295     end
 296   end
 297
 298   def run(["invites"]) do
 299     start_pleroma()
 300
 301     shell_info("Invites list:")
 302
 303     UserInviteToken.list_invites()
 304     |> Enum.each(fn invite ->
 305       expire_info =
 306         with expires_at when not is_nil(expires_at) <- invite.expires_at do
 307           " | Expires at: #{Date.to_string(expires_at)}"
 308         end
 309
 310       using_info =
 311         with max_use when not is_nil(max_use) <- invite.max_use do
 312           " | Max use: #{max_use}    Left use: #{max_use - invite.uses}"
 313         end
 314
 315       shell_info(
 316         "ID: #{invite.id} | Token: #{invite.token} | Token type: #{invite.invite_type} | Used: #{invite.used}#{expire_info}#{using_info}"
 317       )
 318     end)
 319   end
 320
 321   def run(["revoke_invite", token]) do
 322     start_pleroma()
 323
 324     with {:ok, invite} <- UserInviteToken.find_by_token(token),
 325          {:ok, _} <- UserInviteToken.update_invite(invite, %{used: true}) do
 326       shell_info("Invite for token #{token} was revoked.")
 327     else
 328       _ -> shell_error("No invite found with token #{token}")
 329     end
 330   end
 331
 332   def run(["delete_activities", nickname]) do
 333     start_pleroma()
 334
 335     with %User{local: true} = user <- User.get_cached_by_nickname(nickname) do
 336       User.delete_user_activities(user)
 337       shell_info("User #{nickname} statuses deleted.")
 338     else
 339       _ ->
 340         shell_error("No local user #{nickname}")
 341     end
 342   end
 343
 344   def run(["confirm", nickname]) do
 345     start_pleroma()
 346
 347     with %User{} = user <- User.get_cached_by_nickname(nickname) do
 348       {:ok, user} = User.confirm(user)
 349
 350       message = if !user.is_confirmed, do: "needs", else: "doesn't need"
 351
 352       shell_info("#{nickname} #{message} confirmation.")
 353     else
 354       _ ->
 355         shell_error("No local user #{nickname}")
 356     end
 357   end
 358
 359   def run(["confirm_all"]) do
 360     start_pleroma()
 361
 362     Pleroma.User.Query.build(%{
 363       local: true,
 364       is_active: true,
 365       is_moderator: false,
 366       is_admin: false,
 367       invisible: false
 368     })
 369     |> Pleroma.Repo.chunk_stream(500, :batches)
 370     |> Stream.each(fn users ->
 371       users
 372       |> Enum.each(fn user -> User.set_confirmation(user, true) end)
 373     end)
 374     |> Stream.run()
 375   end
 376
 377   def run(["unconfirm_all"]) do
 378     start_pleroma()
 379
 380     Pleroma.User.Query.build(%{
 381       local: true,
 382       is_active: true,
 383       is_moderator: false,
 384       is_admin: false,
 385       invisible: false
 386     })
 387     |> Pleroma.Repo.chunk_stream(500, :batches)
 388     |> Stream.each(fn users ->
 389       users
 390       |> Enum.each(fn user -> User.set_confirmation(user, false) end)
 391     end)
 392     |> Stream.run()
 393   end
 394
 395   def run(["sign_out", nickname]) do
 396     start_pleroma()
 397
 398     with %User{local: true} = user <- User.get_cached_by_nickname(nickname) do
 399       User.global_sign_out(user)
 400
 401       shell_info("#{nickname} signed out from all apps.")
 402     else
 403       _ ->
 404         shell_error("No local user #{nickname}")
 405     end
 406   end
 407
 408   def run(["list"]) do
 409     start_pleroma()
 410
 411     Pleroma.User.Query.build(%{local: true})
 412     |> Pleroma.Repo.chunk_stream(500, :batches)
 413     |> Stream.each(fn users ->
 414       users
 415       |> Enum.each(fn user ->
 416         shell_info(
 417           "#{user.nickname} moderator: #{user.is_moderator}, admin: #{user.is_admin}, locked: #{user.is_locked}, is_active: #{user.is_active}"
 418         )
 419       end)
 420     end)
 421     |> Stream.run()
 422   end
 423
 424   defp set_moderator(user, value) do
 425     {:ok, user} =
 426       user
 427       |> Changeset.change(%{is_moderator: value})
 428       |> User.update_and_set_cache()
 429
 430     shell_info("Moderator status of #{user.nickname}: #{user.is_moderator}")
 431     user
 432   end
 433
 434   defp set_admin(user, value) do
 435     {:ok, user} = User.admin_api_update(user, %{is_admin: value})
 436
 437     shell_info("Admin status of #{user.nickname}: #{user.is_admin}")
 438     user
 439   end
 440
 441   defp set_locked(user, value) do
 442     {:ok, user} =
 443       user
 444       |> Changeset.change(%{is_locked: value})
 445       |> User.update_and_set_cache()
 446
 447     shell_info("Locked status of #{user.nickname}: #{user.is_locked}")
 448     user
 449   end
 450
 451   defp set_confirmation(user, value) do
 452     {:ok, user} = User.set_confirmation(user, value)
 453
 454     shell_info("Confirmation status of #{user.nickname}: #{user.is_confirmed}")
 455     user
 456   end
 457 end