git.squeep.com Git - akkoma/blob - test/web/twitter_api/twitter_api_test.exs

   1 defmodule Pleroma.Web.TwitterAPI.TwitterAPITest do
   2   use Pleroma.DataCase
   3   alias Pleroma.Builders.{UserBuilder, ActivityBuilder}
   4   alias Pleroma.Web.TwitterAPI.TwitterAPI
   5   alias Pleroma.{Activity, User, Object, Repo}
   6   alias Pleroma.Web.TwitterAPI.Representers.{ActivityRepresenter, UserRepresenter}
   7   alias Pleroma.Web.ActivityPub.ActivityPub
   8
   9   import Pleroma.Factory
  10
  11   test "create a status" do
  12     user = UserBuilder.build(%{ap_id: "142344"})
  13     _mentioned_user = UserBuilder.insert(%{nickname: "shp", ap_id: "shp"})
  14
  15     object_data = %{
  16       "type" => "Image",
  17       "url" => [
  18         %{
  19           "type" => "Link",
  20           "mediaType" => "image/jpg",
  21           "href" => "http://example.org/image.jpg"
  22         }
  23       ],
  24       "uuid" => 1
  25     }
  26
  27     object = Repo.insert!(%Object{data: object_data})
  28
  29     input = %{
  30       "status" => "Hello again, @shp.<script></script>\nThis is on another line.",
  31       "media_ids" => [object.id]
  32     }
  33
  34     { :ok, activity = %Activity{} } = TwitterAPI.create_status(user, input)
  35
  36     assert get_in(activity.data, ["object", "content"]) == "Hello again, <a href='shp'>@shp</a>.<br>This is on another line.<br><a href='http://example.org/image.jpg'>http://example.org/image.jpg</a>"
  37     assert get_in(activity.data, ["object", "type"]) == "Note"
  38     assert get_in(activity.data, ["object", "actor"]) == user.ap_id
  39     assert get_in(activity.data, ["actor"]) == user.ap_id
  40     assert Enum.member?(get_in(activity.data, ["to"]), User.ap_followers(user))
  41     assert Enum.member?(get_in(activity.data, ["to"]), "https://www.w3.org/ns/activitystreams#Public")
  42     assert Enum.member?(get_in(activity.data, ["to"]), "shp")
  43     assert activity.local == true
  44
  45     # Add a context
  46     assert is_binary(get_in(activity.data, ["context"]))
  47     assert is_binary(get_in(activity.data, ["object", "context"]))
  48
  49     assert is_list(activity.data["object"]["attachment"])
  50
  51     assert activity.data["object"] == Object.get_by_ap_id(activity.data["object"]["id"]).data
  52   end
  53
  54   test "create a status that is a reply" do
  55     user = UserBuilder.build(%{ap_id: "some_cool_id"})
  56     input = %{
  57       "status" => "Hello again."
  58     }
  59
  60     { :ok, activity = %Activity{} } = TwitterAPI.create_status(user, input)
  61
  62     input = %{
  63       "status" => "Here's your (you).",
  64       "in_reply_to_status_id" => activity.id
  65     }
  66
  67     { :ok, reply = %Activity{} } = TwitterAPI.create_status(user, input)
  68
  69     assert get_in(reply.data, ["context"]) == get_in(activity.data, ["context"])
  70     assert get_in(reply.data, ["object", "context"]) == get_in(activity.data, ["object", "context"])
  71     assert get_in(reply.data, ["object", "inReplyTo"]) == get_in(activity.data, ["object", "id"])
  72     assert get_in(reply.data, ["object", "inReplyToStatusId"]) == activity.id
  73     assert Enum.member?(get_in(reply.data, ["to"]), "some_cool_id")
  74   end
  75
  76   test "fetch public statuses, excluding remote ones." do
  77     %{ public: activity, user: user } = ActivityBuilder.public_and_non_public
  78     insert(:note_activity, %{local: false})
  79
  80     follower = insert(:user, following: [User.ap_followers(user)])
  81
  82     statuses = TwitterAPI.fetch_public_statuses(follower)
  83
  84     assert length(statuses) == 1
  85     assert Enum.at(statuses, 0) == ActivityRepresenter.to_map(activity, %{user: user, for: follower})
  86   end
  87
  88   test "fetch whole known network statuses" do
  89     %{ public: activity, user: user } = ActivityBuilder.public_and_non_public
  90     insert(:note_activity, %{local: false})
  91
  92     follower = insert(:user, following: [User.ap_followers(user)])
  93
  94     statuses = TwitterAPI.fetch_public_and_external_statuses(follower)
  95
  96     assert length(statuses) == 2
  97     assert Enum.at(statuses, 0) == ActivityRepresenter.to_map(activity, %{user: user, for: follower})
  98   end
  99
 100   test "fetch friends' statuses" do
 101     user = insert(:user, %{following: ["someguy/followers"]})
 102     {:ok, activity} = ActivityBuilder.insert(%{"to" => ["someguy/followers"]})
 103     {:ok, direct_activity} = ActivityBuilder.insert(%{"to" => [user.ap_id]})
 104
 105     statuses = TwitterAPI.fetch_friend_statuses(user)
 106
 107     activity_user = Repo.get_by(User, ap_id: activity.data["actor"])
 108     direct_activity_user = Repo.get_by(User, ap_id: direct_activity.data["actor"])
 109
 110     assert length(statuses) == 2
 111     assert Enum.at(statuses, 0) == ActivityRepresenter.to_map(activity, %{user: activity_user})
 112     assert Enum.at(statuses, 1) == ActivityRepresenter.to_map(direct_activity, %{user: direct_activity_user, mentioned: [user]})
 113   end
 114
 115   test "fetch user's mentions" do
 116     user = insert(:user)
 117     {:ok, activity} = ActivityBuilder.insert(%{"to" => [user.ap_id]})
 118     activity_user = Repo.get_by(User, ap_id: activity.data["actor"])
 119
 120     statuses = TwitterAPI.fetch_mentions(user)
 121
 122     assert length(statuses) == 1
 123     assert Enum.at(statuses, 0) == ActivityRepresenter.to_map(activity, %{user: activity_user, mentioned: [user]})
 124   end
 125
 126   test "get a user by params" do
 127     user1_result = {:ok, user1} = UserBuilder.insert(%{ap_id: "some id", email: "test@pleroma"})
 128     {:ok, user2} = UserBuilder.insert(%{ap_id: "some other id", nickname: "testname2", email: "test2@pleroma"})
 129
 130     assert {:error, "You need to specify screen_name or user_id"} == TwitterAPI.get_user(nil, nil)
 131     assert user1_result == TwitterAPI.get_user(nil, %{"user_id" => user1.id})
 132     assert user1_result == TwitterAPI.get_user(nil, %{"screen_name" => user1.nickname})
 133     assert user1_result == TwitterAPI.get_user(user1, nil)
 134     assert user1_result == TwitterAPI.get_user(user2, %{"user_id" => user1.id})
 135     assert user1_result == TwitterAPI.get_user(user2, %{"screen_name" => user1.nickname})
 136     assert {:error, "No user with such screen_name"} == TwitterAPI.get_user(nil, %{"screen_name" => "Satan"})
 137     assert {:error, "No user with such user_id"} == TwitterAPI.get_user(nil, %{"user_id" => 666})
 138   end
 139
 140   test "fetch user's statuses" do
 141     {:ok, user1} = UserBuilder.insert(%{ap_id: "some id", email: "test@pleroma"})
 142     {:ok, user2} = UserBuilder.insert(%{ap_id: "some other id", nickname: "testname2", email: "test2@pleroma"})
 143
 144     {:ok, status1} = ActivityBuilder.insert(%{"id" => 1}, %{user: user1})
 145     {:ok, status2} = ActivityBuilder.insert(%{"id" => 2}, %{user: user2})
 146
 147     user1_statuses = TwitterAPI.fetch_user_statuses(user1, %{"actor_id" => user1.ap_id})
 148
 149     assert length(user1_statuses) == 1
 150     assert Enum.at(user1_statuses, 0) == ActivityRepresenter.to_map(status1, %{user: user1})
 151
 152     user2_statuses = TwitterAPI.fetch_user_statuses(user1, %{"actor_id" => user2.ap_id})
 153
 154     assert length(user2_statuses) == 1
 155     assert Enum.at(user2_statuses, 0) == ActivityRepresenter.to_map(status2, %{user: user2})
 156   end
 157
 158   test "fetch a single status" do
 159     {:ok, activity} = ActivityBuilder.insert()
 160     {:ok, user} = UserBuilder.insert()
 161     actor = Repo.get_by!(User, ap_id: activity.data["actor"])
 162
 163     status = TwitterAPI.fetch_status(user, activity.id)
 164
 165     assert status == ActivityRepresenter.to_map(activity, %{for: user, user: actor})
 166   end
 167
 168   test "Follow another user using user_id" do
 169     user = insert(:user)
 170     followed = insert(:user)
 171
 172     {:ok, user, followed, _activity } = TwitterAPI.follow(user, %{"user_id" => followed.id})
 173     assert user.following == [User.ap_followers(followed)]
 174
 175     { :error, msg } = TwitterAPI.follow(user, %{"user_id" => followed.id})
 176     assert msg == "Could not follow user: #{followed.nickname} is already on your list."
 177   end
 178
 179   test "Follow another user using screen_name" do
 180     user = insert(:user)
 181     followed = insert(:user)
 182
 183     {:ok, user, followed, _activity } = TwitterAPI.follow(user, %{"screen_name" => followed.nickname})
 184     assert user.following == [User.ap_followers(followed)]
 185
 186     { :error, msg } = TwitterAPI.follow(user, %{"screen_name" => followed.nickname})
 187     assert msg == "Could not follow user: #{followed.nickname} is already on your list."
 188   end
 189
 190   test "Unfollow another user using user_id" do
 191     unfollowed = insert(:user)
 192     user = insert(:user, %{following: [User.ap_followers(unfollowed)]})
 193
 194     {:ok, user, unfollowed } = TwitterAPI.unfollow(user, %{"user_id" => unfollowed.id})
 195     assert user.following == []
 196
 197     { :error, msg } = TwitterAPI.unfollow(user, %{"user_id" => unfollowed.id})
 198     assert msg == "Not subscribed!"
 199   end
 200
 201   test "Unfollow another user using screen_name" do
 202     unfollowed = insert(:user)
 203     user = insert(:user, %{following: [User.ap_followers(unfollowed)]})
 204
 205     {:ok, user, unfollowed } = TwitterAPI.unfollow(user, %{"screen_name" => unfollowed.nickname})
 206     assert user.following == []
 207
 208     { :error, msg } = TwitterAPI.unfollow(user, %{"screen_name" => unfollowed.nickname})
 209     assert msg == "Not subscribed!"
 210   end
 211
 212   test "fetch statuses in a context using the conversation id" do
 213     {:ok, user} = UserBuilder.insert()
 214     {:ok, activity} = ActivityBuilder.insert(%{"context" => "2hu"})
 215     {:ok, activity_two} = ActivityBuilder.insert(%{"context" => "2hu"})
 216     {:ok, _activity_three} = ActivityBuilder.insert(%{"context" => "3hu"})
 217
 218     {:ok, object} = Object.context_mapping("2hu") |> Repo.insert
 219
 220     statuses = TwitterAPI.fetch_conversation(user, object.id)
 221
 222     assert length(statuses) == 2
 223     assert Enum.at(statuses, 0)["id"] == activity.id
 224     assert Enum.at(statuses, 1)["id"] == activity_two.id
 225   end
 226
 227   test "upload a file" do
 228     file = %Plug.Upload{content_type: "image/jpg", path: Path.absname("test/fixtures/image.jpg"), filename: "an_image.jpg"}
 229
 230     response = TwitterAPI.upload(file)
 231
 232     assert is_binary(response)
 233   end
 234
 235   test "it can parse mentions and return the relevant users" do
 236     text = "@gsimg According to @archaeme , that is @daggsy."
 237
 238     gsimg = insert(:user, %{nickname: "gsimg"})
 239     archaeme = insert(:user, %{nickname: "archaeme"})
 240
 241     expected_result = [
 242       {"@gsimg", gsimg},
 243       {"@archaeme", archaeme}
 244     ]
 245
 246     assert TwitterAPI.parse_mentions(text) == expected_result
 247   end
 248
 249   test "it adds user links to an existing text" do
 250     text = "@gsimg According to @archaeme , that is @daggsy."
 251
 252     gsimg = insert(:user, %{nickname: "gsimg"})
 253     archaeme = insert(:user, %{nickname: "archaeme"})
 254
 255     mentions = TwitterAPI.parse_mentions(text)
 256     expected_text = "<a href='#{gsimg.ap_id}'>@gsimg</a> According to <a href='#{archaeme.ap_id}'>@archaeme</a> , that is @daggsy."
 257
 258     assert TwitterAPI.add_user_links(text, mentions) == expected_text
 259   end
 260
 261   test "it favorites a status, returns the updated status" do
 262     user = insert(:user)
 263     note_activity = insert(:note_activity)
 264     activity_user = Repo.get_by!(User, ap_id: note_activity.data["actor"])
 265
 266     {:ok, status} = TwitterAPI.favorite(user, note_activity)
 267     updated_activity = Activity.get_by_ap_id(note_activity.data["id"])
 268
 269     assert status == ActivityRepresenter.to_map(updated_activity, %{user: activity_user, for: user})
 270   end
 271
 272   test "it unfavorites a status, returns the updated status" do
 273     user = insert(:user)
 274     note_activity = insert(:note_activity)
 275     activity_user = Repo.get_by!(User, ap_id: note_activity.data["actor"])
 276     object = Object.get_by_ap_id(note_activity.data["object"]["id"])
 277
 278     {:ok, _like_activity, _object } = ActivityPub.like(user, object)
 279     updated_activity = Activity.get_by_ap_id(note_activity.data["id"])
 280     assert ActivityRepresenter.to_map(updated_activity, %{user: activity_user, for: user})["fave_num"] == 1
 281
 282     {:ok, status} = TwitterAPI.unfavorite(user, note_activity)
 283
 284     assert status["fave_num"] == 0
 285   end
 286
 287   test "it retweets a status and returns the retweet" do
 288     user = insert(:user)
 289     note_activity = insert(:note_activity)
 290     activity_user = Repo.get_by!(User, ap_id: note_activity.data["actor"])
 291
 292     {:ok, status} = TwitterAPI.retweet(user, note_activity)
 293     updated_activity = Activity.get_by_ap_id(note_activity.data["id"])
 294
 295     assert status == ActivityRepresenter.to_map(updated_activity, %{user: activity_user, for: user})
 296   end
 297
 298   test "it registers a new user and returns the user." do
 299     data = %{
 300       "nickname" => "lain",
 301       "email" => "lain@wired.jp",
 302       "fullname" => "lain iwakura",
 303       "bio" => "close the world.",
 304       "password" => "bear",
 305       "confirm" => "bear"
 306     }
 307
 308     {:ok, user} = TwitterAPI.register_user(data)
 309
 310     fetched_user = Repo.get_by(User, nickname: "lain")
 311     assert user == UserRepresenter.to_map(fetched_user)
 312   end
 313
 314   test "it returns the error on registration problems" do
 315     data = %{
 316       "nickname" => "lain",
 317       "email" => "lain@wired.jp",
 318       "fullname" => "lain iwakura",
 319       "bio" => "close the world.",
 320       "password" => "bear"
 321     }
 322
 323     {:error, error_object} = TwitterAPI.register_user(data)
 324
 325     assert is_binary(error_object[:error])
 326     refute Repo.get_by(User, nickname: "lain")
 327   end
 328
 329   test "it assigns an integer conversation_id" do
 330     note_activity = insert(:note_activity)
 331     user = User.get_cached_by_ap_id(note_activity.data["actor"])
 332     status = ActivityRepresenter.to_map(note_activity, %{user: user})
 333
 334     assert is_number(status["statusnet_conversation_id"])
 335   end
 336
 337   setup do
 338     Supervisor.terminate_child(Pleroma.Supervisor, Cachex)
 339     Supervisor.restart_child(Pleroma.Supervisor, Cachex)
 340     :ok
 341   end
 342
 343   describe "context_to_conversation_id" do
 344     test "creates a mapping object" do
 345       conversation_id = TwitterAPI.context_to_conversation_id("random context")
 346       object = Object.get_by_ap_id("random context")
 347
 348       assert conversation_id == object.id
 349     end
 350
 351     test "returns an existing mapping for an existing object" do
 352       {:ok, object} = Object.context_mapping("random context") |> Repo.insert
 353       conversation_id = TwitterAPI.context_to_conversation_id("random context")
 354
 355       assert conversation_id == object.id
 356     end
 357   end
 358 end