git.squeep.com Git - akkoma/blob - test/web/twitter_api/twitter_api_controller_test.exs

   1 defmodule Pleroma.Web.TwitterAPI.ControllerTest do
   2   use Pleroma.Web.ConnCase
   3   alias Pleroma.Web.TwitterAPI.Representers.{UserRepresenter, ActivityRepresenter}
   4   alias Pleroma.Builders.{ActivityBuilder, UserBuilder}
   5   alias Pleroma.{Repo, Activity, User}
   6
   7   describe "POST /api/account/verify_credentials" do
   8     setup [:valid_user]
   9     test "without valid credentials", %{conn: conn} do
  10       conn = post conn, "/api/account/verify_credentials.json"
  11       assert json_response(conn, 403) == %{"error" => "Invalid credentials."}
  12     end
  13
  14     test "with credentials", %{conn: conn, user: user} do
  15       conn = conn
  16         |> with_credentials(user.nickname, "test")
  17         |> post("/api/account/verify_credentials.json")
  18
  19       assert json_response(conn, 200) == UserRepresenter.to_map(user)
  20     end
  21   end
  22
  23   describe "POST /statuses/update.json" do
  24     setup [:valid_user]
  25     test "without valid credentials", %{conn: conn} do
  26       conn = post conn, "/api/statuses/update.json"
  27       assert json_response(conn, 403) == %{"error" => "Invalid credentials."}
  28     end
  29
  30     test "with credentials", %{conn: conn, user: user} do
  31       conn = conn
  32         |> with_credentials(user.nickname, "test")
  33         |> post("/api/statuses/update.json", %{ status: "Nice meme." })
  34
  35       assert json_response(conn, 200) == ActivityRepresenter.to_map(Repo.one(Activity), %{user: user})
  36     end
  37   end
  38
  39   describe "GET /statuses/public_timeline.json" do
  40     test "returns statuses", %{conn: conn} do
  41       {:ok, user} = UserBuilder.insert
  42       activities = ActivityBuilder.insert_list(30, %{}, %{user: user})
  43       ActivityBuilder.insert_list(10, %{}, %{user: user})
  44       since_id = List.last(activities).id
  45
  46       conn = conn
  47         |> get("/api/statuses/public_timeline.json", %{since_id: since_id})
  48
  49       response = json_response(conn, 200)
  50
  51       assert length(response) == 10
  52     end
  53   end
  54
  55   describe "GET /statuses/friends_timeline.json" do
  56     setup [:valid_user]
  57     test "without valid credentials", %{conn: conn} do
  58       conn = get conn, "/api/statuses/friends_timeline.json"
  59       assert json_response(conn, 403) == %{"error" => "Invalid credentials."}
  60     end
  61
  62     test "with credentials", %{conn: conn, user: current_user} do
  63       {:ok, user} = UserBuilder.insert
  64       activities = ActivityBuilder.insert_list(30, %{"to" => [User.ap_followers(user)]}, %{user: user})
  65       returned_activities = ActivityBuilder.insert_list(10, %{"to" => [User.ap_followers(user)]}, %{user: user})
  66       {:ok, other_user} = UserBuilder.insert(%{ap_id: "glimmung", nickname: "nockame"})
  67       ActivityBuilder.insert_list(10, %{}, %{user: other_user})
  68       since_id = List.last(activities).id
  69
  70       current_user = Ecto.Changeset.change(current_user, following: [User.ap_followers(user)]) |> Repo.update!
  71
  72       conn = conn
  73         |> with_credentials(current_user.nickname, "test")
  74         |> get("/api/statuses/friends_timeline.json", %{since_id: since_id})
  75
  76       response = json_response(conn, 200)
  77
  78       assert length(response) == 10
  79       assert response == Enum.map(returned_activities, fn (activity) -> ActivityRepresenter.to_map(activity, %{user: user, for: current_user}) end)
  80     end
  81   end
  82
  83   describe "POST /friendships/create.json" do
  84     setup [:valid_user]
  85     test "without valid credentials", %{conn: conn} do
  86       conn = post conn, "/api/friendships/create.json"
  87       assert json_response(conn, 403) == %{"error" => "Invalid credentials."}
  88     end
  89
  90     test "with credentials", %{conn: conn, user: current_user} do
  91       {:ok, followed } = UserBuilder.insert(%{name: "some guy"})
  92
  93       conn = conn
  94       |> with_credentials(current_user.nickname, "test")
  95       |> post("/api/friendships/create.json", %{user_id: followed.id})
  96
  97       current_user = Repo.get(User, current_user.id)
  98       assert current_user.following == [User.ap_followers(followed)]
  99       assert json_response(conn, 200) == UserRepresenter.to_map(followed)
 100     end
 101   end
 102
 103   describe "POST /friendships/destroy.json" do
 104     setup [:valid_user]
 105     test "without valid credentials", %{conn: conn} do
 106       conn = post conn, "/api/friendships/destroy.json"
 107       assert json_response(conn, 403) == %{"error" => "Invalid credentials."}
 108     end
 109
 110     test "with credentials", %{conn: conn, user: current_user} do
 111       {:ok, followed } = UserBuilder.insert(%{name: "some guy"})
 112
 113       {:ok, current_user} = User.follow(current_user, followed)
 114       assert current_user.following == [User.ap_followers(followed)]
 115
 116       conn = conn
 117       |> with_credentials(current_user.nickname, "test")
 118       |> post("/api/friendships/destroy.json", %{user_id: followed.id})
 119
 120       current_user = Repo.get(User, current_user.id)
 121       assert current_user.following == []
 122       assert json_response(conn, 200) == UserRepresenter.to_map(followed)
 123     end
 124   end
 125
 126   defp valid_user(_context) do
 127     { :ok, user } = UserBuilder.insert(%{nickname: "lambda", ap_id: "lambda"})
 128     [user: user]
 129   end
 130
 131   defp with_credentials(conn, username, password) do
 132     header_content = "Basic " <> Base.encode64("#{username}:#{password}")
 133     put_req_header(conn, "authorization", header_content)
 134   end
 135 end