git.squeep.com Git - akkoma/blob - test/web/twitter_api/twitter_api_test.exs

   1 defmodule Pleroma.Web.TwitterAPI.TwitterAPITest do
   2   use Pleroma.DataCase
   3   alias Pleroma.Builders.{UserBuilder, ActivityBuilder}
   4   alias Pleroma.Web.TwitterAPI.TwitterAPI
   5   alias Pleroma.{Activity, User, Object, Repo}
   6   alias Pleroma.Web.TwitterAPI.Representers.{ActivityRepresenter, UserRepresenter}
   7   alias Pleroma.Web.ActivityPub.ActivityPub
   8
   9   import Pleroma.Factory
  10
  11   test "create a status" do
  12     user = UserBuilder.build(%{ap_id: "142344"})
  13     _mentioned_user = UserBuilder.insert(%{nickname: "shp", ap_id: "shp"})
  14
  15     object_data = %{
  16       "type" => "Image",
  17       "url" => [
  18         %{
  19           "type" => "Link",
  20           "mediaType" => "image/jpg",
  21           "href" => "http://example.org/image.jpg"
  22         }
  23       ],
  24       "uuid" => 1
  25     }
  26
  27     object = Repo.insert!(%Object{data: object_data})
  28
  29     input = %{
  30       "status" => "Hello again, @shp.<script></script>\nThis is on another line.",
  31       "media_ids" => [object.id]
  32     }
  33
  34     { :ok, activity = %Activity{} } = TwitterAPI.create_status(user, input)
  35
  36     assert get_in(activity.data, ["object", "content"]) == "Hello again, <a href='shp'>@shp</a>.<br>This is on another line."
  37     assert get_in(activity.data, ["object", "type"]) == "Note"
  38     assert get_in(activity.data, ["object", "actor"]) == user.ap_id
  39     assert get_in(activity.data, ["actor"]) == user.ap_id
  40     assert Enum.member?(get_in(activity.data, ["to"]), User.ap_followers(user))
  41     assert Enum.member?(get_in(activity.data, ["to"]), "https://www.w3.org/ns/activitystreams#Public")
  42     assert Enum.member?(get_in(activity.data, ["to"]), "shp")
  43
  44     # Add a context
  45     assert is_binary(get_in(activity.data, ["context"]))
  46     assert is_binary(get_in(activity.data, ["object", "context"]))
  47
  48     assert is_list(activity.data["object"]["attachment"])
  49
  50     assert activity.data["object"] == Object.get_by_ap_id(activity.data["object"]["id"]).data
  51   end
  52
  53   test "create a status that is a reply" do
  54     user = UserBuilder.build(%{ap_id: "some_cool_id"})
  55     input = %{
  56       "status" => "Hello again."
  57     }
  58
  59     { :ok, activity = %Activity{} } = TwitterAPI.create_status(user, input)
  60
  61     input = %{
  62       "status" => "Here's your (you).",
  63       "in_reply_to_status_id" => activity.id
  64     }
  65
  66     { :ok, reply = %Activity{} } = TwitterAPI.create_status(user, input)
  67
  68     assert get_in(reply.data, ["context"]) == get_in(activity.data, ["context"])
  69     assert get_in(reply.data, ["object", "context"]) == get_in(activity.data, ["object", "context"])
  70     assert get_in(reply.data, ["object", "inReplyTo"]) == get_in(activity.data, ["object", "id"])
  71     assert get_in(reply.data, ["object", "inReplyToStatusId"]) == activity.id
  72     assert Enum.member?(get_in(reply.data, ["to"]), "some_cool_id")
  73   end
  74
  75   test "fetch public statuses" do
  76     %{ public: activity, user: user } = ActivityBuilder.public_and_non_public
  77
  78     follower = insert(:user, following: [User.ap_followers(user)])
  79
  80     statuses = TwitterAPI.fetch_public_statuses(follower)
  81
  82     assert length(statuses) == 1
  83     assert Enum.at(statuses, 0) == ActivityRepresenter.to_map(activity, %{user: user, for: follower})
  84   end
  85
  86   test "fetch friends' statuses" do
  87     user = insert(:user, %{following: ["someguy/followers"]})
  88     {:ok, activity} = ActivityBuilder.insert(%{"to" => ["someguy/followers"]})
  89     {:ok, direct_activity} = ActivityBuilder.insert(%{"to" => [user.ap_id]})
  90
  91     statuses = TwitterAPI.fetch_friend_statuses(user)
  92
  93     activity_user = Repo.get_by(User, ap_id: activity.data["actor"])
  94     direct_activity_user = Repo.get_by(User, ap_id: direct_activity.data["actor"])
  95
  96     assert length(statuses) == 2
  97     assert Enum.at(statuses, 0) == ActivityRepresenter.to_map(activity, %{user: activity_user})
  98     assert Enum.at(statuses, 1) == ActivityRepresenter.to_map(direct_activity, %{user: direct_activity_user, mentioned: [user]})
  99   end
 100
 101   test "fetch user's mentions" do
 102     user = insert(:user)
 103     {:ok, activity} = ActivityBuilder.insert(%{"to" => [user.ap_id]})
 104     activity_user = Repo.get_by(User, ap_id: activity.data["actor"])
 105
 106     statuses = TwitterAPI.fetch_mentions(user)
 107
 108     assert length(statuses) == 1
 109     assert Enum.at(statuses, 0) == ActivityRepresenter.to_map(activity, %{user: activity_user, mentioned: [user]})
 110   end
 111
 112   test "get a user by params" do
 113     user1_result = {:ok, user1} = UserBuilder.insert(%{ap_id: "some id", email: "test@pleroma"})
 114     {:ok, user2} = UserBuilder.insert(%{ap_id: "some other id", nickname: "testname2", email: "test2@pleroma"})
 115
 116     assert {:error, "You need to specify screen_name or user_id"} == TwitterAPI.get_user(nil, nil)
 117     assert user1_result == TwitterAPI.get_user(nil, %{"user_id" => user1.id})
 118     assert user1_result == TwitterAPI.get_user(nil, %{"screen_name" => user1.nickname})
 119     assert user1_result == TwitterAPI.get_user(user1, nil)
 120     assert user1_result == TwitterAPI.get_user(user2, %{"user_id" => user1.id})
 121     assert user1_result == TwitterAPI.get_user(user2, %{"screen_name" => user1.nickname})
 122     assert {:error, "No user with such screen_name"} == TwitterAPI.get_user(nil, %{"screen_name" => "Satan"})
 123     assert {:error, "No user with such user_id"} == TwitterAPI.get_user(nil, %{"user_id" => 666})
 124   end
 125
 126   test "fetch user's statuses" do
 127     {:ok, user1} = UserBuilder.insert(%{ap_id: "some id", email: "test@pleroma"})
 128     {:ok, user2} = UserBuilder.insert(%{ap_id: "some other id", nickname: "testname2", email: "test2@pleroma"})
 129
 130     {:ok, status1} = ActivityBuilder.insert(%{"id" => 1}, %{user: user1})
 131     {:ok, status2} = ActivityBuilder.insert(%{"id" => 2}, %{user: user2})
 132
 133     user1_statuses = TwitterAPI.fetch_user_statuses(user1, %{"actor_id" => user1.ap_id})
 134
 135     assert length(user1_statuses) == 1
 136     assert Enum.at(user1_statuses, 0) == ActivityRepresenter.to_map(status1, %{user: user1})
 137
 138     user2_statuses = TwitterAPI.fetch_user_statuses(user1, %{"actor_id" => user2.ap_id})
 139
 140     assert length(user2_statuses) == 1
 141     assert Enum.at(user2_statuses, 0) == ActivityRepresenter.to_map(status2, %{user: user2})
 142   end
 143
 144   test "fetch a single status" do
 145     {:ok, activity} = ActivityBuilder.insert()
 146     {:ok, user} = UserBuilder.insert()
 147     actor = Repo.get_by!(User, ap_id: activity.data["actor"])
 148
 149     status = TwitterAPI.fetch_status(user, activity.id)
 150
 151     assert status == ActivityRepresenter.to_map(activity, %{for: user, user: actor})
 152   end
 153
 154   test "Follow another user using user_id" do
 155     user = insert(:user)
 156     followed = insert(:user)
 157
 158     {:ok, user, followed, _activity } = TwitterAPI.follow(user, %{"user_id" => followed.id})
 159     assert user.following == [User.ap_followers(followed)]
 160
 161     { :error, msg } = TwitterAPI.follow(user, %{"user_id" => followed.id})
 162     assert msg == "Could not follow user: #{followed.nickname} is already on your list."
 163   end
 164
 165   test "Follow another user using screen_name" do
 166     user = insert(:user)
 167     followed = insert(:user)
 168
 169     {:ok, user, followed, _activity } = TwitterAPI.follow(user, %{"screen_name" => followed.nickname})
 170     assert user.following == [User.ap_followers(followed)]
 171
 172     { :error, msg } = TwitterAPI.follow(user, %{"screen_name" => followed.nickname})
 173     assert msg == "Could not follow user: #{followed.nickname} is already on your list."
 174   end
 175
 176   test "Unfollow another user using user_id" do
 177     unfollowed = insert(:user)
 178     user = insert(:user, %{following: [User.ap_followers(unfollowed)]})
 179
 180     {:ok, user, unfollowed } = TwitterAPI.unfollow(user, %{"user_id" => unfollowed.id})
 181     assert user.following == []
 182
 183     { :error, msg } = TwitterAPI.unfollow(user, %{"user_id" => unfollowed.id})
 184     assert msg == "Not subscribed!"
 185   end
 186
 187   test "Unfollow another user using screen_name" do
 188     unfollowed = insert(:user)
 189     user = insert(:user, %{following: [User.ap_followers(unfollowed)]})
 190
 191     {:ok, user, unfollowed } = TwitterAPI.unfollow(user, %{"screen_name" => unfollowed.nickname})
 192     assert user.following == []
 193
 194     { :error, msg } = TwitterAPI.unfollow(user, %{"screen_name" => unfollowed.nickname})
 195     assert msg == "Not subscribed!"
 196   end
 197
 198   test "fetch statuses in a context using the conversation id" do
 199     {:ok, user} = UserBuilder.insert()
 200     {:ok, activity} = ActivityBuilder.insert(%{"context" => "2hu"})
 201     {:ok, activity_two} = ActivityBuilder.insert(%{"context" => "2hu"})
 202     {:ok, _activity_three} = ActivityBuilder.insert(%{"context" => "3hu"})
 203
 204     {:ok, object} = Object.context_mapping("2hu") |> Repo.insert
 205
 206     statuses = TwitterAPI.fetch_conversation(user, object.id)
 207
 208     assert length(statuses) == 2
 209     assert Enum.at(statuses, 0)["id"] == activity.id
 210     assert Enum.at(statuses, 1)["id"] == activity_two.id
 211   end
 212
 213   test "upload a file" do
 214     file = %Plug.Upload{content_type: "image/jpg", path: Path.absname("test/fixtures/image.jpg"), filename: "an_image.jpg"}
 215
 216     response = TwitterAPI.upload(file)
 217
 218     assert is_binary(response)
 219   end
 220
 221   test "it can parse mentions and return the relevant users" do
 222     text = "@gsimg According to @archaeme , that is @daggsy."
 223
 224     gsimg = insert(:user, %{nickname: "gsimg"})
 225     archaeme = insert(:user, %{nickname: "archaeme"})
 226
 227     expected_result = [
 228       {"@gsimg", gsimg},
 229       {"@archaeme", archaeme}
 230     ]
 231
 232     assert TwitterAPI.parse_mentions(text) == expected_result
 233   end
 234
 235   test "it adds user links to an existing text" do
 236     text = "@gsimg According to @archaeme , that is @daggsy."
 237
 238     gsimg = insert(:user, %{nickname: "gsimg"})
 239     archaeme = insert(:user, %{nickname: "archaeme"})
 240
 241     mentions = TwitterAPI.parse_mentions(text)
 242     expected_text = "<a href='#{gsimg.ap_id}'>@gsimg</a> According to <a href='#{archaeme.ap_id}'>@archaeme</a> , that is @daggsy."
 243
 244     assert TwitterAPI.add_user_links(text, mentions) == expected_text
 245   end
 246
 247   test "it favorites a status, returns the updated status" do
 248     user = insert(:user)
 249     note_activity = insert(:note_activity)
 250     activity_user = Repo.get_by!(User, ap_id: note_activity.data["actor"])
 251
 252     {:ok, status} = TwitterAPI.favorite(user, note_activity)
 253     updated_activity = Activity.get_by_ap_id(note_activity.data["id"])
 254
 255     assert status == ActivityRepresenter.to_map(updated_activity, %{user: activity_user, for: user})
 256   end
 257
 258   test "it unfavorites a status, returns the updated status" do
 259     user = insert(:user)
 260     note_activity = insert(:note_activity)
 261     activity_user = Repo.get_by!(User, ap_id: note_activity.data["actor"])
 262     object = Object.get_by_ap_id(note_activity.data["object"]["id"])
 263
 264     {:ok, _like_activity, _object } = ActivityPub.like(user, object)
 265     updated_activity = Activity.get_by_ap_id(note_activity.data["id"])
 266     assert ActivityRepresenter.to_map(updated_activity, %{user: activity_user, for: user})["fave_num"] == 1
 267
 268     {:ok, status} = TwitterAPI.unfavorite(user, note_activity)
 269
 270     assert status["fave_num"] == 0
 271   end
 272
 273   test "it retweets a status and returns the retweet" do
 274     user = insert(:user)
 275     note_activity = insert(:note_activity)
 276     activity_user = Repo.get_by!(User, ap_id: note_activity.data["actor"])
 277
 278     {:ok, status} = TwitterAPI.retweet(user, note_activity)
 279     updated_activity = Activity.get_by_ap_id(note_activity.data["id"])
 280
 281     assert status == ActivityRepresenter.to_map(updated_activity, %{user: activity_user, for: user})
 282   end
 283
 284   test "it registers a new user and returns the user." do
 285     data = %{
 286       "nickname" => "lain",
 287       "email" => "lain@wired.jp",
 288       "fullname" => "lain iwakura",
 289       "bio" => "close the world.",
 290       "password" => "bear",
 291       "confirm" => "bear"
 292     }
 293
 294     {:ok, user} = TwitterAPI.register_user(data)
 295
 296     fetched_user = Repo.get_by(User, nickname: "lain")
 297     assert user == UserRepresenter.to_map(fetched_user)
 298   end
 299
 300   test "it returns the error on registration problems" do
 301     data = %{
 302       "nickname" => "lain",
 303       "email" => "lain@wired.jp",
 304       "fullname" => "lain iwakura",
 305       "bio" => "close the world.",
 306       "password" => "bear"
 307     }
 308
 309     {:error, error_object} = TwitterAPI.register_user(data)
 310
 311     assert is_binary(error_object[:error])
 312     refute Repo.get_by(User, nickname: "lain")
 313   end
 314
 315   test "it assigns an integer conversation_id" do
 316     note_activity = insert(:note_activity)
 317     user = User.get_cached_by_ap_id(note_activity.data["actor"])
 318     status = ActivityRepresenter.to_map(note_activity, %{user: user})
 319
 320     assert is_number(status["statusnet_conversation_id"])
 321   end
 322
 323   setup do
 324     Supervisor.terminate_child(Pleroma.Supervisor, Cachex)
 325     Supervisor.restart_child(Pleroma.Supervisor, Cachex)
 326     :ok
 327   end
 328
 329   describe "context_to_conversation_id" do
 330     test "creates a mapping object" do
 331       conversation_id = TwitterAPI.context_to_conversation_id("random context")
 332       object = Object.get_by_ap_id("random context")
 333
 334       assert conversation_id == object.id
 335     end
 336
 337     test "returns an existing mapping for an existing object" do
 338       {:ok, object} = Object.context_mapping("random context") |> Repo.insert
 339       conversation_id = TwitterAPI.context_to_conversation_id("random context")
 340
 341       assert conversation_id == object.id
 342     end
 343   end
 344 end