git.squeep.com Git - akkoma/blob - test/web/pleroma_api/controllers/pleroma_api_controller_test.exs

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.PleromaAPI.PleromaAPIControllerTest do
   6   use Pleroma.Web.ConnCase
   7
   8   alias Pleroma.Conversation.Participation
   9   alias Pleroma.Notification
  10   alias Pleroma.Repo
  11   alias Pleroma.Web.CommonAPI
  12
  13   import Pleroma.Factory
  14
  15   test "POST /api/v1/pleroma/statuses/:id/react_with_emoji", %{conn: conn} do
  16     user = insert(:user)
  17     other_user = insert(:user)
  18
  19     {:ok, activity} = CommonAPI.post(user, %{"status" => "#cofe"})
  20
  21     result =
  22       conn
  23       |> assign(:user, other_user)
  24       |> post("/api/v1/pleroma/statuses/#{activity.id}/react_with_emoji", %{"emoji" => "☕"})
  25
  26     assert %{"id" => id} = json_response(result, 200)
  27     assert to_string(activity.id) == id
  28   end
  29
  30   test "POST /api/v1/pleroma/statuses/:id/unreact_with_emoji", %{conn: conn} do
  31     user = insert(:user)
  32     other_user = insert(:user)
  33
  34     {:ok, activity} = CommonAPI.post(user, %{"status" => "#cofe"})
  35     {:ok, activity, _object} = CommonAPI.react_with_emoji(activity.id, other_user, "☕")
  36
  37     result =
  38       conn
  39       |> assign(:user, other_user)
  40       |> post("/api/v1/pleroma/statuses/#{activity.id}/unreact_with_emoji", %{"emoji" => "☕"})
  41
  42     assert %{"id" => id} = json_response(result, 200)
  43     assert to_string(activity.id) == id
  44   end
  45
  46   test "GET /api/v1/pleroma/statuses/:id/emoji_reactions_by", %{conn: conn} do
  47     user = insert(:user)
  48     other_user = insert(:user)
  49
  50     {:ok, activity} = CommonAPI.post(user, %{"status" => "#cofe"})
  51
  52     result =
  53       conn
  54       |> get("/api/v1/pleroma/statuses/#{activity.id}/emoji_reactions_by")
  55       |> json_response(200)
  56
  57     assert result == %{}
  58
  59     {:ok, _, _} = CommonAPI.react_with_emoji(activity.id, other_user, "🎅")
  60
  61     result =
  62       conn
  63       |> get("/api/v1/pleroma/statuses/#{activity.id}/emoji_reactions_by")
  64       |> json_response(200)
  65
  66     [represented_user] = result["🎅"]
  67     assert represented_user["id"] == other_user.id
  68   end
  69
  70   test "/api/v1/pleroma/conversations/:id", %{conn: conn} do
  71     user = insert(:user)
  72     other_user = insert(:user)
  73
  74     {:ok, _activity} =
  75       CommonAPI.post(user, %{"status" => "Hi @#{other_user.nickname}!", "visibility" => "direct"})
  76
  77     [participation] = Participation.for_user(other_user)
  78
  79     result =
  80       conn
  81       |> assign(:user, other_user)
  82       |> get("/api/v1/pleroma/conversations/#{participation.id}")
  83       |> json_response(200)
  84
  85     assert result["id"] == participation.id |> to_string()
  86   end
  87
  88   test "/api/v1/pleroma/conversations/:id/statuses", %{conn: conn} do
  89     user = insert(:user)
  90     other_user = insert(:user)
  91     third_user = insert(:user)
  92
  93     {:ok, _activity} =
  94       CommonAPI.post(user, %{"status" => "Hi @#{third_user.nickname}!", "visibility" => "direct"})
  95
  96     {:ok, activity} =
  97       CommonAPI.post(user, %{"status" => "Hi @#{other_user.nickname}!", "visibility" => "direct"})
  98
  99     [participation] = Participation.for_user(other_user)
 100
 101     {:ok, activity_two} =
 102       CommonAPI.post(other_user, %{
 103         "status" => "Hi!",
 104         "in_reply_to_status_id" => activity.id,
 105         "in_reply_to_conversation_id" => participation.id
 106       })
 107
 108     result =
 109       conn
 110       |> assign(:user, other_user)
 111       |> get("/api/v1/pleroma/conversations/#{participation.id}/statuses")
 112       |> json_response(200)
 113
 114     assert length(result) == 2
 115
 116     id_one = activity.id
 117     id_two = activity_two.id
 118     assert [%{"id" => ^id_one}, %{"id" => ^id_two}] = result
 119   end
 120
 121   test "PATCH /api/v1/pleroma/conversations/:id", %{conn: conn} do
 122     user = insert(:user)
 123     other_user = insert(:user)
 124
 125     {:ok, _activity} = CommonAPI.post(user, %{"status" => "Hi", "visibility" => "direct"})
 126
 127     [participation] = Participation.for_user(user)
 128
 129     participation = Repo.preload(participation, :recipients)
 130
 131     assert [user] == participation.recipients
 132     assert other_user not in participation.recipients
 133
 134     result =
 135       conn
 136       |> assign(:user, user)
 137       |> patch("/api/v1/pleroma/conversations/#{participation.id}", %{
 138         "recipients" => [user.id, other_user.id]
 139       })
 140       |> json_response(200)
 141
 142     assert result["id"] == participation.id |> to_string
 143
 144     [participation] = Participation.for_user(user)
 145     participation = Repo.preload(participation, :recipients)
 146
 147     assert user in participation.recipients
 148     assert other_user in participation.recipients
 149   end
 150
 151   describe "POST /api/v1/pleroma/notifications/read" do
 152     test "it marks a single notification as read", %{conn: conn} do
 153       user1 = insert(:user)
 154       user2 = insert(:user)
 155       {:ok, activity1} = CommonAPI.post(user2, %{"status" => "hi @#{user1.nickname}"})
 156       {:ok, activity2} = CommonAPI.post(user2, %{"status" => "hi @#{user1.nickname}"})
 157       {:ok, [notification1]} = Notification.create_notifications(activity1)
 158       {:ok, [notification2]} = Notification.create_notifications(activity2)
 159
 160       response =
 161         conn
 162         |> assign(:user, user1)
 163         |> post("/api/v1/pleroma/notifications/read", %{"id" => "#{notification1.id}"})
 164         |> json_response(:ok)
 165
 166       assert %{"pleroma" => %{"is_seen" => true}} = response
 167       assert Repo.get(Notification, notification1.id).seen
 168       refute Repo.get(Notification, notification2.id).seen
 169     end
 170
 171     test "it marks multiple notifications as read", %{conn: conn} do
 172       user1 = insert(:user)
 173       user2 = insert(:user)
 174       {:ok, _activity1} = CommonAPI.post(user2, %{"status" => "hi @#{user1.nickname}"})
 175       {:ok, _activity2} = CommonAPI.post(user2, %{"status" => "hi @#{user1.nickname}"})
 176       {:ok, _activity3} = CommonAPI.post(user2, %{"status" => "HIE @#{user1.nickname}"})
 177
 178       [notification3, notification2, notification1] = Notification.for_user(user1, %{limit: 3})
 179
 180       [response1, response2] =
 181         conn
 182         |> assign(:user, user1)
 183         |> post("/api/v1/pleroma/notifications/read", %{"max_id" => "#{notification2.id}"})
 184         |> json_response(:ok)
 185
 186       assert %{"pleroma" => %{"is_seen" => true}} = response1
 187       assert %{"pleroma" => %{"is_seen" => true}} = response2
 188       assert Repo.get(Notification, notification1.id).seen
 189       assert Repo.get(Notification, notification2.id).seen
 190       refute Repo.get(Notification, notification3.id).seen
 191     end
 192
 193     test "it returns error when notification not found", %{conn: conn} do
 194       user1 = insert(:user)
 195
 196       response =
 197         conn
 198         |> assign(:user, user1)
 199         |> post("/api/v1/pleroma/notifications/read", %{"id" => "22222222222222"})
 200         |> json_response(:bad_request)
 201
 202       assert response == %{"error" => "Cannot get notification"}
 203     end
 204   end
 205 end