git.squeep.com Git - akkoma/blob - test/web/salmon/salmon_test.exs

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2018 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.Salmon.SalmonTest do
   6   use Pleroma.DataCase
   7   alias Pleroma.Activity
   8   alias Pleroma.Repo
   9   alias Pleroma.User
  10   alias Pleroma.Web.Salmon
  11   import Pleroma.Factory
  12
  13   @magickey "RSA.pu0s-halox4tu7wmES1FVSx6u-4wc0YrUFXcqWXZG4-27UmbCOpMQftRCldNRfyA-qLbz-eqiwQhh-1EwUvjsD4cYbAHNGHwTvDOyx5AKthQUP44ykPv7kjKGh3DWKySJvcs9tlUG87hlo7AvnMo9pwRS_Zz2CacQ-MKaXyDepk=.AQAB"
  14
  15   @wrong_magickey "RSA.pu0s-halox4tu7wmES1FVSx6u-4wc0YrUFXcqWXZG4-27UmbCOpMQftRCldNRfyA-qLbz-eqiwQhh-1EwUvjsD4cYbAHNGHwTvDOyx5AKthQUP44ykPv7kjKGh3DWKySJvcs9tlUG87hlo7AvnMo9pwRS_Zz2CacQ-MKaXyDepk=.AQAA"
  16
  17   @magickey_friendica "RSA.AMwa8FUs2fWEjX0xN7yRQgegQffhBpuKNC6fa5VNSVorFjGZhRrlPMn7TQOeihlc9lBz2OsHlIedbYn2uJ7yCs0.AQAB"
  18
  19   setup_all do
  20     Tesla.Mock.mock_global(fn env -> apply(HttpRequestMock, :request, [env]) end)
  21     :ok
  22   end
  23
  24   test "decodes a salmon" do
  25     {:ok, salmon} = File.read("test/fixtures/salmon.xml")
  26     {:ok, doc} = Salmon.decode_and_validate(@magickey, salmon)
  27     assert Regex.match?(~r/xml/, doc)
  28   end
  29
  30   test "errors on wrong magic key" do
  31     {:ok, salmon} = File.read("test/fixtures/salmon.xml")
  32     assert Salmon.decode_and_validate(@wrong_magickey, salmon) == :error
  33   end
  34
  35   test "generates an RSA private key pem" do
  36     {:ok, key} = Salmon.generate_rsa_pem()
  37     assert is_binary(key)
  38     assert Regex.match?(~r/RSA/, key)
  39   end
  40
  41   test "it encodes a magic key from a public key" do
  42     key = Salmon.decode_key(@magickey)
  43     magic_key = Salmon.encode_key(key)
  44
  45     assert @magickey == magic_key
  46   end
  47
  48   test "it decodes a friendica public key" do
  49     _key = Salmon.decode_key(@magickey_friendica)
  50   end
  51
  52   test "returns a public and private key from a pem" do
  53     pem = File.read!("test/fixtures/private_key.pem")
  54     {:ok, private, public} = Salmon.keys_from_pem(pem)
  55
  56     assert elem(private, 0) == :RSAPrivateKey
  57     assert elem(public, 0) == :RSAPublicKey
  58   end
  59
  60   test "encodes an xml payload with a private key" do
  61     doc = File.read!("test/fixtures/incoming_note_activity.xml")
  62     pem = File.read!("test/fixtures/private_key.pem")
  63     {:ok, private, public} = Salmon.keys_from_pem(pem)
  64
  65     # Let's try a roundtrip.
  66     {:ok, salmon} = Salmon.encode(private, doc)
  67     {:ok, decoded_doc} = Salmon.decode_and_validate(Salmon.encode_key(public), salmon)
  68
  69     assert doc == decoded_doc
  70   end
  71
  72   test "it gets a magic key" do
  73     salmon = File.read!("test/fixtures/salmon2.xml")
  74     {:ok, key} = Salmon.fetch_magic_key(salmon)
  75
  76     assert key ==
  77              "RSA.uzg6r1peZU0vXGADWxGJ0PE34WvmhjUmydbX5YYdOiXfODVLwCMi1umGoqUDm-mRu4vNEdFBVJU1CpFA7dKzWgIsqsa501i2XqElmEveXRLvNRWFB6nG03Q5OUY2as8eE54BJm0p20GkMfIJGwP6TSFb-ICp3QjzbatuSPJ6xCE=.AQAB"
  78   end
  79
  80   test "it pushes an activity to remote accounts it's addressed to" do
  81     user_data = %{
  82       info: %{
  83         salmon: "http://test-example.org/salmon"
  84       },
  85       local: false
  86     }
  87
  88     mentioned_user = insert(:user, user_data)
  89     note = insert(:note)
  90
  91     activity_data = %{
  92       "id" => Pleroma.Web.ActivityPub.Utils.generate_activity_id(),
  93       "type" => "Create",
  94       "actor" => note.data["actor"],
  95       "to" => note.data["to"] ++ [mentioned_user.ap_id],
  96       "object" => note.data,
  97       "published_at" => DateTime.utc_now() |> DateTime.to_iso8601(),
  98       "context" => note.data["context"]
  99     }
 100
 101     {:ok, activity} = Repo.insert(%Activity{data: activity_data, recipients: activity_data["to"]})
 102     user = User.get_cached_by_ap_id(activity.data["actor"])
 103     {:ok, user} = Pleroma.Web.WebFinger.ensure_keys_present(user)
 104
 105     poster = fn url, _data, _headers ->
 106       assert url == "http://test-example.org/salmon"
 107     end
 108
 109     Salmon.publish(user, activity, poster)
 110   end
 111 end