git.squeep.com Git - akkoma/blob - test/web/twitter_api/twitter_api_test.exs

   1 defmodule Pleroma.Web.TwitterAPI.TwitterAPITest do
   2   use Pleroma.DataCase
   3   alias Pleroma.Builders.{UserBuilder, ActivityBuilder}
   4   alias Pleroma.Web.TwitterAPI.TwitterAPI
   5   alias Pleroma.{Activity, User, Object, Repo}
   6   alias Pleroma.Web.TwitterAPI.Representers.{ActivityRepresenter, UserRepresenter}
   7   alias Pleroma.Web.ActivityPub.ActivityPub
   8
   9   import Pleroma.Factory
  10
  11   test "create a status" do
  12     user = UserBuilder.build(%{ap_id: "142344"})
  13     _mentioned_user = UserBuilder.insert(%{nickname: "shp", ap_id: "shp"})
  14
  15     object_data = %{
  16       "type" => "Image",
  17       "url" => [
  18         %{
  19           "type" => "Link",
  20           "mediaType" => "image/jpg",
  21           "href" => "http://example.org/image.jpg"
  22         }
  23       ],
  24       "uuid" => 1
  25     }
  26
  27     object = Repo.insert!(%Object{data: object_data})
  28
  29     input = %{
  30       "status" => "Hello again, @shp.<script></script>\nThis is on another line.",
  31       "media_ids" => [object.id]
  32     }
  33
  34     { :ok, activity = %Activity{} } = TwitterAPI.create_status(user, input)
  35
  36     assert get_in(activity.data, ["object", "content"]) == "Hello again, <a href='shp'>@shp</a>.<br>This is on another line."
  37     assert get_in(activity.data, ["object", "type"]) == "Note"
  38     assert get_in(activity.data, ["object", "actor"]) == user.ap_id
  39     assert get_in(activity.data, ["actor"]) == user.ap_id
  40     assert Enum.member?(get_in(activity.data, ["to"]), User.ap_followers(user))
  41     assert Enum.member?(get_in(activity.data, ["to"]), "https://www.w3.org/ns/activitystreams#Public")
  42     assert Enum.member?(get_in(activity.data, ["to"]), "shp")
  43
  44     # Add a context + 'statusnet_conversation_id'
  45     assert is_binary(get_in(activity.data, ["context"]))
  46     assert is_binary(get_in(activity.data, ["object", "context"]))
  47     assert get_in(activity.data, ["object", "statusnetConversationId"]) == activity.id
  48     assert get_in(activity.data, ["statusnetConversationId"]) == activity.id
  49
  50     assert is_list(activity.data["object"]["attachment"])
  51
  52     assert activity.data["object"] == Object.get_by_ap_id(activity.data["object"]["id"]).data
  53   end
  54
  55   test "create a status that is a reply" do
  56     user = UserBuilder.build(%{ap_id: "some_cool_id"})
  57     input = %{
  58       "status" => "Hello again."
  59     }
  60
  61     { :ok, activity = %Activity{} } = TwitterAPI.create_status(user, input)
  62
  63     input = %{
  64       "status" => "Here's your (you).",
  65       "in_reply_to_status_id" => activity.id
  66     }
  67
  68     { :ok, reply = %Activity{} } = TwitterAPI.create_status(user, input)
  69
  70     assert get_in(reply.data, ["context"]) == get_in(activity.data, ["context"])
  71     assert get_in(reply.data, ["object", "context"]) == get_in(activity.data, ["object", "context"])
  72     assert get_in(reply.data, ["statusnetConversationId"]) == get_in(activity.data, ["statusnetConversationId"])
  73     assert get_in(reply.data, ["object", "statusnetConversationId"]) == get_in(activity.data, ["object", "statusnetConversationId"])
  74     assert get_in(reply.data, ["object", "inReplyTo"]) == get_in(activity.data, ["object", "id"])
  75     assert get_in(reply.data, ["object", "inReplyToStatusId"]) == activity.id
  76     assert Enum.member?(get_in(reply.data, ["to"]), "some_cool_id")
  77   end
  78
  79   test "fetch public statuses" do
  80     %{ public: activity, user: user } = ActivityBuilder.public_and_non_public
  81
  82     follower = insert(:user, following: [User.ap_followers(user)])
  83
  84     statuses = TwitterAPI.fetch_public_statuses(follower)
  85
  86     assert length(statuses) == 1
  87     assert Enum.at(statuses, 0) == ActivityRepresenter.to_map(activity, %{user: user, for: follower})
  88   end
  89
  90   test "fetch friends' statuses" do
  91     user = insert(:user, %{following: ["someguy/followers"]})
  92     {:ok, activity} = ActivityBuilder.insert(%{"to" => ["someguy/followers"]})
  93     {:ok, direct_activity} = ActivityBuilder.insert(%{"to" => [user.ap_id]})
  94
  95     statuses = TwitterAPI.fetch_friend_statuses(user)
  96
  97     activity_user = Repo.get_by(User, ap_id: activity.data["actor"])
  98     direct_activity_user = Repo.get_by(User, ap_id: direct_activity.data["actor"])
  99
 100     assert length(statuses) == 2
 101     assert Enum.at(statuses, 0) == ActivityRepresenter.to_map(activity, %{user: activity_user})
 102     assert Enum.at(statuses, 1) == ActivityRepresenter.to_map(direct_activity, %{user: direct_activity_user, mentioned: [user]})
 103   end
 104
 105   test "fetch user's mentions" do
 106     user = insert(:user)
 107     {:ok, activity} = ActivityBuilder.insert(%{"to" => [user.ap_id]})
 108     activity_user = Repo.get_by(User, ap_id: activity.data["actor"])
 109
 110     statuses = TwitterAPI.fetch_mentions(user)
 111
 112     assert length(statuses) == 1
 113     assert Enum.at(statuses, 0) == ActivityRepresenter.to_map(activity, %{user: activity_user, mentioned: [user]})
 114   end
 115
 116   test "get a user by params" do
 117     user1_result = {:ok, user1} = UserBuilder.insert(%{ap_id: "some id", email: "test@pleroma"})
 118     {:ok, user2} = UserBuilder.insert(%{ap_id: "some other id", nickname: "testname2", email: "test2@pleroma"})
 119
 120     assert {:error, "You need to specify screen_name or user_id"} == TwitterAPI.get_user(nil, nil)
 121     assert user1_result == TwitterAPI.get_user(nil, %{"user_id" => user1.id})
 122     assert user1_result == TwitterAPI.get_user(nil, %{"screen_name" => user1.nickname})
 123     assert user1_result == TwitterAPI.get_user(user1, nil)
 124     assert user1_result == TwitterAPI.get_user(user2, %{"user_id" => user1.id})
 125     assert user1_result == TwitterAPI.get_user(user2, %{"screen_name" => user1.nickname})
 126     assert {:error, "No user with such screen_name"} == TwitterAPI.get_user(nil, %{"screen_name" => "Satan"})
 127     assert {:error, "No user with such user_id"} == TwitterAPI.get_user(nil, %{"user_id" => 666})
 128   end
 129
 130   test "fetch user's statuses" do
 131     {:ok, user1} = UserBuilder.insert(%{ap_id: "some id", email: "test@pleroma"})
 132     {:ok, user2} = UserBuilder.insert(%{ap_id: "some other id", nickname: "testname2", email: "test2@pleroma"})
 133
 134     {:ok, status1} = ActivityBuilder.insert(%{"id" => 1}, %{user: user1})
 135     {:ok, status2} = ActivityBuilder.insert(%{"id" => 2}, %{user: user2})
 136
 137     user1_statuses = TwitterAPI.fetch_user_statuses(user1, %{"actor_id" => user1.ap_id})
 138
 139     assert length(user1_statuses) == 1
 140     assert Enum.at(user1_statuses, 0) == ActivityRepresenter.to_map(status1, %{user: user1})
 141
 142     user2_statuses = TwitterAPI.fetch_user_statuses(user1, %{"actor_id" => user2.ap_id})
 143
 144     assert length(user2_statuses) == 1
 145     assert Enum.at(user2_statuses, 0) == ActivityRepresenter.to_map(status2, %{user: user2})
 146   end
 147
 148   test "fetch a single status" do
 149     {:ok, activity} = ActivityBuilder.insert()
 150     {:ok, user} = UserBuilder.insert()
 151     actor = Repo.get_by!(User, ap_id: activity.data["actor"])
 152
 153     status = TwitterAPI.fetch_status(user, activity.id)
 154
 155     assert status == ActivityRepresenter.to_map(activity, %{for: user, user: actor})
 156   end
 157
 158   test "Follow another user using user_id" do
 159     user = insert(:user)
 160     followed = insert(:user)
 161
 162     {:ok, user, followed, _activity } = TwitterAPI.follow(user, %{"user_id" => followed.id})
 163     assert user.following == [User.ap_followers(followed)]
 164
 165     { :error, msg } = TwitterAPI.follow(user, %{"user_id" => followed.id})
 166     assert msg == "Could not follow user: #{followed.nickname} is already on your list."
 167   end
 168
 169   test "Follow another user using screen_name" do
 170     user = insert(:user)
 171     followed = insert(:user)
 172
 173     {:ok, user, followed, _activity } = TwitterAPI.follow(user, %{"screen_name" => followed.nickname})
 174     assert user.following == [User.ap_followers(followed)]
 175
 176     { :error, msg } = TwitterAPI.follow(user, %{"screen_name" => followed.nickname})
 177     assert msg == "Could not follow user: #{followed.nickname} is already on your list."
 178   end
 179
 180   test "Unfollow another user using user_id" do
 181     unfollowed = insert(:user)
 182     user = insert(:user, %{following: [User.ap_followers(unfollowed)]})
 183
 184     {:ok, user, unfollowed } = TwitterAPI.unfollow(user, %{"user_id" => unfollowed.id})
 185     assert user.following == []
 186
 187     { :error, msg } = TwitterAPI.unfollow(user, %{"user_id" => unfollowed.id})
 188     assert msg == "Not subscribed!"
 189   end
 190
 191   test "Unfollow another user using screen_name" do
 192     unfollowed = insert(:user)
 193     user = insert(:user, %{following: [User.ap_followers(unfollowed)]})
 194
 195     {:ok, user, unfollowed } = TwitterAPI.unfollow(user, %{"screen_name" => unfollowed.nickname})
 196     assert user.following == []
 197
 198     { :error, msg } = TwitterAPI.unfollow(user, %{"screen_name" => unfollowed.nickname})
 199     assert msg == "Not subscribed!"
 200   end
 201
 202   test "fetch statuses in a context using the conversation id" do
 203     {:ok, user} = UserBuilder.insert()
 204     {:ok, activity} = ActivityBuilder.insert(%{"statusnetConversationId" => 1, "context" => "2hu"})
 205     {:ok, activity_two} = ActivityBuilder.insert(%{"statusnetConversationId" => 1,"context" => "2hu"})
 206     {:ok, _activity_three} = ActivityBuilder.insert(%{"context" => "3hu"})
 207
 208     statuses = TwitterAPI.fetch_conversation(user, 1)
 209
 210     assert length(statuses) == 2
 211     assert Enum.at(statuses, 0)["id"] == activity.id
 212     assert Enum.at(statuses, 1)["id"] == activity_two.id
 213   end
 214
 215   test "upload a file" do
 216     file = %Plug.Upload{content_type: "image/jpg", path: Path.absname("test/fixtures/image.jpg"), filename: "an_image.jpg"}
 217
 218     response = TwitterAPI.upload(file)
 219
 220     assert is_binary(response)
 221   end
 222
 223   test "it can parse mentions and return the relevant users" do
 224     text = "@gsimg According to @archaeme , that is @daggsy."
 225
 226     gsimg = insert(:user, %{nickname: "gsimg"})
 227     archaeme = insert(:user, %{nickname: "archaeme"})
 228
 229     expected_result = [
 230       {"@gsimg", gsimg},
 231       {"@archaeme", archaeme}
 232     ]
 233
 234     assert TwitterAPI.parse_mentions(text) == expected_result
 235   end
 236
 237   test "it adds user links to an existing text" do
 238     text = "@gsimg According to @archaeme , that is @daggsy."
 239
 240     gsimg = insert(:user, %{nickname: "gsimg"})
 241     archaeme = insert(:user, %{nickname: "archaeme"})
 242
 243     mentions = TwitterAPI.parse_mentions(text)
 244     expected_text = "<a href='#{gsimg.ap_id}'>@gsimg</a> According to <a href='#{archaeme.ap_id}'>@archaeme</a> , that is @daggsy."
 245
 246     assert TwitterAPI.add_user_links(text, mentions) == expected_text
 247   end
 248
 249   test "it favorites a status, returns the updated status" do
 250     user = insert(:user)
 251     note_activity = insert(:note_activity)
 252     activity_user = Repo.get_by!(User, ap_id: note_activity.data["actor"])
 253
 254     {:ok, status} = TwitterAPI.favorite(user, note_activity)
 255     updated_activity = Activity.get_by_ap_id(note_activity.data["id"])
 256
 257     assert status == ActivityRepresenter.to_map(updated_activity, %{user: activity_user, for: user})
 258   end
 259
 260   test "it unfavorites a status, returns the updated status" do
 261     user = insert(:user)
 262     note_activity = insert(:note_activity)
 263     activity_user = Repo.get_by!(User, ap_id: note_activity.data["actor"])
 264     object = Object.get_by_ap_id(note_activity.data["object"]["id"])
 265
 266     {:ok, _like_activity, _object } = ActivityPub.like(user, object)
 267     updated_activity = Activity.get_by_ap_id(note_activity.data["id"])
 268     assert ActivityRepresenter.to_map(updated_activity, %{user: activity_user, for: user})["fave_num"] == 1
 269
 270     {:ok, status} = TwitterAPI.unfavorite(user, note_activity)
 271
 272     assert status["fave_num"] == 0
 273   end
 274
 275   test "it retweets a status and returns the retweet" do
 276     user = insert(:user)
 277     note_activity = insert(:note_activity)
 278     activity_user = Repo.get_by!(User, ap_id: note_activity.data["actor"])
 279
 280     {:ok, status} = TwitterAPI.retweet(user, note_activity)
 281     updated_activity = Activity.get_by_ap_id(note_activity.data["id"])
 282
 283     assert status == ActivityRepresenter.to_map(updated_activity, %{user: activity_user, for: user})
 284   end
 285
 286   test "it registers a new user and returns the user." do
 287     data = %{
 288       "nickname" => "lain",
 289       "email" => "lain@wired.jp",
 290       "fullname" => "lain iwakura",
 291       "bio" => "close the world.",
 292       "password" => "bear",
 293       "confirm" => "bear"
 294     }
 295
 296     {:ok, user} = TwitterAPI.register_user(data)
 297
 298     fetched_user = Repo.get_by(User, nickname: "lain")
 299     assert user == UserRepresenter.to_map(fetched_user)
 300   end
 301
 302   test "it returns the error on registration problems" do
 303     data = %{
 304       "nickname" => "lain",
 305       "email" => "lain@wired.jp",
 306       "fullname" => "lain iwakura",
 307       "bio" => "close the world.",
 308       "password" => "bear"
 309     }
 310
 311     {:error, error_object} = TwitterAPI.register_user(data)
 312
 313     assert is_binary(error_object[:error])
 314     refute Repo.get_by(User, nickname: "lain")
 315   end
 316
 317   setup do
 318     Supervisor.terminate_child(Pleroma.Supervisor, Cachex)
 319     Supervisor.restart_child(Pleroma.Supervisor, Cachex)
 320     :ok
 321   end
 322 end