git.squeep.com Git - akkoma/blob - test/web/pleroma_api/pleroma_api_controller_test.exs

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.PleromaAPI.PleromaAPIControllerTest do
   6   use Pleroma.Web.ConnCase
   7
   8   alias Pleroma.Conversation.Participation
   9   alias Pleroma.Repo
  10   alias Pleroma.Web.CommonAPI
  11
  12   import Pleroma.Factory
  13
  14   test "POST /api/v1/pleroma/statuses/:id/react_with_emoji", %{conn: conn} do
  15     user = insert(:user)
  16     other_user = insert(:user)
  17
  18     {:ok, activity} = CommonAPI.post(user, %{"status" => "#cofe"})
  19
  20     result =
  21       conn
  22       |> assign(:user, other_user)
  23       |> post("/api/v1/pleroma/statuses/#{activity.id}/react_with_emoji", %{"emoji" => "☕"})
  24
  25     assert %{"id" => id} = json_response(result, 200)
  26     assert to_string(activity.id) == id
  27   end
  28
  29   test "/api/v1/pleroma/conversations/:id", %{conn: conn} do
  30     user = insert(:user)
  31     other_user = insert(:user)
  32
  33     {:ok, _activity} =
  34       CommonAPI.post(user, %{"status" => "Hi @#{other_user.nickname}!", "visibility" => "direct"})
  35
  36     [participation] = Participation.for_user(other_user)
  37
  38     result =
  39       conn
  40       |> assign(:user, other_user)
  41       |> get("/api/v1/pleroma/conversations/#{participation.id}")
  42       |> json_response(200)
  43
  44     assert result["id"] == participation.id |> to_string()
  45   end
  46
  47   test "/api/v1/pleroma/conversations/:id/statuses", %{conn: conn} do
  48     user = insert(:user)
  49     other_user = insert(:user)
  50     third_user = insert(:user)
  51
  52     {:ok, _activity} =
  53       CommonAPI.post(user, %{"status" => "Hi @#{third_user.nickname}!", "visibility" => "direct"})
  54
  55     {:ok, activity} =
  56       CommonAPI.post(user, %{"status" => "Hi @#{other_user.nickname}!", "visibility" => "direct"})
  57
  58     [participation] = Participation.for_user(other_user)
  59
  60     {:ok, activity_two} =
  61       CommonAPI.post(other_user, %{
  62         "status" => "Hi!",
  63         "in_reply_to_status_id" => activity.id,
  64         "in_reply_to_conversation_id" => participation.id
  65       })
  66
  67     result =
  68       conn
  69       |> assign(:user, other_user)
  70       |> get("/api/v1/pleroma/conversations/#{participation.id}/statuses")
  71       |> json_response(200)
  72
  73     assert length(result) == 2
  74
  75     id_one = activity.id
  76     id_two = activity_two.id
  77     assert [%{"id" => ^id_one}, %{"id" => ^id_two}] = result
  78   end
  79
  80   test "PATCH /api/v1/pleroma/conversations/:id", %{conn: conn} do
  81     user = insert(:user)
  82     other_user = insert(:user)
  83
  84     {:ok, _activity} = CommonAPI.post(user, %{"status" => "Hi", "visibility" => "direct"})
  85
  86     [participation] = Participation.for_user(user)
  87
  88     participation = Repo.preload(participation, :recipients)
  89
  90     assert [user] == participation.recipients
  91     assert other_user not in participation.recipients
  92
  93     result =
  94       conn
  95       |> assign(:user, user)
  96       |> patch("/api/v1/pleroma/conversations/#{participation.id}", %{
  97         "recipients" => [user.id, other_user.id]
  98       })
  99       |> json_response(200)
 100
 101     assert result["id"] == participation.id |> to_string
 102
 103     [participation] = Participation.for_user(user)
 104     participation = Repo.preload(participation, :recipients)
 105
 106     assert user in participation.recipients
 107     assert other_user in participation.recipients
 108   end
 109 end