git.squeep.com Git - akkoma/blob - test/web/twitter_api/twitter_api_controller_test.exs

   1 defmodule Pleroma.Web.TwitterAPI.ControllerTest do
   2   use Pleroma.Web.ConnCase
   3   alias Pleroma.Web.TwitterAPI.Representers.ActivityRepresenter
   4   alias Pleroma.Builders.{ActivityBuilder, UserBuilder}
   5   alias Pleroma.{Repo, Activity, User, Object, Notification}
   6   alias Pleroma.Web.ActivityPub.ActivityPub
   7   alias Pleroma.Web.TwitterAPI.UserView
   8   alias Pleroma.Web.TwitterAPI.NotificationView
   9   alias Pleroma.Web.CommonAPI
  10   alias Pleroma.Web.TwitterAPI.TwitterAPI
  11   alias Comeonin.Pbkdf2
  12
  13   import Pleroma.Factory
  14
  15   describe "POST /api/account/verify_credentials" do
  16     setup [:valid_user]
  17
  18     test "without valid credentials", %{conn: conn} do
  19       conn = post(conn, "/api/account/verify_credentials.json")
  20       assert json_response(conn, 403) == %{"error" => "Invalid credentials."}
  21     end
  22
  23     test "with credentials", %{conn: conn, user: user} do
  24       conn =
  25         conn
  26         |> with_credentials(user.nickname, "test")
  27         |> post("/api/account/verify_credentials.json")
  28
  29       assert response = json_response(conn, 200)
  30       assert response == UserView.render("show.json", %{user: user, token: response["token"]})
  31     end
  32   end
  33
  34   describe "POST /api/account/most_recent_notification" do
  35     setup [:valid_user]
  36
  37     test "without valid credentials", %{conn: conn} do
  38       conn = post(conn, "/api/account/most_recent_notification.json")
  39       assert json_response(conn, 403) == %{"error" => "Invalid credentials."}
  40     end
  41
  42     test "with credentials", %{conn: conn, user: user} do
  43       conn =
  44         conn
  45         |> with_credentials(user.nickname, "test")
  46         |> post("/api/account/most_recent_notification.json", %{id: "200"})
  47
  48       assert json_response(conn, 200)
  49       user = User.get_by_nickname(user.nickname)
  50       assert user.info["most_recent_notification"] == 200
  51     end
  52   end
  53
  54   describe "POST /statuses/update.json" do
  55     setup [:valid_user]
  56
  57     test "without valid credentials", %{conn: conn} do
  58       conn = post(conn, "/api/statuses/update.json")
  59       assert json_response(conn, 403) == %{"error" => "Invalid credentials."}
  60     end
  61
  62     test "with credentials", %{conn: conn, user: user} do
  63       conn_with_creds = conn |> with_credentials(user.nickname, "test")
  64       request_path = "/api/statuses/update.json"
  65
  66       error_response = %{
  67         "request" => request_path,
  68         "error" => "Client must provide a 'status' parameter with a value."
  69       }
  70
  71       conn = conn_with_creds |> post(request_path)
  72       assert json_response(conn, 400) == error_response
  73
  74       conn = conn_with_creds |> post(request_path, %{status: ""})
  75       assert json_response(conn, 400) == error_response
  76
  77       conn = conn_with_creds |> post(request_path, %{status: " "})
  78       assert json_response(conn, 400) == error_response
  79
  80       conn = conn_with_creds |> post(request_path, %{status: "Nice meme."})
  81
  82       assert json_response(conn, 200) ==
  83                ActivityRepresenter.to_map(Repo.one(Activity), %{user: user})
  84     end
  85   end
  86
  87   describe "GET /statuses/public_timeline.json" do
  88     test "returns statuses", %{conn: conn} do
  89       {:ok, user} = UserBuilder.insert()
  90       activities = ActivityBuilder.insert_list(30, %{}, %{user: user})
  91       ActivityBuilder.insert_list(10, %{}, %{user: user})
  92       since_id = List.last(activities).id
  93
  94       conn =
  95         conn
  96         |> get("/api/statuses/public_timeline.json", %{since_id: since_id})
  97
  98       response = json_response(conn, 200)
  99
 100       assert length(response) == 10
 101     end
 102   end
 103
 104   describe "GET /statuses/show/:id.json" do
 105     test "returns one status", %{conn: conn} do
 106       user = insert(:user)
 107       {:ok, activity} = CommonAPI.post(user, %{"status" => "Hey!"})
 108       actor = Repo.get_by!(User, ap_id: activity.data["actor"])
 109
 110       conn =
 111         conn
 112         |> get("/api/statuses/show/#{activity.id}.json")
 113
 114       response = json_response(conn, 200)
 115
 116       assert response == ActivityRepresenter.to_map(activity, %{user: actor})
 117     end
 118   end
 119
 120   describe "GET /users/show.json" do
 121     test "gets user with screen_name", %{conn: conn} do
 122       user = insert(:user)
 123
 124       conn =
 125         conn
 126         |> get("/api/users/show.json", %{"screen_name" => user.nickname})
 127
 128       response = json_response(conn, 200)
 129
 130       assert response["id"] == user.id
 131     end
 132
 133     test "gets user with user_id", %{conn: conn} do
 134       user = insert(:user)
 135
 136       conn =
 137         conn
 138         |> get("/api/users/show.json", %{"user_id" => user.id})
 139
 140       response = json_response(conn, 200)
 141
 142       assert response["id"] == user.id
 143     end
 144
 145     test "gets a user for a logged in user", %{conn: conn} do
 146       user = insert(:user)
 147       logged_in = insert(:user)
 148
 149       {:ok, logged_in, user, _activity} = TwitterAPI.follow(logged_in, %{"user_id" => user.id})
 150
 151       conn =
 152         conn
 153         |> with_credentials(logged_in.nickname, "test")
 154         |> get("/api/users/show.json", %{"user_id" => user.id})
 155
 156       response = json_response(conn, 200)
 157
 158       assert response["following"] == true
 159     end
 160   end
 161
 162   describe "GET /statusnet/conversation/:id.json" do
 163     test "returns the statuses in the conversation", %{conn: conn} do
 164       {:ok, _user} = UserBuilder.insert()
 165       {:ok, activity} = ActivityBuilder.insert(%{"type" => "Create", "context" => "2hu"})
 166       {:ok, _activity_two} = ActivityBuilder.insert(%{"type" => "Create", "context" => "2hu"})
 167       {:ok, _activity_three} = ActivityBuilder.insert(%{"type" => "Create", "context" => "3hu"})
 168
 169       conn =
 170         conn
 171         |> get("/api/statusnet/conversation/#{activity.data["context_id"]}.json")
 172
 173       response = json_response(conn, 200)
 174
 175       assert length(response) == 2
 176     end
 177   end
 178
 179   describe "GET /statuses/friends_timeline.json" do
 180     setup [:valid_user]
 181
 182     test "without valid credentials", %{conn: conn} do
 183       conn = get(conn, "/api/statuses/friends_timeline.json")
 184       assert json_response(conn, 403) == %{"error" => "Invalid credentials."}
 185     end
 186
 187     test "with credentials", %{conn: conn, user: current_user} do
 188       user = insert(:user)
 189
 190       activities =
 191         ActivityBuilder.insert_list(30, %{"to" => [User.ap_followers(user)]}, %{user: user})
 192
 193       returned_activities =
 194         ActivityBuilder.insert_list(10, %{"to" => [User.ap_followers(user)]}, %{user: user})
 195
 196       other_user = insert(:user)
 197       ActivityBuilder.insert_list(10, %{}, %{user: other_user})
 198       since_id = List.last(activities).id
 199
 200       current_user =
 201         Ecto.Changeset.change(current_user, following: [User.ap_followers(user)])
 202         |> Repo.update!()
 203
 204       conn =
 205         conn
 206         |> with_credentials(current_user.nickname, "test")
 207         |> get("/api/statuses/friends_timeline.json", %{since_id: since_id})
 208
 209       response = json_response(conn, 200)
 210
 211       assert length(response) == 10
 212
 213       assert response ==
 214                Enum.map(returned_activities, fn activity ->
 215                  ActivityRepresenter.to_map(activity, %{
 216                    user: User.get_cached_by_ap_id(activity.data["actor"]),
 217                    for: current_user
 218                  })
 219                end)
 220     end
 221   end
 222
 223   describe "GET /statuses/mentions.json" do
 224     setup [:valid_user]
 225
 226     test "without valid credentials", %{conn: conn} do
 227       conn = get(conn, "/api/statuses/mentions.json")
 228       assert json_response(conn, 403) == %{"error" => "Invalid credentials."}
 229     end
 230
 231     test "with credentials", %{conn: conn, user: current_user} do
 232       {:ok, activity} =
 233         ActivityBuilder.insert(%{"to" => [current_user.ap_id]}, %{user: current_user})
 234
 235       conn =
 236         conn
 237         |> with_credentials(current_user.nickname, "test")
 238         |> get("/api/statuses/mentions.json")
 239
 240       response = json_response(conn, 200)
 241
 242       assert length(response) == 1
 243
 244       assert Enum.at(response, 0) ==
 245                ActivityRepresenter.to_map(activity, %{
 246                  user: current_user,
 247                  mentioned: [current_user]
 248                })
 249     end
 250   end
 251
 252   describe "GET /api/qvitter/statuses/notifications.json" do
 253     setup [:valid_user]
 254
 255     test "without valid credentials", %{conn: conn} do
 256       conn = get(conn, "/api/qvitter/statuses/notifications.json")
 257       assert json_response(conn, 403) == %{"error" => "Invalid credentials."}
 258     end
 259
 260     test "with credentials", %{conn: conn, user: current_user} do
 261       other_user = insert(:user)
 262
 263       {:ok, activity} =
 264         ActivityBuilder.insert(%{"to" => [current_user.ap_id]}, %{user: other_user})
 265
 266       conn =
 267         conn
 268         |> with_credentials(current_user.nickname, "test")
 269         |> get("/api/qvitter/statuses/notifications.json")
 270
 271       response = json_response(conn, 200)
 272
 273       assert length(response) == 1
 274
 275       assert response ==
 276                NotificationView.render("notification.json", %{
 277                  notifications: Notification.for_user(current_user),
 278                  for: current_user
 279                })
 280     end
 281   end
 282
 283   describe "GET /statuses/user_timeline.json" do
 284     setup [:valid_user]
 285
 286     test "without any params", %{conn: conn} do
 287       conn = get(conn, "/api/statuses/user_timeline.json")
 288
 289       assert json_response(conn, 400) == %{
 290                "error" => "You need to specify screen_name or user_id",
 291                "request" => "/api/statuses/user_timeline.json"
 292              }
 293     end
 294
 295     test "with user_id", %{conn: conn} do
 296       user = insert(:user)
 297       {:ok, activity} = ActivityBuilder.insert(%{"id" => 1}, %{user: user})
 298
 299       conn = get(conn, "/api/statuses/user_timeline.json", %{"user_id" => user.id})
 300       response = json_response(conn, 200)
 301       assert length(response) == 1
 302       assert Enum.at(response, 0) == ActivityRepresenter.to_map(activity, %{user: user})
 303     end
 304
 305     test "with screen_name", %{conn: conn} do
 306       user = insert(:user)
 307       {:ok, activity} = ActivityBuilder.insert(%{"id" => 1}, %{user: user})
 308
 309       conn = get(conn, "/api/statuses/user_timeline.json", %{"screen_name" => user.nickname})
 310       response = json_response(conn, 200)
 311       assert length(response) == 1
 312       assert Enum.at(response, 0) == ActivityRepresenter.to_map(activity, %{user: user})
 313     end
 314
 315     test "with credentials", %{conn: conn, user: current_user} do
 316       {:ok, activity} = ActivityBuilder.insert(%{"id" => 1}, %{user: current_user})
 317
 318       conn =
 319         conn
 320         |> with_credentials(current_user.nickname, "test")
 321         |> get("/api/statuses/user_timeline.json")
 322
 323       response = json_response(conn, 200)
 324
 325       assert length(response) == 1
 326       assert Enum.at(response, 0) == ActivityRepresenter.to_map(activity, %{user: current_user})
 327     end
 328
 329     test "with credentials with user_id", %{conn: conn, user: current_user} do
 330       user = insert(:user)
 331       {:ok, activity} = ActivityBuilder.insert(%{"id" => 1}, %{user: user})
 332
 333       conn =
 334         conn
 335         |> with_credentials(current_user.nickname, "test")
 336         |> get("/api/statuses/user_timeline.json", %{"user_id" => user.id})
 337
 338       response = json_response(conn, 200)
 339
 340       assert length(response) == 1
 341       assert Enum.at(response, 0) == ActivityRepresenter.to_map(activity, %{user: user})
 342     end
 343
 344     test "with credentials screen_name", %{conn: conn, user: current_user} do
 345       user = insert(:user)
 346       {:ok, activity} = ActivityBuilder.insert(%{"id" => 1}, %{user: user})
 347
 348       conn =
 349         conn
 350         |> with_credentials(current_user.nickname, "test")
 351         |> get("/api/statuses/user_timeline.json", %{"screen_name" => user.nickname})
 352
 353       response = json_response(conn, 200)
 354
 355       assert length(response) == 1
 356       assert Enum.at(response, 0) == ActivityRepresenter.to_map(activity, %{user: user})
 357     end
 358   end
 359
 360   describe "POST /friendships/create.json" do
 361     setup [:valid_user]
 362
 363     test "without valid credentials", %{conn: conn} do
 364       conn = post(conn, "/api/friendships/create.json")
 365       assert json_response(conn, 403) == %{"error" => "Invalid credentials."}
 366     end
 367
 368     test "with credentials", %{conn: conn, user: current_user} do
 369       followed = insert(:user)
 370
 371       conn =
 372         conn
 373         |> with_credentials(current_user.nickname, "test")
 374         |> post("/api/friendships/create.json", %{user_id: followed.id})
 375
 376       current_user = Repo.get(User, current_user.id)
 377       assert User.ap_followers(followed) in current_user.following
 378
 379       assert json_response(conn, 200) ==
 380                UserView.render("show.json", %{user: followed, for: current_user})
 381     end
 382   end
 383
 384   describe "POST /friendships/destroy.json" do
 385     setup [:valid_user]
 386
 387     test "without valid credentials", %{conn: conn} do
 388       conn = post(conn, "/api/friendships/destroy.json")
 389       assert json_response(conn, 403) == %{"error" => "Invalid credentials."}
 390     end
 391
 392     test "with credentials", %{conn: conn, user: current_user} do
 393       followed = insert(:user)
 394
 395       {:ok, current_user} = User.follow(current_user, followed)
 396       assert User.ap_followers(followed) in current_user.following
 397       ActivityPub.follow(current_user, followed)
 398
 399       conn =
 400         conn
 401         |> with_credentials(current_user.nickname, "test")
 402         |> post("/api/friendships/destroy.json", %{user_id: followed.id})
 403
 404       current_user = Repo.get(User, current_user.id)
 405       assert current_user.following == [current_user.ap_id]
 406
 407       assert json_response(conn, 200) ==
 408                UserView.render("show.json", %{user: followed, for: current_user})
 409     end
 410   end
 411
 412   describe "POST /blocks/create.json" do
 413     setup [:valid_user]
 414
 415     test "without valid credentials", %{conn: conn} do
 416       conn = post(conn, "/api/blocks/create.json")
 417       assert json_response(conn, 403) == %{"error" => "Invalid credentials."}
 418     end
 419
 420     test "with credentials", %{conn: conn, user: current_user} do
 421       blocked = insert(:user)
 422
 423       conn =
 424         conn
 425         |> with_credentials(current_user.nickname, "test")
 426         |> post("/api/blocks/create.json", %{user_id: blocked.id})
 427
 428       current_user = Repo.get(User, current_user.id)
 429       assert User.blocks?(current_user, blocked)
 430
 431       assert json_response(conn, 200) ==
 432                UserView.render("show.json", %{user: blocked, for: current_user})
 433     end
 434   end
 435
 436   describe "POST /blocks/destroy.json" do
 437     setup [:valid_user]
 438
 439     test "without valid credentials", %{conn: conn} do
 440       conn = post(conn, "/api/blocks/destroy.json")
 441       assert json_response(conn, 403) == %{"error" => "Invalid credentials."}
 442     end
 443
 444     test "with credentials", %{conn: conn, user: current_user} do
 445       blocked = insert(:user)
 446
 447       {:ok, current_user, blocked} = TwitterAPI.block(current_user, %{"user_id" => blocked.id})
 448       assert User.blocks?(current_user, blocked)
 449
 450       conn =
 451         conn
 452         |> with_credentials(current_user.nickname, "test")
 453         |> post("/api/blocks/destroy.json", %{user_id: blocked.id})
 454
 455       current_user = Repo.get(User, current_user.id)
 456       assert current_user.info["blocks"] == []
 457
 458       assert json_response(conn, 200) ==
 459                UserView.render("show.json", %{user: blocked, for: current_user})
 460     end
 461   end
 462
 463   describe "GET /help/test.json" do
 464     test "returns \"ok\"", %{conn: conn} do
 465       conn = get(conn, "/api/help/test.json")
 466       assert json_response(conn, 200) == "ok"
 467     end
 468   end
 469
 470   describe "POST /api/qvitter/update_avatar.json" do
 471     setup [:valid_user]
 472
 473     test "without valid credentials", %{conn: conn} do
 474       conn = post(conn, "/api/qvitter/update_avatar.json")
 475       assert json_response(conn, 403) == %{"error" => "Invalid credentials."}
 476     end
 477
 478     test "with credentials", %{conn: conn, user: current_user} do
 479       avatar_image = File.read!("test/fixtures/avatar_data_uri")
 480
 481       conn =
 482         conn
 483         |> with_credentials(current_user.nickname, "test")
 484         |> post("/api/qvitter/update_avatar.json", %{img: avatar_image})
 485
 486       current_user = Repo.get(User, current_user.id)
 487       assert is_map(current_user.avatar)
 488
 489       assert json_response(conn, 200) ==
 490                UserView.render("show.json", %{user: current_user, for: current_user})
 491     end
 492   end
 493
 494   describe "POST /api/favorites/create/:id" do
 495     setup [:valid_user]
 496
 497     test "without valid credentials", %{conn: conn} do
 498       note_activity = insert(:note_activity)
 499       conn = post(conn, "/api/favorites/create/#{note_activity.id}.json")
 500       assert json_response(conn, 403) == %{"error" => "Invalid credentials."}
 501     end
 502
 503     test "with credentials", %{conn: conn, user: current_user} do
 504       note_activity = insert(:note_activity)
 505
 506       conn =
 507         conn
 508         |> with_credentials(current_user.nickname, "test")
 509         |> post("/api/favorites/create/#{note_activity.id}.json")
 510
 511       assert json_response(conn, 200)
 512     end
 513   end
 514
 515   describe "POST /api/favorites/destroy/:id" do
 516     setup [:valid_user]
 517
 518     test "without valid credentials", %{conn: conn} do
 519       note_activity = insert(:note_activity)
 520       conn = post(conn, "/api/favorites/destroy/#{note_activity.id}.json")
 521       assert json_response(conn, 403) == %{"error" => "Invalid credentials."}
 522     end
 523
 524     test "with credentials", %{conn: conn, user: current_user} do
 525       note_activity = insert(:note_activity)
 526       object = Object.get_by_ap_id(note_activity.data["object"]["id"])
 527       ActivityPub.like(current_user, object)
 528
 529       conn =
 530         conn
 531         |> with_credentials(current_user.nickname, "test")
 532         |> post("/api/favorites/destroy/#{note_activity.id}.json")
 533
 534       assert json_response(conn, 200)
 535     end
 536   end
 537
 538   describe "POST /api/statuses/retweet/:id" do
 539     setup [:valid_user]
 540
 541     test "without valid credentials", %{conn: conn} do
 542       note_activity = insert(:note_activity)
 543       conn = post(conn, "/api/statuses/retweet/#{note_activity.id}.json")
 544       assert json_response(conn, 403) == %{"error" => "Invalid credentials."}
 545     end
 546
 547     test "with credentials", %{conn: conn, user: current_user} do
 548       note_activity = insert(:note_activity)
 549
 550       request_path = "/api/statuses/retweet/#{note_activity.id}.json"
 551
 552       response =
 553         conn
 554         |> with_credentials(current_user.nickname, "test")
 555         |> post(request_path)
 556
 557       activity = Repo.get(Activity, note_activity.id)
 558       activity_user = Repo.get_by(User, ap_id: note_activity.data["actor"])
 559
 560       assert json_response(response, 200) ==
 561                ActivityRepresenter.to_map(activity, %{user: activity_user, for: current_user})
 562     end
 563   end
 564
 565   describe "POST /api/account/register" do
 566     test "it creates a new user", %{conn: conn} do
 567       data = %{
 568         "nickname" => "lain",
 569         "email" => "lain@wired.jp",
 570         "fullname" => "lain iwakura",
 571         "bio" => "close the world.",
 572         "password" => "bear",
 573         "confirm" => "bear"
 574       }
 575
 576       conn =
 577         conn
 578         |> post("/api/account/register", data)
 579
 580       user = json_response(conn, 200)
 581
 582       fetched_user = Repo.get_by(User, nickname: "lain")
 583       assert user == UserView.render("show.json", %{user: fetched_user})
 584     end
 585
 586     test "it returns errors on a problem", %{conn: conn} do
 587       data = %{
 588         "email" => "lain@wired.jp",
 589         "fullname" => "lain iwakura",
 590         "bio" => "close the world.",
 591         "password" => "bear",
 592         "confirm" => "bear"
 593       }
 594
 595       conn =
 596         conn
 597         |> post("/api/account/register", data)
 598
 599       errors = json_response(conn, 400)
 600
 601       assert is_binary(errors["error"])
 602     end
 603   end
 604
 605   describe "GET /api/externalprofile/show" do
 606     test "it returns the user", %{conn: conn} do
 607       user = insert(:user)
 608       other_user = insert(:user)
 609
 610       conn =
 611         conn
 612         |> assign(:user, user)
 613         |> get("/api/externalprofile/show", %{profileurl: other_user.ap_id})
 614
 615       assert json_response(conn, 200) == UserView.render("show.json", %{user: other_user})
 616     end
 617   end
 618
 619   describe "GET /api/statuses/followers" do
 620     test "it returns a user's followers", %{conn: conn} do
 621       user = insert(:user)
 622       follower_one = insert(:user)
 623       follower_two = insert(:user)
 624       _not_follower = insert(:user)
 625
 626       {:ok, follower_one} = User.follow(follower_one, user)
 627       {:ok, follower_two} = User.follow(follower_two, user)
 628
 629       conn =
 630         conn
 631         |> assign(:user, user)
 632         |> get("/api/statuses/followers")
 633
 634       expected = UserView.render("index.json", %{users: [follower_one, follower_two], for: user})
 635       result = json_response(conn, 200)
 636       assert Enum.sort(expected) == Enum.sort(result)
 637     end
 638   end
 639
 640   describe "GET /api/statuses/friends" do
 641     test "it returns the logged in user's friends", %{conn: conn} do
 642       user = insert(:user)
 643       followed_one = insert(:user)
 644       followed_two = insert(:user)
 645       _not_followed = insert(:user)
 646
 647       {:ok, user} = User.follow(user, followed_one)
 648       {:ok, user} = User.follow(user, followed_two)
 649
 650       conn =
 651         conn
 652         |> assign(:user, user)
 653         |> get("/api/statuses/friends")
 654
 655       expected = UserView.render("index.json", %{users: [followed_one, followed_two], for: user})
 656       result = json_response(conn, 200)
 657       assert Enum.sort(expected) == Enum.sort(result)
 658     end
 659
 660     test "it returns a given user's friends with user_id", %{conn: conn} do
 661       user = insert(:user)
 662       followed_one = insert(:user)
 663       followed_two = insert(:user)
 664       _not_followed = insert(:user)
 665
 666       {:ok, user} = User.follow(user, followed_one)
 667       {:ok, user} = User.follow(user, followed_two)
 668
 669       conn =
 670         conn
 671         |> get("/api/statuses/friends", %{"user_id" => user.id})
 672
 673       assert MapSet.equal?(
 674                MapSet.new(json_response(conn, 200)),
 675                MapSet.new(
 676                  UserView.render("index.json", %{users: [followed_one, followed_two], for: user})
 677                )
 678              )
 679     end
 680
 681     test "it returns a given user's friends with screen_name", %{conn: conn} do
 682       user = insert(:user)
 683       followed_one = insert(:user)
 684       followed_two = insert(:user)
 685       _not_followed = insert(:user)
 686
 687       {:ok, user} = User.follow(user, followed_one)
 688       {:ok, user} = User.follow(user, followed_two)
 689
 690       conn =
 691         conn
 692         |> get("/api/statuses/friends", %{"screen_name" => user.nickname})
 693
 694       assert MapSet.equal?(
 695                MapSet.new(json_response(conn, 200)),
 696                MapSet.new(
 697                  UserView.render("index.json", %{users: [followed_one, followed_two], for: user})
 698                )
 699              )
 700     end
 701   end
 702
 703   describe "GET /friends/ids" do
 704     test "it returns a user's friends", %{conn: conn} do
 705       user = insert(:user)
 706       followed_one = insert(:user)
 707       followed_two = insert(:user)
 708       _not_followed = insert(:user)
 709
 710       {:ok, user} = User.follow(user, followed_one)
 711       {:ok, user} = User.follow(user, followed_two)
 712
 713       conn =
 714         conn
 715         |> assign(:user, user)
 716         |> get("/api/friends/ids")
 717
 718       expected = [followed_one.id, followed_two.id]
 719
 720       assert MapSet.equal?(
 721                MapSet.new(Poison.decode!(json_response(conn, 200))),
 722                MapSet.new(expected)
 723              )
 724     end
 725   end
 726
 727   describe "POST /api/account/update_profile.json" do
 728     test "it updates a user's profile", %{conn: conn} do
 729       user = insert(:user)
 730
 731       conn =
 732         conn
 733         |> assign(:user, user)
 734         |> post("/api/account/update_profile.json", %{
 735           "name" => "new name",
 736           "description" => "new description"
 737         })
 738
 739       user = Repo.get!(User, user.id)
 740       assert user.name == "new name"
 741       assert user.bio == "new description"
 742
 743       assert json_response(conn, 200) == UserView.render("user.json", %{user: user, for: user})
 744     end
 745   end
 746
 747   defp valid_user(_context) do
 748     user = insert(:user)
 749     [user: user]
 750   end
 751
 752   defp with_credentials(conn, username, password) do
 753     header_content = "Basic " <> Base.encode64("#{username}:#{password}")
 754     put_req_header(conn, "authorization", header_content)
 755   end
 756
 757   describe "GET /api/search.json" do
 758     test "it returns search results", %{conn: conn} do
 759       user = insert(:user)
 760       user_two = insert(:user, %{nickname: "shp@shitposter.club"})
 761
 762       {:ok, activity} = CommonAPI.post(user, %{"status" => "This is about 2hu"})
 763       {:ok, _} = CommonAPI.post(user_two, %{"status" => "This isn't"})
 764
 765       conn =
 766         conn
 767         |> get("/api/search.json", %{"q" => "2hu", "page" => "1", "rpp" => "1"})
 768
 769       assert [status] = json_response(conn, 200)
 770       assert status["id"] == activity.id
 771     end
 772   end
 773
 774   describe "GET /api/statusnet/tags/timeline/:tag.json" do
 775     test "it returns the tags timeline", %{conn: conn} do
 776       user = insert(:user)
 777       user_two = insert(:user, %{nickname: "shp@shitposter.club"})
 778
 779       {:ok, activity} = CommonAPI.post(user, %{"status" => "This is about #2hu"})
 780       {:ok, _} = CommonAPI.post(user_two, %{"status" => "This isn't"})
 781
 782       conn =
 783         conn
 784         |> get("/api/statusnet/tags/timeline/2hu.json")
 785
 786       assert [status] = json_response(conn, 200)
 787       assert status["id"] == activity.id
 788     end
 789   end
 790
 791   test "Convert newlines to <br> in bio", %{conn: conn} do
 792     user = insert(:user)
 793
 794     conn =
 795       conn
 796       |> assign(:user, user)
 797       |> post("/api/account/update_profile.json", %{
 798         "description" => "Hello,\r\nWorld! I\n am a test."
 799       })
 800
 801     user = Repo.get!(User, user.id)
 802     assert user.bio == "Hello,<br>World! I<br> am a test."
 803   end
 804
 805   describe "POST /api/pleroma/change_password" do
 806     setup [:valid_user]
 807
 808     test "without credentials", %{conn: conn} do
 809       conn = post(conn, "/api/pleroma/change_password")
 810       assert json_response(conn, 403) == %{"error" => "Invalid credentials."}
 811     end
 812
 813     test "with credentials and invalid password", %{conn: conn, user: current_user} do
 814       conn =
 815         conn
 816         |> with_credentials(current_user.nickname, "test")
 817         |> post("/api/pleroma/change_password", %{
 818           "password" => "hi",
 819           "new_password" => "newpass",
 820           "new_password_confirmation" => "newpass"
 821         })
 822
 823       assert json_response(conn, 200) == %{"error" => "Invalid password."}
 824     end
 825
 826     test "with credentials, valid password and new password and confirmation not matching", %{
 827       conn: conn,
 828       user: current_user
 829     } do
 830       conn =
 831         conn
 832         |> with_credentials(current_user.nickname, "test")
 833         |> post("/api/pleroma/change_password", %{
 834           "password" => "test",
 835           "new_password" => "newpass",
 836           "new_password_confirmation" => "notnewpass"
 837         })
 838
 839       assert json_response(conn, 200) == %{
 840                "error" => "New password does not match confirmation."
 841              }
 842     end
 843
 844     test "with credentials, valid password and invalid new password", %{
 845       conn: conn,
 846       user: current_user
 847     } do
 848       conn =
 849         conn
 850         |> with_credentials(current_user.nickname, "test")
 851         |> post("/api/pleroma/change_password", %{
 852           "password" => "test",
 853           "new_password" => "",
 854           "new_password_confirmation" => ""
 855         })
 856
 857       assert json_response(conn, 200) == %{
 858                "error" => "New password can't be blank."
 859              }
 860     end
 861
 862     test "with credentials, valid password and matching new password and confirmation", %{
 863       conn: conn,
 864       user: current_user
 865     } do
 866       conn =
 867         conn
 868         |> with_credentials(current_user.nickname, "test")
 869         |> post("/api/pleroma/change_password", %{
 870           "password" => "test",
 871           "new_password" => "newpass",
 872           "new_password_confirmation" => "newpass"
 873         })
 874
 875       assert json_response(conn, 200) == %{"status" => "success"}
 876       fetched_user = Repo.get(User, current_user.id)
 877       assert Pbkdf2.checkpw("newpass", fetched_user.password_hash) == true
 878     end
 879   end
 880
 881   describe "POST /api/pleroma/delete_account" do
 882     setup [:valid_user]
 883
 884     test "without credentials", %{conn: conn} do
 885       conn = post(conn, "/api/pleroma/delete_account")
 886       assert json_response(conn, 403) == %{"error" => "Invalid credentials."}
 887     end
 888
 889     test "with credentials and invalid password", %{conn: conn, user: current_user} do
 890       conn =
 891         conn
 892         |> with_credentials(current_user.nickname, "test")
 893         |> post("/api/pleroma/delete_account", %{"password" => "hi"})
 894
 895       assert json_response(conn, 200) == %{"error" => "Invalid password."}
 896     end
 897
 898     test "with credentials and valid password", %{conn: conn, user: current_user} do
 899       conn =
 900         conn
 901         |> with_credentials(current_user.nickname, "test")
 902         |> post("/api/pleroma/delete_account", %{"password" => "test"})
 903
 904       assert json_response(conn, 200) == %{"status" => "success"}
 905     end
 906   end
 907 end