git.squeep.com Git - akkoma/blob - lib/mix/tasks/pleroma/config.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Mix.Tasks.Pleroma.Config do
   6   use Mix.Task
   7
   8   import Mix.Pleroma
   9
  10   alias Pleroma.ConfigDB
  11   alias Pleroma.Repo
  12
  13   @shortdoc "Manages the location of the config"
  14   @moduledoc File.read!("docs/administration/CLI_tasks/config.md")
  15
  16   def run(["migrate_to_db"]) do
  17     start_pleroma()
  18     migrate_to_db()
  19   end
  20
  21   def run(["migrate_from_db" | options]) do
  22     start_pleroma()
  23
  24     {opts, _} =
  25       OptionParser.parse!(options,
  26         strict: [env: :string, delete: :boolean],
  27         aliases: [d: :delete]
  28       )
  29
  30     migrate_from_db(opts)
  31   end
  32
  33   @spec migrate_to_db(Path.t() | nil) :: any()
  34   def migrate_to_db(file_path \\ nil) do
  35     with true <- Pleroma.Config.get([:configurable_from_database]),
  36          :ok <- Pleroma.Config.DeprecationWarnings.warn() do
  37       config_file =
  38         if file_path do
  39           file_path
  40         else
  41           if Pleroma.Config.get(:release) do
  42             Pleroma.Config.get(:config_path)
  43           else
  44             "config/#{Pleroma.Config.get(:env)}.secret.exs"
  45           end
  46         end
  47
  48       do_migrate_to_db(config_file)
  49     else
  50       :error -> deprecation_error()
  51       _ -> migration_error()
  52     end
  53   end
  54
  55   defp do_migrate_to_db(config_file) do
  56     if File.exists?(config_file) do
  57       shell_info("Migrating settings from file: #{Path.expand(config_file)}")
  58       Ecto.Adapters.SQL.query!(Repo, "TRUNCATE config;")
  59       Ecto.Adapters.SQL.query!(Repo, "ALTER SEQUENCE config_id_seq RESTART;")
  60
  61       custom_config =
  62         config_file
  63         |> read_file()
  64         |> elem(0)
  65
  66       custom_config
  67       |> Keyword.keys()
  68       |> Enum.each(&create(&1, custom_config))
  69     else
  70       shell_info("To migrate settings, you must define custom settings in #{config_file}.")
  71     end
  72   end
  73
  74   defp create(group, settings) do
  75     group
  76     |> Pleroma.Config.Loader.filter_group(settings)
  77     |> Enum.each(fn {key, value} ->
  78       {:ok, _} = ConfigDB.update_or_create(%{group: group, key: key, value: value})
  79
  80       shell_info("Settings for key #{key} migrated.")
  81     end)
  82
  83     shell_info("Settings for group :#{group} migrated.")
  84   end
  85
  86   defp migrate_from_db(opts) do
  87     if Pleroma.Config.get([:configurable_from_database]) do
  88       env = opts[:env] || Pleroma.Config.get(:env)
  89
  90       config_path =
  91         if Pleroma.Config.get(:release) do
  92           :config_path
  93           |> Pleroma.Config.get()
  94           |> Path.dirname()
  95         else
  96           "config"
  97         end
  98         |> Path.join("#{env}.exported_from_db.secret.exs")
  99
 100       file = File.open!(config_path, [:write, :utf8])
 101
 102       IO.write(file, config_header())
 103
 104       ConfigDB
 105       |> Repo.all()
 106       |> Enum.each(&write_and_delete(&1, file, opts[:delete]))
 107
 108       :ok = File.close(file)
 109       System.cmd("mix", ["format", config_path])
 110
 111       shell_info(
 112         "Database configuration settings have been exported to config/#{env}.exported_from_db.secret.exs"
 113       )
 114     else
 115       migration_error()
 116     end
 117   end
 118
 119   defp migration_error do
 120     shell_error(
 121       "Migration is not allowed in config. You can change this behavior by setting `config :pleroma, configurable_from_database: true`"
 122     )
 123   end
 124
 125   defp deprecation_error do
 126     shell_error("Migration is not allowed until all deprecation warnings have been resolved.")
 127   end
 128
 129   if Code.ensure_loaded?(Config.Reader) do
 130     defp config_header, do: "import Config\r\n\r\n"
 131     defp read_file(config_file), do: Config.Reader.read_imports!(config_file)
 132   else
 133     defp config_header, do: "use Mix.Config\r\n\r\n"
 134     defp read_file(config_file), do: Mix.Config.eval!(config_file)
 135   end
 136
 137   defp write_and_delete(config, file, delete?) do
 138     config
 139     |> write(file)
 140     |> delete(delete?)
 141   end
 142
 143   defp write(config, file) do
 144     value = inspect(config.value, limit: :infinity)
 145
 146     IO.write(file, "config #{inspect(config.group)}, #{inspect(config.key)}, #{value}\r\n\r\n")
 147
 148     config
 149   end
 150
 151   defp delete(config, true) do
 152     {:ok, _} = Repo.delete(config)
 153     shell_info("#{config.key} deleted from DB.")
 154   end
 155
 156   defp delete(_config, _), do: :ok
 157 end