git.squeep.com Git - akkoma/blob - test/web/twitter_api/twitter_api_test.exs

   1 defmodule Pleroma.Web.TwitterAPI.TwitterAPITest do
   2   use Pleroma.DataCase
   3   alias Pleroma.Builders.{UserBuilder, ActivityBuilder}
   4   alias Pleroma.Web.TwitterAPI.TwitterAPI
   5   alias Pleroma.{Activity, User, Object, Repo}
   6   alias Pleroma.Web.TwitterAPI.Representers.{ActivityRepresenter, UserRepresenter}
   7   alias Pleroma.Web.ActivityPub.ActivityPub
   8
   9   import Pleroma.Factory
  10
  11   test "create a status" do
  12     user = UserBuilder.build(%{ap_id: "142344"})
  13     _mentioned_user = UserBuilder.insert(%{nickname: "shp", ap_id: "shp"})
  14
  15     object_data = %{
  16       "type" => "Image",
  17       "url" => [
  18         %{
  19           "type" => "Link",
  20           "mediaType" => "image/jpg",
  21           "href" => "http://example.org/image.jpg"
  22         }
  23       ],
  24       "uuid" => 1
  25     }
  26
  27     object = Repo.insert!(%Object{data: object_data})
  28
  29     input = %{
  30       "status" => "Hello again, @shp.<script></script>\nThis is on another line.",
  31       "media_ids" => [object.id]
  32     }
  33
  34     { :ok, activity = %Activity{} } = TwitterAPI.create_status(user, input)
  35
  36     assert get_in(activity.data, ["object", "content"]) == "Hello again, <a href='shp'>@shp</a>.<br>This is on another line."
  37     assert get_in(activity.data, ["object", "type"]) == "Note"
  38     assert get_in(activity.data, ["object", "actor"]) == user.ap_id
  39     assert get_in(activity.data, ["actor"]) == user.ap_id
  40     assert Enum.member?(get_in(activity.data, ["to"]), User.ap_followers(user))
  41     assert Enum.member?(get_in(activity.data, ["to"]), "https://www.w3.org/ns/activitystreams#Public")
  42     assert Enum.member?(get_in(activity.data, ["to"]), "shp")
  43
  44     # Add a context + 'statusnet_conversation_id'
  45     assert is_binary(get_in(activity.data, ["context"]))
  46     assert is_binary(get_in(activity.data, ["object", "context"]))
  47     assert get_in(activity.data, ["object", "statusnetConversationId"]) == activity.id
  48     assert get_in(activity.data, ["statusnetConversationId"]) == activity.id
  49
  50     assert is_list(activity.data["object"]["attachment"])
  51
  52     assert activity.data["object"] == Object.get_by_ap_id(activity.data["object"]["id"]).data
  53   end
  54
  55   test "create a status that is a reply" do
  56     user = UserBuilder.build(%{ap_id: "some_cool_id"})
  57     input = %{
  58       "status" => "Hello again."
  59     }
  60
  61     { :ok, activity = %Activity{} } = TwitterAPI.create_status(user, input)
  62
  63     input = %{
  64       "status" => "Here's your (you).",
  65       "in_reply_to_status_id" => activity.id
  66     }
  67
  68     { :ok, reply = %Activity{} } = TwitterAPI.create_status(user, input)
  69
  70     assert get_in(reply.data, ["context"]) == get_in(activity.data, ["context"])
  71     assert get_in(reply.data, ["object", "context"]) == get_in(activity.data, ["object", "context"])
  72     assert get_in(reply.data, ["statusnetConversationId"]) == get_in(activity.data, ["statusnetConversationId"])
  73     assert get_in(reply.data, ["object", "statusnetConversationId"]) == get_in(activity.data, ["object", "statusnetConversationId"])
  74     assert get_in(reply.data, ["object", "inReplyTo"]) == get_in(activity.data, ["object", "id"])
  75     assert get_in(reply.data, ["object", "inReplyToStatusId"]) == activity.id
  76     assert Enum.member?(get_in(reply.data, ["to"]), "some_cool_id")
  77   end
  78
  79   test "fetch public statuses" do
  80     %{ public: activity, user: user } = ActivityBuilder.public_and_non_public
  81     {:ok, follower } = UserBuilder.insert(%{name: "dude", ap_id: "idididid", following: [User.ap_followers(user)]})
  82
  83     statuses = TwitterAPI.fetch_public_statuses(follower)
  84
  85     assert length(statuses) == 1
  86     assert Enum.at(statuses, 0) == ActivityRepresenter.to_map(activity, %{user: user, for: follower})
  87   end
  88
  89   test "fetch friends' statuses" do
  90     ActivityBuilder.public_and_non_public
  91
  92     {:ok, activity} = ActivityBuilder.insert(%{"to" => ["someguy/followers"]})
  93     {:ok, direct_activity} = ActivityBuilder.insert(%{"to" => ["some other id"]})
  94     {:ok, user} = UserBuilder.insert(%{ap_id: "some other id", following: ["someguy/followers"]})
  95
  96     statuses = TwitterAPI.fetch_friend_statuses(user)
  97
  98     activity_user = Repo.get_by(User, ap_id: activity.data["actor"])
  99
 100     assert length(statuses) == 2
 101     assert Enum.at(statuses, 0) == ActivityRepresenter.to_map(activity, %{user: activity_user})
 102     assert Enum.at(statuses, 1) == ActivityRepresenter.to_map(direct_activity, %{user: activity_user, mentioned: [user]})
 103   end
 104
 105   test "fetch a single status" do
 106     {:ok, activity} = ActivityBuilder.insert()
 107     {:ok, user} = UserBuilder.insert()
 108     actor = Repo.get_by!(User, ap_id: activity.data["actor"])
 109
 110     status = TwitterAPI.fetch_status(user, activity.id)
 111
 112     assert status == ActivityRepresenter.to_map(activity, %{for: user, user: actor})
 113   end
 114
 115   test "Follow another user" do
 116     { :ok, user } = UserBuilder.insert
 117     { :ok, following } = UserBuilder.insert(%{nickname: "guy"})
 118
 119     {:ok, user, following, activity } = TwitterAPI.follow(user, following.id)
 120
 121     user = Repo.get(User, user.id)
 122     follow = Repo.get(Activity, activity.id)
 123
 124     assert user.following == [User.ap_followers(following)]
 125     assert follow == activity
 126   end
 127
 128   test "Unfollow another user" do
 129     { :ok, following } = UserBuilder.insert(%{nickname: "guy"})
 130     { :ok, user } = UserBuilder.insert(%{following: [User.ap_followers(following)]})
 131
 132     {:ok, user, _following } = TwitterAPI.unfollow(user, following.id)
 133
 134     user = Repo.get(User, user.id)
 135
 136     assert user.following == []
 137   end
 138
 139   test "fetch statuses in a context using the conversation id" do
 140     {:ok, user} = UserBuilder.insert()
 141     {:ok, activity} = ActivityBuilder.insert(%{"statusnetConversationId" => 1, "context" => "2hu"})
 142     {:ok, activity_two} = ActivityBuilder.insert(%{"statusnetConversationId" => 1,"context" => "2hu"})
 143     {:ok, _activity_three} = ActivityBuilder.insert(%{"context" => "3hu"})
 144
 145     statuses = TwitterAPI.fetch_conversation(user, 1)
 146
 147     assert length(statuses) == 2
 148     assert Enum.at(statuses, 0)["id"] == activity.id
 149     assert Enum.at(statuses, 1)["id"] == activity_two.id
 150   end
 151
 152   test "upload a file" do
 153     file = %Plug.Upload{content_type: "image/jpg", path: Path.absname("test/fixtures/image.jpg"), filename: "an_image.jpg"}
 154
 155     response = TwitterAPI.upload(file)
 156
 157     assert is_binary(response)
 158   end
 159
 160   test "it can parse mentions and return the relevant users" do
 161     text = "@gsimg According to @archaeme , that is @daggsy."
 162
 163     {:ok, gsimg} = UserBuilder.insert(%{nickname: "gsimg"})
 164     {:ok, archaeme} = UserBuilder.insert(%{nickname: "archaeme"})
 165
 166     expected_result = [
 167       {"@gsimg", gsimg},
 168       {"@archaeme", archaeme}
 169     ]
 170
 171     assert TwitterAPI.parse_mentions(text) == expected_result
 172   end
 173
 174   test "it adds user links to an existing text" do
 175     text = "@gsimg According to @archaeme , that is @daggsy."
 176
 177     {:ok, _gsimg} = UserBuilder.insert(%{nickname: "gsimg", ap_id: "first_link" })
 178     {:ok, _archaeme} = UserBuilder.insert(%{nickname: "archaeme", ap_id: "second_link"})
 179
 180     mentions = TwitterAPI.parse_mentions(text)
 181     expected_text = "<a href='first_link'>@gsimg</a> According to <a href='second_link'>@archaeme</a> , that is @daggsy."
 182
 183     assert TwitterAPI.add_user_links(text, mentions) == expected_text
 184   end
 185
 186   test "it favorites a status, returns the updated status" do
 187     user = insert(:user)
 188     note_activity = insert(:note_activity)
 189     activity_user = Repo.get_by!(User, ap_id: note_activity.data["actor"])
 190
 191     {:ok, status} = TwitterAPI.favorite(user, note_activity)
 192     updated_activity = Activity.get_by_ap_id(note_activity.data["id"])
 193
 194     assert status == ActivityRepresenter.to_map(updated_activity, %{user: activity_user, for: user})
 195   end
 196
 197   test "it unfavorites a status, returns the updated status" do
 198     user = insert(:user)
 199     note_activity = insert(:note_activity)
 200     activity_user = Repo.get_by!(User, ap_id: note_activity.data["actor"])
 201     object = Object.get_by_ap_id(note_activity.data["object"]["id"])
 202
 203     {:ok, _like_activity, _object } = ActivityPub.like(user, object)
 204     updated_activity = Activity.get_by_ap_id(note_activity.data["id"])
 205     assert ActivityRepresenter.to_map(updated_activity, %{user: activity_user, for: user})["fave_num"] == 1
 206
 207     {:ok, status} = TwitterAPI.unfavorite(user, note_activity)
 208
 209     assert status["fave_num"] == 0
 210   end
 211
 212   test "it retweets a status and returns the retweet" do
 213     user = insert(:user)
 214     note_activity = insert(:note_activity)
 215     activity_user = Repo.get_by!(User, ap_id: note_activity.data["actor"])
 216
 217     {:ok, status} = TwitterAPI.retweet(user, note_activity)
 218     updated_activity = Activity.get_by_ap_id(note_activity.data["id"])
 219
 220     assert status == ActivityRepresenter.to_map(updated_activity, %{user: activity_user, for: user})
 221   end
 222
 223   test "it registers a new user and returns the user." do
 224     data = %{
 225       "nickname" => "lain",
 226       "email" => "lain@wired.jp",
 227       "fullname" => "lain iwakura",
 228       "bio" => "close the world.",
 229       "password" => "bear",
 230       "confirm" => "bear"
 231     }
 232
 233     {:ok, user} = TwitterAPI.register_user(data)
 234
 235     fetched_user = Repo.get_by(User, nickname: "lain")
 236     assert user == UserRepresenter.to_map(fetched_user)
 237   end
 238
 239   test "it returns the error on registration problems" do
 240     data = %{
 241       "nickname" => "lain",
 242       "email" => "lain@wired.jp",
 243       "fullname" => "lain iwakura",
 244       "bio" => "close the world.",
 245       "password" => "bear"
 246     }
 247
 248     {:error, error_object} = TwitterAPI.register_user(data)
 249
 250     assert is_binary(error_object[:error])
 251     refute Repo.get_by(User, nickname: "lain")
 252   end
 253
 254   setup do
 255     Supervisor.terminate_child(Pleroma.Supervisor, ConCache)
 256     Supervisor.restart_child(Pleroma.Supervisor, ConCache)
 257     :ok
 258   end
 259 end