+ defp restrict_actor(query, _), do: query
+
+ defp restrict_type(query, %{"type" => type}) when is_binary(type) do
+ restrict_type(query, %{"type" => [type]})
+ end
+
+ defp restrict_type(query, %{"type" => type}) do
+ from(activity in query, where: fragment("?->>'type' = ANY(?)", activity.data, ^type))
+ end
+
+ defp restrict_type(query, _), do: query
+
+ defp restrict_favorited_by(query, %{"favorited_by" => ap_id}) do
+ from(
+ activity in query,
+ where: fragment("? <@ (? #> '{\"object\",\"likes\"}')", ^ap_id, activity.data)
+ )
+ end
+
+ defp restrict_favorited_by(query, _), do: query
+
+ defp restrict_media(query, %{"only_media" => val}) when val == "true" or val == "1" do
+ from(
+ activity in query,
+ where: fragment("not (? #> '{\"object\",\"attachment\"}' = ?)", activity.data, ^[])
+ )
+ end
+
+ defp restrict_media(query, _), do: query
+
+ # Only search through last 100_000 activities by default
+ defp restrict_recent(query, %{"whole_db" => true}), do: query
+
+ defp restrict_recent(query, _) do
+ since = (Repo.aggregate(Activity, :max, :id) || 0) - 100_000
+
+ from(activity in query, where: activity.id > ^since)
+ end
+
+ defp restrict_blocked(query, %{"blocking_user" => %User{info: info}}) do
+ blocks = info["blocks"] || []
+
+ from(
+ activity in query,
+ where: fragment("not (? = ANY(?))", activity.actor, ^blocks),
+ where: fragment("not (?->'to' \\?| ?)", activity.data, ^blocks)
+ )
+ end
+
+ defp restrict_blocked(query, _), do: query
+
+ defp restrict_unlisted(query) do
+ from(
+ activity in query,
+ where:
+ fragment(
+ "not (coalesce(?->'cc', '{}'::jsonb) \\?| ?)",
+ activity.data,
+ ^["https://www.w3.org/ns/activitystreams#Public"]
+ )
+ )
+ end
+
+ def fetch_activities_query(recipients, opts \\ %{}) do
+ base_query =
+ from(
+ activity in Activity,
+ limit: 20,
+ order_by: [fragment("? desc nulls last", activity.id)]
+ )
+
+ base_query
+ |> restrict_recipients(recipients, opts["user"])
+ |> restrict_tag(opts)
+ |> restrict_since(opts)
+ |> restrict_local(opts)
+ |> restrict_limit(opts)
+ |> restrict_max(opts)
+ |> restrict_actor(opts)
+ |> restrict_type(opts)
+ |> restrict_favorited_by(opts)
+ |> restrict_recent(opts)
+ |> restrict_blocked(opts)
+ |> restrict_media(opts)
+ |> restrict_visibility(opts)