git.squeep.com Git - akkoma/blob - test/web/streamer/streamer_test.exs

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.StreamerTest do
   6   use Pleroma.DataCase
   7
   8   import Pleroma.Factory
   9
  10   alias Pleroma.Conversation.Participation
  11   alias Pleroma.List
  12   alias Pleroma.User
  13   alias Pleroma.Web.CommonAPI
  14   alias Pleroma.Web.Streamer
  15
  16   @moduletag needs_streamer: true, capture_log: true
  17
  18   setup do: clear_config([:instance, :skip_thread_containment])
  19
  20   describe "get_topic without an user" do
  21     test "allows public" do
  22       assert {:ok, "public"} = Streamer.get_topic("public", nil)
  23       assert {:ok, "public:local"} = Streamer.get_topic("public:local", nil)
  24       assert {:ok, "public:media"} = Streamer.get_topic("public:media", nil)
  25       assert {:ok, "public:local:media"} = Streamer.get_topic("public:local:media", nil)
  26     end
  27
  28     test "allows hashtag streams" do
  29       assert {:ok, "hashtag:cofe"} = Streamer.get_topic("hashtag", nil, %{"tag" => "cofe"})
  30     end
  31
  32     test "disallows user streams" do
  33       assert {:error, _} = Streamer.get_topic("user", nil)
  34       assert {:error, _} = Streamer.get_topic("user:notification", nil)
  35       assert {:error, _} = Streamer.get_topic("direct", nil)
  36     end
  37
  38     test "disallows list streams" do
  39       assert {:error, _} = Streamer.get_topic("list", nil, %{"list" => 42})
  40     end
  41   end
  42
  43   describe "get_topic with an user" do
  44     setup do
  45       user = insert(:user)
  46       {:ok, %{user: user}}
  47     end
  48
  49     test "allows public streams", %{user: user} do
  50       assert {:ok, "public"} = Streamer.get_topic("public", user)
  51       assert {:ok, "public:local"} = Streamer.get_topic("public:local", user)
  52       assert {:ok, "public:media"} = Streamer.get_topic("public:media", user)
  53       assert {:ok, "public:local:media"} = Streamer.get_topic("public:local:media", user)
  54     end
  55
  56     test "allows user streams", %{user: user} do
  57       expected_user_topic = "user:#{user.id}"
  58       expected_notif_topic = "user:notification:#{user.id}"
  59       expected_direct_topic = "direct:#{user.id}"
  60       assert {:ok, ^expected_user_topic} = Streamer.get_topic("user", user)
  61       assert {:ok, ^expected_notif_topic} = Streamer.get_topic("user:notification", user)
  62       assert {:ok, ^expected_direct_topic} = Streamer.get_topic("direct", user)
  63     end
  64
  65     test "allows hashtag streams", %{user: user} do
  66       assert {:ok, "hashtag:cofe"} = Streamer.get_topic("hashtag", user, %{"tag" => "cofe"})
  67     end
  68
  69     test "disallows registering to an user stream", %{user: user} do
  70       another_user = insert(:user)
  71       assert {:error, _} = Streamer.get_topic("user:#{another_user.id}", user)
  72       assert {:error, _} = Streamer.get_topic("user:notification:#{another_user.id}", user)
  73       assert {:error, _} = Streamer.get_topic("direct:#{another_user.id}", user)
  74     end
  75
  76     test "allows list stream that are owned by the user", %{user: user} do
  77       {:ok, list} = List.create("Test", user)
  78       assert {:error, _} = Streamer.get_topic("list:#{list.id}", user)
  79       assert {:ok, _} = Streamer.get_topic("list", user, %{"list" => list.id})
  80     end
  81
  82     test "disallows list stream that are not owned by the user", %{user: user} do
  83       another_user = insert(:user)
  84       {:ok, list} = List.create("Test", another_user)
  85       assert {:error, _} = Streamer.get_topic("list:#{list.id}", user)
  86       assert {:error, _} = Streamer.get_topic("list", user, %{"list" => list.id})
  87     end
  88   end
  89
  90   describe "user streams" do
  91     setup do
  92       user = insert(:user)
  93       notify = insert(:notification, user: user, activity: build(:note_activity))
  94       {:ok, %{user: user, notify: notify}}
  95     end
  96
  97     test "it streams the user's post in the 'user' stream", %{user: user} do
  98       Streamer.get_topic_and_add_socket("user", user)
  99       {:ok, activity} = CommonAPI.post(user, %{status: "hey"})
 100       assert_receive {:render_with_user, _, _, ^activity}
 101       refute Streamer.filtered_by_user?(user, activity)
 102     end
 103
 104     test "it streams boosts of the user in the 'user' stream", %{user: user} do
 105       Streamer.get_topic_and_add_socket("user", user)
 106
 107       other_user = insert(:user)
 108       {:ok, activity} = CommonAPI.post(other_user, %{status: "hey"})
 109       {:ok, announce} = CommonAPI.repeat(activity.id, user)
 110
 111       assert_receive {:render_with_user, Pleroma.Web.StreamerView, "update.json", ^announce}
 112       refute Streamer.filtered_by_user?(user, announce)
 113     end
 114
 115     test "it streams boosts of mastodon user in the 'user' stream", %{user: user} do
 116       Streamer.get_topic_and_add_socket("user", user)
 117
 118       other_user = insert(:user)
 119       {:ok, activity} = CommonAPI.post(other_user, %{status: "hey"})
 120
 121       data =
 122         File.read!("test/fixtures/mastodon-announce.json")
 123         |> Poison.decode!()
 124         |> Map.put("object", activity.data["object"])
 125         |> Map.put("actor", user.ap_id)
 126
 127       {:ok, %Pleroma.Activity{data: data, local: false} = announce} =
 128         Pleroma.Web.ActivityPub.Transmogrifier.handle_incoming(data)
 129
 130       assert_receive {:render_with_user, Pleroma.Web.StreamerView, "update.json", ^announce}
 131       refute Streamer.filtered_by_user?(user, announce)
 132     end
 133
 134     test "it sends notify to in the 'user' stream", %{user: user, notify: notify} do
 135       Streamer.get_topic_and_add_socket("user", user)
 136       Streamer.stream("user", notify)
 137       assert_receive {:render_with_user, _, _, ^notify}
 138       refute Streamer.filtered_by_user?(user, notify)
 139     end
 140
 141     test "it sends notify to in the 'user:notification' stream", %{user: user, notify: notify} do
 142       Streamer.get_topic_and_add_socket("user:notification", user)
 143       Streamer.stream("user:notification", notify)
 144       assert_receive {:render_with_user, _, _, ^notify}
 145       refute Streamer.filtered_by_user?(user, notify)
 146     end
 147
 148     test "it doesn't send notify to the 'user:notification' stream when a user is blocked", %{
 149       user: user
 150     } do
 151       blocked = insert(:user)
 152       {:ok, _user_relationship} = User.block(user, blocked)
 153
 154       Streamer.get_topic_and_add_socket("user:notification", user)
 155
 156       {:ok, activity} = CommonAPI.post(user, %{status: ":("})
 157       {:ok, _} = CommonAPI.favorite(blocked, activity.id)
 158
 159       refute_receive _
 160     end
 161
 162     test "it doesn't send notify to the 'user:notification' stream when a thread is muted", %{
 163       user: user
 164     } do
 165       user2 = insert(:user)
 166
 167       {:ok, activity} = CommonAPI.post(user, %{status: "super hot take"})
 168       {:ok, _} = CommonAPI.add_mute(user, activity)
 169
 170       Streamer.get_topic_and_add_socket("user:notification", user)
 171
 172       {:ok, favorite_activity} = CommonAPI.favorite(user2, activity.id)
 173
 174       refute_receive _
 175       assert Streamer.filtered_by_user?(user, favorite_activity)
 176     end
 177
 178     test "it sends favorite to 'user:notification' stream'", %{
 179       user: user
 180     } do
 181       user2 = insert(:user, %{ap_id: "https://hecking-lewd-place.com/user/meanie"})
 182
 183       {:ok, activity} = CommonAPI.post(user, %{status: "super hot take"})
 184       Streamer.get_topic_and_add_socket("user:notification", user)
 185       {:ok, favorite_activity} = CommonAPI.favorite(user2, activity.id)
 186
 187       assert_receive {:render_with_user, _, "notification.json", notif}
 188       assert notif.activity.id == favorite_activity.id
 189       refute Streamer.filtered_by_user?(user, notif)
 190     end
 191
 192     test "it doesn't send the 'user:notification' stream' when a domain is blocked", %{
 193       user: user
 194     } do
 195       user2 = insert(:user, %{ap_id: "https://hecking-lewd-place.com/user/meanie"})
 196
 197       {:ok, user} = User.block_domain(user, "hecking-lewd-place.com")
 198       {:ok, activity} = CommonAPI.post(user, %{status: "super hot take"})
 199       Streamer.get_topic_and_add_socket("user:notification", user)
 200       {:ok, favorite_activity} = CommonAPI.favorite(user2, activity.id)
 201
 202       refute_receive _
 203       assert Streamer.filtered_by_user?(user, favorite_activity)
 204     end
 205
 206     test "it sends follow activities to the 'user:notification' stream", %{
 207       user: user
 208     } do
 209       user_url = user.ap_id
 210       user2 = insert(:user)
 211
 212       body =
 213         File.read!("test/fixtures/users_mock/localhost.json")
 214         |> String.replace("{{nickname}}", user.nickname)
 215         |> Jason.encode!()
 216
 217       Tesla.Mock.mock_global(fn
 218         %{method: :get, url: ^user_url} ->
 219           %Tesla.Env{status: 200, body: body}
 220       end)
 221
 222       Streamer.get_topic_and_add_socket("user:notification", user)
 223       {:ok, _follower, _followed, follow_activity} = CommonAPI.follow(user2, user)
 224
 225       assert_receive {:render_with_user, _, "notification.json", notif}
 226       assert notif.activity.id == follow_activity.id
 227       refute Streamer.filtered_by_user?(user, notif)
 228     end
 229   end
 230
 231   test "it sends to public authenticated" do
 232     user = insert(:user)
 233     other_user = insert(:user)
 234
 235     Streamer.get_topic_and_add_socket("public", other_user)
 236
 237     {:ok, activity} = CommonAPI.post(user, %{status: "Test"})
 238     assert_receive {:render_with_user, _, _, ^activity}
 239     refute Streamer.filtered_by_user?(user, activity)
 240   end
 241
 242   test "works for deletions" do
 243     user = insert(:user)
 244     other_user = insert(:user)
 245     {:ok, activity} = CommonAPI.post(other_user, %{status: "Test"})
 246
 247     Streamer.get_topic_and_add_socket("public", user)
 248
 249     {:ok, _} = CommonAPI.delete(activity.id, other_user)
 250     activity_id = activity.id
 251     assert_receive {:text, event}
 252     assert %{"event" => "delete", "payload" => ^activity_id} = Jason.decode!(event)
 253   end
 254
 255   test "it sends to public unauthenticated" do
 256     user = insert(:user)
 257
 258     Streamer.get_topic_and_add_socket("public", nil)
 259
 260     {:ok, activity} = CommonAPI.post(user, %{status: "Test"})
 261     activity_id = activity.id
 262     assert_receive {:text, event}
 263     assert %{"event" => "update", "payload" => payload} = Jason.decode!(event)
 264     assert %{"id" => ^activity_id} = Jason.decode!(payload)
 265
 266     {:ok, _} = CommonAPI.delete(activity.id, user)
 267     assert_receive {:text, event}
 268     assert %{"event" => "delete", "payload" => ^activity_id} = Jason.decode!(event)
 269   end
 270
 271   describe "thread_containment" do
 272     test "it filters to user if recipients invalid and thread containment is enabled" do
 273       Pleroma.Config.put([:instance, :skip_thread_containment], false)
 274       author = insert(:user)
 275       user = insert(:user)
 276       User.follow(user, author, :follow_accept)
 277
 278       activity =
 279         insert(:note_activity,
 280           note:
 281             insert(:note,
 282               user: author,
 283               data: %{"to" => ["TEST-FFF"]}
 284             )
 285         )
 286
 287       Streamer.get_topic_and_add_socket("public", user)
 288       Streamer.stream("public", activity)
 289       assert_receive {:render_with_user, _, _, ^activity}
 290       assert Streamer.filtered_by_user?(user, activity)
 291     end
 292
 293     test "it sends message if recipients invalid and thread containment is disabled" do
 294       Pleroma.Config.put([:instance, :skip_thread_containment], true)
 295       author = insert(:user)
 296       user = insert(:user)
 297       User.follow(user, author, :follow_accept)
 298
 299       activity =
 300         insert(:note_activity,
 301           note:
 302             insert(:note,
 303               user: author,
 304               data: %{"to" => ["TEST-FFF"]}
 305             )
 306         )
 307
 308       Streamer.get_topic_and_add_socket("public", user)
 309       Streamer.stream("public", activity)
 310
 311       assert_receive {:render_with_user, _, _, ^activity}
 312       refute Streamer.filtered_by_user?(user, activity)
 313     end
 314
 315     test "it sends message if recipients invalid and thread containment is enabled but user's thread containment is disabled" do
 316       Pleroma.Config.put([:instance, :skip_thread_containment], false)
 317       author = insert(:user)
 318       user = insert(:user, skip_thread_containment: true)
 319       User.follow(user, author, :follow_accept)
 320
 321       activity =
 322         insert(:note_activity,
 323           note:
 324             insert(:note,
 325               user: author,
 326               data: %{"to" => ["TEST-FFF"]}
 327             )
 328         )
 329
 330       Streamer.get_topic_and_add_socket("public", user)
 331       Streamer.stream("public", activity)
 332
 333       assert_receive {:render_with_user, _, _, ^activity}
 334       refute Streamer.filtered_by_user?(user, activity)
 335     end
 336   end
 337
 338   describe "blocks" do
 339     test "it filters messages involving blocked users" do
 340       user = insert(:user)
 341       blocked_user = insert(:user)
 342       {:ok, _user_relationship} = User.block(user, blocked_user)
 343
 344       Streamer.get_topic_and_add_socket("public", user)
 345       {:ok, activity} = CommonAPI.post(blocked_user, %{status: "Test"})
 346       assert_receive {:render_with_user, _, _, ^activity}
 347       assert Streamer.filtered_by_user?(user, activity)
 348     end
 349
 350     test "it filters messages transitively involving blocked users" do
 351       blocker = insert(:user)
 352       blockee = insert(:user)
 353       friend = insert(:user)
 354
 355       Streamer.get_topic_and_add_socket("public", blocker)
 356
 357       {:ok, _user_relationship} = User.block(blocker, blockee)
 358
 359       {:ok, activity_one} = CommonAPI.post(friend, %{status: "hey! @#{blockee.nickname}"})
 360
 361       assert_receive {:render_with_user, _, _, ^activity_one}
 362       assert Streamer.filtered_by_user?(blocker, activity_one)
 363
 364       {:ok, activity_two} = CommonAPI.post(blockee, %{status: "hey! @#{friend.nickname}"})
 365
 366       assert_receive {:render_with_user, _, _, ^activity_two}
 367       assert Streamer.filtered_by_user?(blocker, activity_two)
 368
 369       {:ok, activity_three} = CommonAPI.post(blockee, %{status: "hey! @#{blocker.nickname}"})
 370
 371       assert_receive {:render_with_user, _, _, ^activity_three}
 372       assert Streamer.filtered_by_user?(blocker, activity_three)
 373     end
 374   end
 375
 376   describe "lists" do
 377     test "it doesn't send unwanted DMs to list" do
 378       user_a = insert(:user)
 379       user_b = insert(:user)
 380       user_c = insert(:user)
 381
 382       {:ok, user_a} = User.follow(user_a, user_b)
 383
 384       {:ok, list} = List.create("Test", user_a)
 385       {:ok, list} = List.follow(list, user_b)
 386
 387       Streamer.get_topic_and_add_socket("list", user_a, %{"list" => list.id})
 388
 389       {:ok, _activity} =
 390         CommonAPI.post(user_b, %{
 391           status: "@#{user_c.nickname} Test",
 392           visibility: "direct"
 393         })
 394
 395       refute_receive _
 396     end
 397
 398     test "it doesn't send unwanted private posts to list" do
 399       user_a = insert(:user)
 400       user_b = insert(:user)
 401
 402       {:ok, list} = List.create("Test", user_a)
 403       {:ok, list} = List.follow(list, user_b)
 404
 405       Streamer.get_topic_and_add_socket("list", user_a, %{"list" => list.id})
 406
 407       {:ok, _activity} =
 408         CommonAPI.post(user_b, %{
 409           status: "Test",
 410           visibility: "private"
 411         })
 412
 413       refute_receive _
 414     end
 415
 416     test "it sends wanted private posts to list" do
 417       user_a = insert(:user)
 418       user_b = insert(:user)
 419
 420       {:ok, user_a} = User.follow(user_a, user_b)
 421
 422       {:ok, list} = List.create("Test", user_a)
 423       {:ok, list} = List.follow(list, user_b)
 424
 425       Streamer.get_topic_and_add_socket("list", user_a, %{"list" => list.id})
 426
 427       {:ok, activity} =
 428         CommonAPI.post(user_b, %{
 429           status: "Test",
 430           visibility: "private"
 431         })
 432
 433       assert_receive {:render_with_user, _, _, ^activity}
 434       refute Streamer.filtered_by_user?(user_a, activity)
 435     end
 436   end
 437
 438   describe "muted reblogs" do
 439     test "it filters muted reblogs" do
 440       user1 = insert(:user)
 441       user2 = insert(:user)
 442       user3 = insert(:user)
 443       CommonAPI.follow(user1, user2)
 444       CommonAPI.hide_reblogs(user1, user2)
 445
 446       {:ok, create_activity} = CommonAPI.post(user3, %{status: "I'm kawen"})
 447
 448       Streamer.get_topic_and_add_socket("user", user1)
 449       {:ok, announce_activity} = CommonAPI.repeat(create_activity.id, user2)
 450       assert_receive {:render_with_user, _, _, ^announce_activity}
 451       assert Streamer.filtered_by_user?(user1, announce_activity)
 452     end
 453
 454     test "it filters reblog notification for reblog-muted actors" do
 455       user1 = insert(:user)
 456       user2 = insert(:user)
 457       CommonAPI.follow(user1, user2)
 458       CommonAPI.hide_reblogs(user1, user2)
 459
 460       {:ok, create_activity} = CommonAPI.post(user1, %{status: "I'm kawen"})
 461       Streamer.get_topic_and_add_socket("user", user1)
 462       {:ok, _announce_activity} = CommonAPI.repeat(create_activity.id, user2)
 463
 464       assert_receive {:render_with_user, _, "notification.json", notif}
 465       assert Streamer.filtered_by_user?(user1, notif)
 466     end
 467
 468     test "it send non-reblog notification for reblog-muted actors" do
 469       user1 = insert(:user)
 470       user2 = insert(:user)
 471       CommonAPI.follow(user1, user2)
 472       CommonAPI.hide_reblogs(user1, user2)
 473
 474       {:ok, create_activity} = CommonAPI.post(user1, %{status: "I'm kawen"})
 475       Streamer.get_topic_and_add_socket("user", user1)
 476       {:ok, _favorite_activity} = CommonAPI.favorite(user2, create_activity.id)
 477
 478       assert_receive {:render_with_user, _, "notification.json", notif}
 479       refute Streamer.filtered_by_user?(user1, notif)
 480     end
 481   end
 482
 483   test "it filters posts from muted threads" do
 484     user = insert(:user)
 485     user2 = insert(:user)
 486     Streamer.get_topic_and_add_socket("user", user2)
 487     {:ok, user2, user, _activity} = CommonAPI.follow(user2, user)
 488     {:ok, activity} = CommonAPI.post(user, %{status: "super hot take"})
 489     {:ok, _} = CommonAPI.add_mute(user2, activity)
 490     assert_receive {:render_with_user, _, _, ^activity}
 491     assert Streamer.filtered_by_user?(user2, activity)
 492   end
 493
 494   describe "direct streams" do
 495     setup do
 496       :ok
 497     end
 498
 499     test "it sends conversation update to the 'direct' stream", %{} do
 500       user = insert(:user)
 501       another_user = insert(:user)
 502
 503       Streamer.get_topic_and_add_socket("direct", user)
 504
 505       {:ok, _create_activity} =
 506         CommonAPI.post(another_user, %{
 507           status: "hey @#{user.nickname}",
 508           visibility: "direct"
 509         })
 510
 511       assert_receive {:text, received_event}
 512
 513       assert %{"event" => "conversation", "payload" => received_payload} =
 514                Jason.decode!(received_event)
 515
 516       assert %{"last_status" => last_status} = Jason.decode!(received_payload)
 517       [participation] = Participation.for_user(user)
 518       assert last_status["pleroma"]["direct_conversation_id"] == participation.id
 519     end
 520
 521     test "it doesn't send conversation update to the 'direct' stream when the last message in the conversation is deleted" do
 522       user = insert(:user)
 523       another_user = insert(:user)
 524
 525       Streamer.get_topic_and_add_socket("direct", user)
 526
 527       {:ok, create_activity} =
 528         CommonAPI.post(another_user, %{
 529           status: "hi @#{user.nickname}",
 530           visibility: "direct"
 531         })
 532
 533       create_activity_id = create_activity.id
 534       assert_receive {:render_with_user, _, _, ^create_activity}
 535       assert_receive {:text, received_conversation1}
 536       assert %{"event" => "conversation", "payload" => _} = Jason.decode!(received_conversation1)
 537
 538       {:ok, _} = CommonAPI.delete(create_activity_id, another_user)
 539
 540       assert_receive {:text, received_event}
 541
 542       assert %{"event" => "delete", "payload" => ^create_activity_id} =
 543                Jason.decode!(received_event)
 544
 545       refute_receive _
 546     end
 547
 548     test "it sends conversation update to the 'direct' stream when a message is deleted" do
 549       user = insert(:user)
 550       another_user = insert(:user)
 551       Streamer.get_topic_and_add_socket("direct", user)
 552
 553       {:ok, create_activity} =
 554         CommonAPI.post(another_user, %{
 555           status: "hi @#{user.nickname}",
 556           visibility: "direct"
 557         })
 558
 559       {:ok, create_activity2} =
 560         CommonAPI.post(another_user, %{
 561           status: "hi @#{user.nickname} 2",
 562           in_reply_to_status_id: create_activity.id,
 563           visibility: "direct"
 564         })
 565
 566       assert_receive {:render_with_user, _, _, ^create_activity}
 567       assert_receive {:render_with_user, _, _, ^create_activity2}
 568       assert_receive {:text, received_conversation1}
 569       assert %{"event" => "conversation", "payload" => _} = Jason.decode!(received_conversation1)
 570       assert_receive {:text, received_conversation1}
 571       assert %{"event" => "conversation", "payload" => _} = Jason.decode!(received_conversation1)
 572
 573       {:ok, _} = CommonAPI.delete(create_activity2.id, another_user)
 574
 575       assert_receive {:text, received_event}
 576       assert %{"event" => "delete", "payload" => _} = Jason.decode!(received_event)
 577
 578       assert_receive {:text, received_event}
 579
 580       assert %{"event" => "conversation", "payload" => received_payload} =
 581                Jason.decode!(received_event)
 582
 583       assert %{"last_status" => last_status} = Jason.decode!(received_payload)
 584       assert last_status["id"] == to_string(create_activity.id)
 585     end
 586   end
 587 end