git.squeep.com Git - akkoma/blob - test/web/pleroma_api/controllers/chat_controller_test.exs

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4 defmodule Pleroma.Web.PleromaAPI.ChatControllerTest do
   5   use Pleroma.Web.ConnCase, async: true
   6
   7   alias Pleroma.Chat
   8   alias Pleroma.Chat.MessageReference
   9   alias Pleroma.Object
  10   alias Pleroma.User
  11   alias Pleroma.Web.ActivityPub.ActivityPub
  12   alias Pleroma.Web.CommonAPI
  13
  14   import Pleroma.Factory
  15
  16   describe "POST /api/v1/pleroma/chats/:id/messages/:message_id/read" do
  17     setup do: oauth_access(["write:chats"])
  18
  19     test "it marks one message as read", %{conn: conn, user: user} do
  20       other_user = insert(:user)
  21
  22       {:ok, create} = CommonAPI.post_chat_message(other_user, user, "sup")
  23       {:ok, _create} = CommonAPI.post_chat_message(other_user, user, "sup part 2")
  24       {:ok, chat} = Chat.get_or_create(user.id, other_user.ap_id)
  25       object = Object.normalize(create, false)
  26       cm_ref = MessageReference.for_chat_and_object(chat, object)
  27
  28       assert cm_ref.unread == true
  29
  30       result =
  31         conn
  32         |> post("/api/v1/pleroma/chats/#{chat.id}/messages/#{cm_ref.id}/read")
  33         |> json_response_and_validate_schema(200)
  34
  35       assert result["unread"] == false
  36
  37       cm_ref = MessageReference.for_chat_and_object(chat, object)
  38
  39       assert cm_ref.unread == false
  40     end
  41   end
  42
  43   describe "POST /api/v1/pleroma/chats/:id/read" do
  44     setup do: oauth_access(["write:chats"])
  45
  46     test "given a `last_read_id`, it marks everything until then as read", %{
  47       conn: conn,
  48       user: user
  49     } do
  50       other_user = insert(:user)
  51
  52       {:ok, create} = CommonAPI.post_chat_message(other_user, user, "sup")
  53       {:ok, _create} = CommonAPI.post_chat_message(other_user, user, "sup part 2")
  54       {:ok, chat} = Chat.get_or_create(user.id, other_user.ap_id)
  55       object = Object.normalize(create, false)
  56       cm_ref = MessageReference.for_chat_and_object(chat, object)
  57
  58       assert cm_ref.unread == true
  59
  60       result =
  61         conn
  62         |> put_req_header("content-type", "application/json")
  63         |> post("/api/v1/pleroma/chats/#{chat.id}/read", %{"last_read_id" => cm_ref.id})
  64         |> json_response_and_validate_schema(200)
  65
  66       assert result["unread"] == 1
  67
  68       cm_ref = MessageReference.for_chat_and_object(chat, object)
  69
  70       assert cm_ref.unread == false
  71     end
  72   end
  73
  74   describe "POST /api/v1/pleroma/chats/:id/messages" do
  75     setup do: oauth_access(["write:chats"])
  76
  77     test "it posts a message to the chat", %{conn: conn, user: user} do
  78       other_user = insert(:user)
  79
  80       {:ok, chat} = Chat.get_or_create(user.id, other_user.ap_id)
  81
  82       result =
  83         conn
  84         |> put_req_header("content-type", "application/json")
  85         |> post("/api/v1/pleroma/chats/#{chat.id}/messages", %{"content" => "Hallo!!"})
  86         |> json_response_and_validate_schema(200)
  87
  88       assert result["content"] == "Hallo!!"
  89       assert result["chat_id"] == chat.id |> to_string()
  90     end
  91
  92     test "it fails if there is no content", %{conn: conn, user: user} do
  93       other_user = insert(:user)
  94
  95       {:ok, chat} = Chat.get_or_create(user.id, other_user.ap_id)
  96
  97       result =
  98         conn
  99         |> put_req_header("content-type", "application/json")
 100         |> post("/api/v1/pleroma/chats/#{chat.id}/messages")
 101         |> json_response_and_validate_schema(400)
 102
 103       assert %{"error" => "no_content"} == result
 104     end
 105
 106     test "it works with an attachment", %{conn: conn, user: user} do
 107       file = %Plug.Upload{
 108         content_type: "image/jpg",
 109         path: Path.absname("test/fixtures/image.jpg"),
 110         filename: "an_image.jpg"
 111       }
 112
 113       {:ok, upload} = ActivityPub.upload(file, actor: user.ap_id)
 114
 115       other_user = insert(:user)
 116
 117       {:ok, chat} = Chat.get_or_create(user.id, other_user.ap_id)
 118
 119       result =
 120         conn
 121         |> put_req_header("content-type", "application/json")
 122         |> post("/api/v1/pleroma/chats/#{chat.id}/messages", %{
 123           "media_id" => to_string(upload.id)
 124         })
 125         |> json_response_and_validate_schema(200)
 126
 127       assert result["attachment"]
 128     end
 129
 130     test "gets MRF reason when rejected", %{conn: conn, user: user} do
 131       clear_config([:mrf_keyword, :reject], ["GNO"])
 132       clear_config([:mrf, :policies], [Pleroma.Web.ActivityPub.MRF.KeywordPolicy])
 133
 134       other_user = insert(:user)
 135
 136       {:ok, chat} = Chat.get_or_create(user.id, other_user.ap_id)
 137
 138       result =
 139         conn
 140         |> put_req_header("content-type", "application/json")
 141         |> post("/api/v1/pleroma/chats/#{chat.id}/messages", %{"content" => "GNO/Linux"})
 142         |> json_response_and_validate_schema(422)
 143
 144       assert %{"error" => "[KeywordPolicy] Matches with rejected keyword"} == result
 145     end
 146   end
 147
 148   describe "DELETE /api/v1/pleroma/chats/:id/messages/:message_id" do
 149     setup do: oauth_access(["write:chats"])
 150
 151     test "it deletes a message from the chat", %{conn: conn, user: user} do
 152       recipient = insert(:user)
 153
 154       {:ok, message} =
 155         CommonAPI.post_chat_message(user, recipient, "Hello darkness my old friend")
 156
 157       {:ok, other_message} = CommonAPI.post_chat_message(recipient, user, "nico nico ni")
 158
 159       object = Object.normalize(message, false)
 160
 161       chat = Chat.get(user.id, recipient.ap_id)
 162
 163       cm_ref = MessageReference.for_chat_and_object(chat, object)
 164
 165       # Deleting your own message removes the message and the reference
 166       result =
 167         conn
 168         |> put_req_header("content-type", "application/json")
 169         |> delete("/api/v1/pleroma/chats/#{chat.id}/messages/#{cm_ref.id}")
 170         |> json_response_and_validate_schema(200)
 171
 172       assert result["id"] == cm_ref.id
 173       refute MessageReference.get_by_id(cm_ref.id)
 174       assert %{data: %{"type" => "Tombstone"}} = Object.get_by_id(object.id)
 175
 176       # Deleting other people's messages just removes the reference
 177       object = Object.normalize(other_message, false)
 178       cm_ref = MessageReference.for_chat_and_object(chat, object)
 179
 180       result =
 181         conn
 182         |> put_req_header("content-type", "application/json")
 183         |> delete("/api/v1/pleroma/chats/#{chat.id}/messages/#{cm_ref.id}")
 184         |> json_response_and_validate_schema(200)
 185
 186       assert result["id"] == cm_ref.id
 187       refute MessageReference.get_by_id(cm_ref.id)
 188       assert Object.get_by_id(object.id)
 189     end
 190   end
 191
 192   describe "GET /api/v1/pleroma/chats/:id/messages" do
 193     setup do: oauth_access(["read:chats"])
 194
 195     test "it paginates", %{conn: conn, user: user} do
 196       recipient = insert(:user)
 197
 198       Enum.each(1..30, fn _ ->
 199         {:ok, _} = CommonAPI.post_chat_message(user, recipient, "hey")
 200       end)
 201
 202       chat = Chat.get(user.id, recipient.ap_id)
 203
 204       result =
 205         conn
 206         |> get("/api/v1/pleroma/chats/#{chat.id}/messages")
 207         |> json_response_and_validate_schema(200)
 208
 209       assert length(result) == 20
 210
 211       result =
 212         conn
 213         |> get("/api/v1/pleroma/chats/#{chat.id}/messages?max_id=#{List.last(result)["id"]}")
 214         |> json_response_and_validate_schema(200)
 215
 216       assert length(result) == 10
 217     end
 218
 219     test "it returns the messages for a given chat", %{conn: conn, user: user} do
 220       other_user = insert(:user)
 221       third_user = insert(:user)
 222
 223       {:ok, _} = CommonAPI.post_chat_message(user, other_user, "hey")
 224       {:ok, _} = CommonAPI.post_chat_message(user, third_user, "hey")
 225       {:ok, _} = CommonAPI.post_chat_message(user, other_user, "how are you?")
 226       {:ok, _} = CommonAPI.post_chat_message(other_user, user, "fine, how about you?")
 227
 228       chat = Chat.get(user.id, other_user.ap_id)
 229
 230       result =
 231         conn
 232         |> get("/api/v1/pleroma/chats/#{chat.id}/messages")
 233         |> json_response_and_validate_schema(200)
 234
 235       result
 236       |> Enum.each(fn message ->
 237         assert message["chat_id"] == chat.id |> to_string()
 238       end)
 239
 240       assert length(result) == 3
 241
 242       # Trying to get the chat of a different user
 243       result =
 244         conn
 245         |> assign(:user, other_user)
 246         |> get("/api/v1/pleroma/chats/#{chat.id}/messages")
 247
 248       assert result |> json_response(404)
 249     end
 250   end
 251
 252   describe "POST /api/v1/pleroma/chats/by-account-id/:id" do
 253     setup do: oauth_access(["write:chats"])
 254
 255     test "it creates or returns a chat", %{conn: conn} do
 256       other_user = insert(:user)
 257
 258       result =
 259         conn
 260         |> post("/api/v1/pleroma/chats/by-account-id/#{other_user.id}")
 261         |> json_response_and_validate_schema(200)
 262
 263       assert result["id"]
 264     end
 265   end
 266
 267   describe "GET /api/v1/pleroma/chats/:id" do
 268     setup do: oauth_access(["read:chats"])
 269
 270     test "it returns a chat", %{conn: conn, user: user} do
 271       other_user = insert(:user)
 272
 273       {:ok, chat} = Chat.get_or_create(user.id, other_user.ap_id)
 274
 275       result =
 276         conn
 277         |> get("/api/v1/pleroma/chats/#{chat.id}")
 278         |> json_response_and_validate_schema(200)
 279
 280       assert result["id"] == to_string(chat.id)
 281     end
 282   end
 283
 284   describe "GET /api/v1/pleroma/chats" do
 285     setup do: oauth_access(["read:chats"])
 286
 287     test "it does not return chats with deleted users", %{conn: conn, user: user} do
 288       recipient = insert(:user)
 289       {:ok, _} = Chat.get_or_create(user.id, recipient.ap_id)
 290
 291       Pleroma.Repo.delete(recipient)
 292       User.invalidate_cache(recipient)
 293
 294       result =
 295         conn
 296         |> get("/api/v1/pleroma/chats")
 297         |> json_response_and_validate_schema(200)
 298
 299       assert length(result) == 0
 300     end
 301
 302     test "it does not return chats with users you blocked", %{conn: conn, user: user} do
 303       recipient = insert(:user)
 304
 305       {:ok, _} = Chat.get_or_create(user.id, recipient.ap_id)
 306
 307       result =
 308         conn
 309         |> get("/api/v1/pleroma/chats")
 310         |> json_response_and_validate_schema(200)
 311
 312       assert length(result) == 1
 313
 314       User.block(user, recipient)
 315
 316       result =
 317         conn
 318         |> get("/api/v1/pleroma/chats")
 319         |> json_response_and_validate_schema(200)
 320
 321       assert length(result) == 0
 322     end
 323
 324     test "it returns all chats", %{conn: conn, user: user} do
 325       Enum.each(1..30, fn _ ->
 326         recipient = insert(:user)
 327         {:ok, _} = Chat.get_or_create(user.id, recipient.ap_id)
 328       end)
 329
 330       result =
 331         conn
 332         |> get("/api/v1/pleroma/chats")
 333         |> json_response_and_validate_schema(200)
 334
 335       assert length(result) == 30
 336     end
 337
 338     test "it return a list of chats the current user is participating in, in descending order of updates",
 339          %{conn: conn, user: user} do
 340       har = insert(:user)
 341       jafnhar = insert(:user)
 342       tridi = insert(:user)
 343
 344       {:ok, chat_1} = Chat.get_or_create(user.id, har.ap_id)
 345       :timer.sleep(1000)
 346       {:ok, _chat_2} = Chat.get_or_create(user.id, jafnhar.ap_id)
 347       :timer.sleep(1000)
 348       {:ok, chat_3} = Chat.get_or_create(user.id, tridi.ap_id)
 349       :timer.sleep(1000)
 350
 351       # bump the second one
 352       {:ok, chat_2} = Chat.bump_or_create(user.id, jafnhar.ap_id)
 353
 354       result =
 355         conn
 356         |> get("/api/v1/pleroma/chats")
 357         |> json_response_and_validate_schema(200)
 358
 359       ids = Enum.map(result, & &1["id"])
 360
 361       assert ids == [
 362                chat_2.id |> to_string(),
 363                chat_3.id |> to_string(),
 364                chat_1.id |> to_string()
 365              ]
 366     end
 367
 368     test "it is not affected by :restrict_unauthenticated setting (issue #1973)", %{
 369       conn: conn,
 370       user: user
 371     } do
 372       clear_config([:restrict_unauthenticated, :profiles, :local], true)
 373       clear_config([:restrict_unauthenticated, :profiles, :remote], true)
 374
 375       user2 = insert(:user)
 376       user3 = insert(:user, local: false)
 377
 378       {:ok, _chat_12} = Chat.get_or_create(user.id, user2.ap_id)
 379       {:ok, _chat_13} = Chat.get_or_create(user.id, user3.ap_id)
 380
 381       result =
 382         conn
 383         |> get("/api/v1/pleroma/chats")
 384         |> json_response_and_validate_schema(200)
 385
 386       account_ids = Enum.map(result, &get_in(&1, ["account", "id"]))
 387       assert Enum.sort(account_ids) == Enum.sort([user2.id, user3.id])
 388     end
 389   end
 390 end