git.squeep.com Git - akkoma/blob - test/web/twitter_api/remote_follow_controller_test.exs

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.TwitterAPI.RemoteFollowControllerTest do
   6   use Pleroma.Web.ConnCase
   7
   8   alias Pleroma.User
   9   alias Pleroma.Web.CommonAPI
  10   import ExUnit.CaptureLog
  11   import Pleroma.Factory
  12
  13   setup do
  14     Tesla.Mock.mock(fn env -> apply(HttpRequestMock, :request, [env]) end)
  15     :ok
  16   end
  17
  18   clear_config([:instance])
  19   clear_config([:frontend_configurations, :pleroma_fe])
  20   clear_config([:user, :deny_follow_blocked])
  21
  22   describe "GET /ostatus_subscribe - remote_follow/2" do
  23     test "adds status to pleroma instance if the `acct` is a status", %{conn: conn} do
  24       assert conn
  25              |> get(
  26                remote_follow_path(conn, :follow, %{
  27                  acct: "https://mastodon.social/users/emelie/statuses/101849165031453009"
  28                })
  29              )
  30              |> redirected_to() =~ "/notice/"
  31     end
  32
  33     test "show follow account page if the `acct` is a account link", %{conn: conn} do
  34       response =
  35         conn
  36         |> get(remote_follow_path(conn, :follow, %{acct: "https://mastodon.social/users/emelie"}))
  37         |> html_response(200)
  38
  39       assert response =~ "Log in to follow"
  40     end
  41
  42     test "show follow page if the `acct` is a account link", %{conn: conn} do
  43       user = insert(:user)
  44
  45       response =
  46         conn
  47         |> assign(:user, user)
  48         |> get(remote_follow_path(conn, :follow, %{acct: "https://mastodon.social/users/emelie"}))
  49         |> html_response(200)
  50
  51       assert response =~ "Remote follow"
  52     end
  53
  54     test "show follow page with error when user cannot fecth by `acct` link", %{conn: conn} do
  55       user = insert(:user)
  56
  57       assert capture_log(fn ->
  58                response =
  59                  conn
  60                  |> assign(:user, user)
  61                  |> get(
  62                    remote_follow_path(conn, :follow, %{
  63                      acct: "https://mastodon.social/users/not_found"
  64                    })
  65                  )
  66                  |> html_response(200)
  67
  68                assert response =~ "Error fetching user"
  69              end) =~ "Object has been deleted"
  70     end
  71   end
  72
  73   describe "POST /ostatus_subscribe - do_follow/2 with assigned user " do
  74     test "required `follow | write:follows` scope", %{conn: conn} do
  75       user = insert(:user)
  76       user2 = insert(:user)
  77       read_token = insert(:oauth_token, user: user, scopes: ["read"])
  78
  79       assert capture_log(fn ->
  80                response =
  81                  conn
  82                  |> assign(:user, user)
  83                  |> assign(:token, read_token)
  84                  |> post(remote_follow_path(conn, :do_follow), %{"user" => %{"id" => user2.id}})
  85                  |> response(200)
  86
  87                assert response =~ "Error following account"
  88              end) =~ "Insufficient permissions: follow | write:follows."
  89     end
  90
  91     test "follows user", %{conn: conn} do
  92       user = insert(:user)
  93       user2 = insert(:user)
  94
  95       conn =
  96         conn
  97         |> assign(:user, user)
  98         |> assign(:token, insert(:oauth_token, user: user, scopes: ["write:follows"]))
  99         |> post(remote_follow_path(conn, :do_follow), %{"user" => %{"id" => user2.id}})
 100
 101       assert redirected_to(conn) == "/users/#{user2.id}"
 102     end
 103
 104     test "returns error when user is deactivated", %{conn: conn} do
 105       user = insert(:user, deactivated: true)
 106       user2 = insert(:user)
 107
 108       response =
 109         conn
 110         |> assign(:user, user)
 111         |> post(remote_follow_path(conn, :do_follow), %{"user" => %{"id" => user2.id}})
 112         |> response(200)
 113
 114       assert response =~ "Error following account"
 115     end
 116
 117     test "returns error when user is blocked", %{conn: conn} do
 118       Pleroma.Config.put([:user, :deny_follow_blocked], true)
 119       user = insert(:user)
 120       user2 = insert(:user)
 121
 122       {:ok, _user_block} = Pleroma.User.block(user2, user)
 123
 124       response =
 125         conn
 126         |> assign(:user, user)
 127         |> post(remote_follow_path(conn, :do_follow), %{"user" => %{"id" => user2.id}})
 128         |> response(200)
 129
 130       assert response =~ "Error following account"
 131     end
 132
 133     test "returns error when followee not found", %{conn: conn} do
 134       user = insert(:user)
 135
 136       response =
 137         conn
 138         |> assign(:user, user)
 139         |> post(remote_follow_path(conn, :do_follow), %{"user" => %{"id" => "jimm"}})
 140         |> response(200)
 141
 142       assert response =~ "Error following account"
 143     end
 144
 145     test "returns success result when user already in followers", %{conn: conn} do
 146       user = insert(:user)
 147       user2 = insert(:user)
 148       {:ok, _, _, _} = CommonAPI.follow(user, user2)
 149
 150       conn =
 151         conn
 152         |> assign(:user, refresh_record(user))
 153         |> assign(:token, insert(:oauth_token, user: user, scopes: ["write:follows"]))
 154         |> post(remote_follow_path(conn, :do_follow), %{"user" => %{"id" => user2.id}})
 155
 156       assert redirected_to(conn) == "/users/#{user2.id}"
 157     end
 158   end
 159
 160   describe "POST /ostatus_subscribe - follow/2 without assigned user " do
 161     test "follows", %{conn: conn} do
 162       user = insert(:user)
 163       user2 = insert(:user)
 164
 165       conn =
 166         conn
 167         |> post(remote_follow_path(conn, :do_follow), %{
 168           "authorization" => %{"name" => user.nickname, "password" => "test", "id" => user2.id}
 169         })
 170
 171       assert redirected_to(conn) == "/users/#{user2.id}"
 172       assert user2.follower_address in User.following(user)
 173     end
 174
 175     test "returns error when followee not found", %{conn: conn} do
 176       user = insert(:user)
 177
 178       response =
 179         conn
 180         |> post(remote_follow_path(conn, :do_follow), %{
 181           "authorization" => %{"name" => user.nickname, "password" => "test", "id" => "jimm"}
 182         })
 183         |> response(200)
 184
 185       assert response =~ "Error following account"
 186     end
 187
 188     test "returns error when login invalid", %{conn: conn} do
 189       user = insert(:user)
 190
 191       response =
 192         conn
 193         |> post(remote_follow_path(conn, :do_follow), %{
 194           "authorization" => %{"name" => "jimm", "password" => "test", "id" => user.id}
 195         })
 196         |> response(200)
 197
 198       assert response =~ "Wrong username or password"
 199     end
 200
 201     test "returns error when password invalid", %{conn: conn} do
 202       user = insert(:user)
 203       user2 = insert(:user)
 204
 205       response =
 206         conn
 207         |> post(remote_follow_path(conn, :do_follow), %{
 208           "authorization" => %{"name" => user.nickname, "password" => "42", "id" => user2.id}
 209         })
 210         |> response(200)
 211
 212       assert response =~ "Wrong username or password"
 213     end
 214
 215     test "returns error when user is blocked", %{conn: conn} do
 216       Pleroma.Config.put([:user, :deny_follow_blocked], true)
 217       user = insert(:user)
 218       user2 = insert(:user)
 219       {:ok, _user_block} = Pleroma.User.block(user2, user)
 220
 221       response =
 222         conn
 223         |> post(remote_follow_path(conn, :do_follow), %{
 224           "authorization" => %{"name" => user.nickname, "password" => "test", "id" => user2.id}
 225         })
 226         |> response(200)
 227
 228       assert response =~ "Error following account"
 229     end
 230   end
 231 end