git.squeep.com Git - akkoma/blob - test/web/twitter_api/twitter_api_test.exs

   1 defmodule Pleroma.Web.TwitterAPI.TwitterAPITest do
   2   use Pleroma.DataCase
   3   alias Pleroma.Builders.{UserBuilder, ActivityBuilder}
   4   alias Pleroma.Web.TwitterAPI.{TwitterAPI, UserView}
   5   alias Pleroma.Web.CommonAPI.Utils
   6   alias Pleroma.{Activity, User, Object, Repo}
   7   alias Pleroma.Web.TwitterAPI.Representers.ActivityRepresenter
   8   alias Pleroma.Web.ActivityPub.ActivityPub
   9
  10   import Pleroma.Factory
  11
  12   test "create a status" do
  13     user = insert(:user)
  14     _mentioned_user = UserBuilder.insert(%{nickname: "shp", ap_id: "shp"})
  15
  16     object_data = %{
  17       "type" => "Image",
  18       "url" => [
  19         %{
  20           "type" => "Link",
  21           "mediaType" => "image/jpg",
  22           "href" => "http://example.org/image.jpg"
  23         }
  24       ],
  25       "uuid" => 1
  26     }
  27
  28     object = Repo.insert!(%Object{data: object_data})
  29
  30     input = %{
  31       "status" =>
  32         "Hello again, @shp.<script></script>\nThis is on another :moominmamma: line. #2hu #epic #phantasmagoric",
  33       "media_ids" => [object.id]
  34     }
  35
  36     {:ok, activity = %Activity{}} = TwitterAPI.create_status(user, input)
  37
  38     expected_text =
  39       "Hello again, <span><a href='shp'>@<span>shp</span></a></span>.&lt;script&gt;&lt;/script&gt;<br>This is on another :moominmamma: line. <a href='http://localhost:4001/tag/2hu' rel='tag'>#2hu</a> <a href='http://localhost:4001/tag/epic' rel='tag'>#epic</a> <a href='http://localhost:4001/tag/phantasmagoric' rel='tag'>#phantasmagoric</a><br><a href=\"http://example.org/image.jpg\" class='attachment'>image.jpg</a>"
  40
  41     assert get_in(activity.data, ["object", "content"]) == expected_text
  42     assert get_in(activity.data, ["object", "type"]) == "Note"
  43     assert get_in(activity.data, ["object", "actor"]) == user.ap_id
  44     assert get_in(activity.data, ["actor"]) == user.ap_id
  45     assert Enum.member?(get_in(activity.data, ["cc"]), User.ap_followers(user))
  46
  47     assert Enum.member?(
  48              get_in(activity.data, ["to"]),
  49              "https://www.w3.org/ns/activitystreams#Public"
  50            )
  51
  52     assert Enum.member?(get_in(activity.data, ["cc"]), "shp")
  53     assert activity.local == true
  54
  55     assert %{"moominmamma" => "http://localhost:4001/finmoji/128px/moominmamma-128.png"} =
  56              activity.data["object"]["emoji"]
  57
  58     # hashtags
  59     assert activity.data["object"]["tag"] == ["2hu", "epic", "phantasmagoric"]
  60
  61     # Add a context
  62     assert is_binary(get_in(activity.data, ["context"]))
  63     assert is_binary(get_in(activity.data, ["object", "context"]))
  64
  65     assert is_list(activity.data["object"]["attachment"])
  66
  67     assert activity.data["object"] == Object.get_by_ap_id(activity.data["object"]["id"]).data
  68
  69     user = User.get_by_ap_id(user.ap_id)
  70
  71     assert user.info["note_count"] == 1
  72   end
  73
  74   test "create a status that is a reply" do
  75     user = insert(:user)
  76
  77     input = %{
  78       "status" => "Hello again."
  79     }
  80
  81     {:ok, activity = %Activity{}} = TwitterAPI.create_status(user, input)
  82
  83     input = %{
  84       "status" => "Here's your (you).",
  85       "in_reply_to_status_id" => activity.id
  86     }
  87
  88     {:ok, reply = %Activity{}} = TwitterAPI.create_status(user, input)
  89
  90     assert get_in(reply.data, ["context"]) == get_in(activity.data, ["context"])
  91
  92     assert get_in(reply.data, ["object", "context"]) ==
  93              get_in(activity.data, ["object", "context"])
  94
  95     assert get_in(reply.data, ["object", "inReplyTo"]) == get_in(activity.data, ["object", "id"])
  96     assert get_in(reply.data, ["object", "inReplyToStatusId"]) == activity.id
  97   end
  98
  99   test "fetch public statuses, excluding remote ones." do
 100     %{public: activity, user: user} = ActivityBuilder.public_and_non_public()
 101     insert(:note_activity, %{local: false})
 102
 103     follower = insert(:user, following: [User.ap_followers(user)])
 104
 105     statuses = TwitterAPI.fetch_public_statuses(follower)
 106
 107     assert length(statuses) == 1
 108
 109     assert Enum.at(statuses, 0) ==
 110              ActivityRepresenter.to_map(activity, %{user: user, for: follower})
 111   end
 112
 113   test "fetch whole known network statuses" do
 114     %{public: activity, user: user} = ActivityBuilder.public_and_non_public()
 115     insert(:note_activity, %{local: false})
 116
 117     follower = insert(:user, following: [user.follower_address])
 118
 119     statuses = TwitterAPI.fetch_public_and_external_statuses(follower)
 120
 121     assert length(statuses) == 2
 122
 123     assert Enum.at(statuses, 0) ==
 124              ActivityRepresenter.to_map(activity, %{user: user, for: follower})
 125   end
 126
 127   test "fetch friends' statuses" do
 128     user = insert(:user, %{following: ["someguy/followers"]})
 129     {:ok, activity} = ActivityBuilder.insert(%{"to" => ["someguy/followers"]})
 130     {:ok, direct_activity} = ActivityBuilder.insert(%{"to" => [user.ap_id]})
 131
 132     statuses = TwitterAPI.fetch_friend_statuses(user)
 133
 134     activity_user = Repo.get_by(User, ap_id: activity.data["actor"])
 135     direct_activity_user = Repo.get_by(User, ap_id: direct_activity.data["actor"])
 136
 137     assert length(statuses) == 2
 138     assert Enum.at(statuses, 0) == ActivityRepresenter.to_map(activity, %{user: activity_user})
 139
 140     assert Enum.at(statuses, 1) ==
 141              ActivityRepresenter.to_map(direct_activity, %{
 142                user: direct_activity_user,
 143                mentioned: [user]
 144              })
 145   end
 146
 147   test "fetch user's mentions" do
 148     user = insert(:user)
 149     {:ok, activity} = ActivityBuilder.insert(%{"to" => [user.ap_id]})
 150     activity_user = Repo.get_by(User, ap_id: activity.data["actor"])
 151
 152     statuses = TwitterAPI.fetch_mentions(user)
 153
 154     assert length(statuses) == 1
 155
 156     assert Enum.at(statuses, 0) ==
 157              ActivityRepresenter.to_map(activity, %{user: activity_user, mentioned: [user]})
 158   end
 159
 160   test "get a user by params" do
 161     user1_result = {:ok, user1} = UserBuilder.insert(%{ap_id: "some id", email: "test@pleroma"})
 162
 163     {:ok, user2} =
 164       UserBuilder.insert(%{ap_id: "some other id", nickname: "testname2", email: "test2@pleroma"})
 165
 166     assert {:error, "You need to specify screen_name or user_id"} == TwitterAPI.get_user(nil, nil)
 167     assert user1_result == TwitterAPI.get_user(nil, %{"user_id" => user1.id})
 168     assert user1_result == TwitterAPI.get_user(nil, %{"user_id" => user1.nickname})
 169     assert user1_result == TwitterAPI.get_user(nil, %{"screen_name" => user1.nickname})
 170     assert user1_result == TwitterAPI.get_user(user1, nil)
 171     assert user1_result == TwitterAPI.get_user(user2, %{"user_id" => user1.id})
 172     assert user1_result == TwitterAPI.get_user(user2, %{"screen_name" => user1.nickname})
 173
 174     assert {:error, "No user with such screen_name"} ==
 175              TwitterAPI.get_user(nil, %{"screen_name" => "Satan"})
 176
 177     assert {:error, "No user with such user_id"} == TwitterAPI.get_user(nil, %{"user_id" => 666})
 178   end
 179
 180   test "fetch user's statuses" do
 181     {:ok, user1} = UserBuilder.insert(%{ap_id: "some id", email: "test@pleroma"})
 182
 183     {:ok, user2} =
 184       UserBuilder.insert(%{ap_id: "some other id", nickname: "testname2", email: "test2@pleroma"})
 185
 186     {:ok, status1} = ActivityBuilder.insert(%{"id" => 1}, %{user: user1})
 187     {:ok, status2} = ActivityBuilder.insert(%{"id" => 2}, %{user: user2})
 188
 189     user1_statuses = TwitterAPI.fetch_user_statuses(user1, %{"actor_id" => user1.ap_id})
 190
 191     assert length(user1_statuses) == 1
 192     assert Enum.at(user1_statuses, 0) == ActivityRepresenter.to_map(status1, %{user: user1})
 193
 194     user2_statuses = TwitterAPI.fetch_user_statuses(user1, %{"actor_id" => user2.ap_id})
 195
 196     assert length(user2_statuses) == 1
 197     assert Enum.at(user2_statuses, 0) == ActivityRepresenter.to_map(status2, %{user: user2})
 198   end
 199
 200   test "fetch a single status" do
 201     {:ok, activity} = ActivityBuilder.insert()
 202     {:ok, user} = UserBuilder.insert()
 203     actor = Repo.get_by!(User, ap_id: activity.data["actor"])
 204
 205     status = TwitterAPI.fetch_status(user, activity.id)
 206
 207     assert status == ActivityRepresenter.to_map(activity, %{for: user, user: actor})
 208   end
 209
 210   test "Follow another user using user_id" do
 211     user = insert(:user)
 212     followed = insert(:user)
 213
 214     {:ok, user, followed, _activity} = TwitterAPI.follow(user, %{"user_id" => followed.id})
 215     assert User.ap_followers(followed) in user.following
 216
 217     {:error, msg} = TwitterAPI.follow(user, %{"user_id" => followed.id})
 218     assert msg == "Could not follow user: #{followed.nickname} is already on your list."
 219   end
 220
 221   test "Follow another user using screen_name" do
 222     user = insert(:user)
 223     followed = insert(:user)
 224
 225     {:ok, user, followed, _activity} =
 226       TwitterAPI.follow(user, %{"screen_name" => followed.nickname})
 227
 228     assert User.ap_followers(followed) in user.following
 229
 230     followed = User.get_by_ap_id(followed.ap_id)
 231     assert followed.info["follower_count"] == 1
 232
 233     {:error, msg} = TwitterAPI.follow(user, %{"screen_name" => followed.nickname})
 234     assert msg == "Could not follow user: #{followed.nickname} is already on your list."
 235   end
 236
 237   test "Unfollow another user using user_id" do
 238     unfollowed = insert(:user)
 239     user = insert(:user, %{following: [User.ap_followers(unfollowed)]})
 240     ActivityPub.follow(user, unfollowed)
 241
 242     {:ok, user, unfollowed} = TwitterAPI.unfollow(user, %{"user_id" => unfollowed.id})
 243     assert user.following == []
 244
 245     {:error, msg} = TwitterAPI.unfollow(user, %{"user_id" => unfollowed.id})
 246     assert msg == "Not subscribed!"
 247   end
 248
 249   test "Unfollow another user using screen_name" do
 250     unfollowed = insert(:user)
 251     user = insert(:user, %{following: [User.ap_followers(unfollowed)]})
 252
 253     ActivityPub.follow(user, unfollowed)
 254
 255     {:ok, user, unfollowed} = TwitterAPI.unfollow(user, %{"screen_name" => unfollowed.nickname})
 256     assert user.following == []
 257
 258     {:error, msg} = TwitterAPI.unfollow(user, %{"screen_name" => unfollowed.nickname})
 259     assert msg == "Not subscribed!"
 260   end
 261
 262   test "Block another user using user_id" do
 263     user = insert(:user)
 264     blocked = insert(:user)
 265
 266     {:ok, user, blocked} = TwitterAPI.block(user, %{"user_id" => blocked.id})
 267     assert User.blocks?(user, blocked)
 268   end
 269
 270   test "Block another user using screen_name" do
 271     user = insert(:user)
 272     blocked = insert(:user)
 273
 274     {:ok, user, blocked} = TwitterAPI.block(user, %{"screen_name" => blocked.nickname})
 275     assert User.blocks?(user, blocked)
 276   end
 277
 278   test "Unblock another user using user_id" do
 279     unblocked = insert(:user)
 280     user = insert(:user)
 281     User.block(user, unblocked)
 282
 283     {:ok, user, _unblocked} = TwitterAPI.unblock(user, %{"user_id" => unblocked.id})
 284     assert user.info["blocks"] == []
 285   end
 286
 287   test "Unblock another user using screen_name" do
 288     unblocked = insert(:user)
 289     user = insert(:user)
 290     User.block(user, unblocked)
 291
 292     {:ok, user, _unblocked} = TwitterAPI.unblock(user, %{"screen_name" => unblocked.nickname})
 293     assert user.info["blocks"] == []
 294   end
 295
 296   test "fetch statuses in a context using the conversation id" do
 297     {:ok, user} = UserBuilder.insert()
 298     {:ok, activity} = ActivityBuilder.insert(%{"type" => "Create", "context" => "2hu"})
 299     {:ok, activity_two} = ActivityBuilder.insert(%{"type" => "Create", "context" => "2hu"})
 300     {:ok, _activity_three} = ActivityBuilder.insert(%{"type" => "Create", "context" => "3hu"})
 301
 302     {:ok, object} = Object.context_mapping("2hu") |> Repo.insert()
 303
 304     statuses = TwitterAPI.fetch_conversation(user, object.id)
 305
 306     assert length(statuses) == 2
 307     assert Enum.at(statuses, 1)["id"] == activity.id
 308     assert Enum.at(statuses, 0)["id"] == activity_two.id
 309   end
 310
 311   test "upload a file" do
 312     file = %Plug.Upload{
 313       content_type: "image/jpg",
 314       path: Path.absname("test/fixtures/image.jpg"),
 315       filename: "an_image.jpg"
 316     }
 317
 318     response = TwitterAPI.upload(file)
 319
 320     assert is_binary(response)
 321   end
 322
 323   test "it favorites a status, returns the updated status" do
 324     user = insert(:user)
 325     note_activity = insert(:note_activity)
 326     activity_user = Repo.get_by!(User, ap_id: note_activity.data["actor"])
 327
 328     {:ok, status} = TwitterAPI.fav(user, note_activity.id)
 329     updated_activity = Activity.get_by_ap_id(note_activity.data["id"])
 330
 331     assert status ==
 332              ActivityRepresenter.to_map(updated_activity, %{user: activity_user, for: user})
 333   end
 334
 335   test "it unfavorites a status, returns the updated status" do
 336     user = insert(:user)
 337     note_activity = insert(:note_activity)
 338     activity_user = Repo.get_by!(User, ap_id: note_activity.data["actor"])
 339     object = Object.get_by_ap_id(note_activity.data["object"]["id"])
 340
 341     {:ok, _like_activity, _object} = ActivityPub.like(user, object)
 342     updated_activity = Activity.get_by_ap_id(note_activity.data["id"])
 343
 344     assert ActivityRepresenter.to_map(updated_activity, %{user: activity_user, for: user})[
 345              "fave_num"
 346            ] == 1
 347
 348     {:ok, status} = TwitterAPI.unfav(user, note_activity.id)
 349
 350     assert status["fave_num"] == 0
 351   end
 352
 353   test "it retweets a status and returns the retweet" do
 354     user = insert(:user)
 355     note_activity = insert(:note_activity)
 356     activity_user = Repo.get_by!(User, ap_id: note_activity.data["actor"])
 357
 358     {:ok, status} = TwitterAPI.repeat(user, note_activity.id)
 359     updated_activity = Activity.get_by_ap_id(note_activity.data["id"])
 360
 361     assert status ==
 362              ActivityRepresenter.to_map(updated_activity, %{user: activity_user, for: user})
 363   end
 364
 365   test "it registers a new user and returns the user." do
 366     data = %{
 367       "nickname" => "lain",
 368       "email" => "lain@wired.jp",
 369       "fullname" => "lain iwakura",
 370       "bio" => "close the world.",
 371       "password" => "bear",
 372       "confirm" => "bear"
 373     }
 374
 375     {:ok, user} = TwitterAPI.register_user(data)
 376
 377     fetched_user = Repo.get_by(User, nickname: "lain")
 378
 379     assert UserView.render("show.json", %{user: user}) ==
 380              UserView.render("show.json", %{user: fetched_user})
 381   end
 382
 383   test "it returns the error on registration problems" do
 384     data = %{
 385       "nickname" => "lain",
 386       "email" => "lain@wired.jp",
 387       "fullname" => "lain iwakura",
 388       "bio" => "close the world.",
 389       "password" => "bear"
 390     }
 391
 392     {:error, error_object} = TwitterAPI.register_user(data)
 393
 394     assert is_binary(error_object[:error])
 395     refute Repo.get_by(User, nickname: "lain")
 396   end
 397
 398   test "it assigns an integer conversation_id" do
 399     note_activity = insert(:note_activity)
 400     user = User.get_cached_by_ap_id(note_activity.data["actor"])
 401     status = ActivityRepresenter.to_map(note_activity, %{user: user})
 402
 403     assert is_number(status["statusnet_conversation_id"])
 404   end
 405
 406   setup do
 407     Supervisor.terminate_child(Pleroma.Supervisor, Cachex)
 408     Supervisor.restart_child(Pleroma.Supervisor, Cachex)
 409     :ok
 410   end
 411
 412   describe "context_to_conversation_id" do
 413     test "creates a mapping object" do
 414       conversation_id = TwitterAPI.context_to_conversation_id("random context")
 415       object = Object.get_by_ap_id("random context")
 416
 417       assert conversation_id == object.id
 418     end
 419
 420     test "returns an existing mapping for an existing object" do
 421       {:ok, object} = Object.context_mapping("random context") |> Repo.insert()
 422       conversation_id = TwitterAPI.context_to_conversation_id("random context")
 423
 424       assert conversation_id == object.id
 425     end
 426   end
 427
 428   describe "fetching a user by uri" do
 429     test "fetches a user by uri" do
 430       id = "https://mastodon.social/users/lambadalambda"
 431       user = insert(:user)
 432       {:ok, represented} = TwitterAPI.get_external_profile(user, id)
 433       remote = User.get_by_ap_id(id)
 434
 435       assert represented["id"] == UserView.render("show.json", %{user: remote, for: user})["id"]
 436
 437       # Also fetches the feed.
 438       # assert Activity.get_create_activity_by_object_ap_id("tag:mastodon.social,2017-04-05:objectId=1641750:objectType=Status")
 439     end
 440   end
 441 end