git.squeep.com Git - akkoma/blob - test/web/media_proxy/media_proxy_test.exs

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MediaProxyTest do
   6   use ExUnit.Case
   7   use Pleroma.Tests.Helpers
   8
   9   alias Pleroma.Config
  10   alias Pleroma.Web.Endpoint
  11   alias Pleroma.Web.MediaProxy
  12
  13   defp decode_result(encoded) do
  14     [_, "proxy", sig, base64 | _] = URI.parse(encoded).path |> String.split("/")
  15     {:ok, decoded} = MediaProxy.decode_url(sig, base64)
  16     decoded
  17   end
  18
  19   describe "when enabled" do
  20     setup do: clear_config([:media_proxy, :enabled], true)
  21
  22     test "ignores invalid url" do
  23       assert MediaProxy.url(nil) == nil
  24       assert MediaProxy.url("") == nil
  25     end
  26
  27     test "ignores relative url" do
  28       assert MediaProxy.url("/local") == "/local"
  29       assert MediaProxy.url("/") == "/"
  30     end
  31
  32     test "ignores local url" do
  33       local_url = Endpoint.url() <> "/hello"
  34       local_root = Endpoint.url()
  35       assert MediaProxy.url(local_url) == local_url
  36       assert MediaProxy.url(local_root) == local_root
  37     end
  38
  39     test "encodes and decodes URL" do
  40       url = "https://pleroma.soykaf.com/static/logo.png"
  41       encoded = MediaProxy.url(url)
  42
  43       assert String.starts_with?(
  44                encoded,
  45                Config.get([:media_proxy, :base_url], Pleroma.Web.base_url())
  46              )
  47
  48       assert String.ends_with?(encoded, "/logo.png")
  49
  50       assert decode_result(encoded) == url
  51     end
  52
  53     test "encodes and decodes URL without a path" do
  54       url = "https://pleroma.soykaf.com"
  55       encoded = MediaProxy.url(url)
  56       assert decode_result(encoded) == url
  57     end
  58
  59     test "encodes and decodes URL without an extension" do
  60       url = "https://pleroma.soykaf.com/path/"
  61       encoded = MediaProxy.url(url)
  62       assert String.ends_with?(encoded, "/path")
  63       assert decode_result(encoded) == url
  64     end
  65
  66     test "encodes and decodes URL and ignores query params for the path" do
  67       url = "https://pleroma.soykaf.com/static/logo.png?93939393939&bunny=true"
  68       encoded = MediaProxy.url(url)
  69       assert String.ends_with?(encoded, "/logo.png")
  70       assert decode_result(encoded) == url
  71     end
  72
  73     test "validates signature" do
  74       secret_key_base = Config.get([Endpoint, :secret_key_base])
  75       clear_config([Endpoint, :secret_key_base], secret_key_base)
  76
  77       encoded = MediaProxy.url("https://pleroma.social")
  78
  79       Config.put(
  80         [Endpoint, :secret_key_base],
  81         "00000000000000000000000000000000000000000000000"
  82       )
  83
  84       [_, "proxy", sig, base64 | _] = URI.parse(encoded).path |> String.split("/")
  85       assert MediaProxy.decode_url(sig, base64) == {:error, :invalid_signature}
  86     end
  87
  88     def test_verify_request_path_and_url(request_path, url, expected_result) do
  89       assert MediaProxy.verify_request_path_and_url(request_path, url) == expected_result
  90
  91       assert MediaProxy.verify_request_path_and_url(
  92                %Plug.Conn{
  93                  params: %{"filename" => Path.basename(request_path)},
  94                  request_path: request_path
  95                },
  96                url
  97              ) == expected_result
  98     end
  99
 100     test "if first arg of `verify_request_path_and_url/2` is a Plug.Conn without \"filename\" " <>
 101            "parameter, `verify_request_path_and_url/2` returns :ok " do
 102       assert MediaProxy.verify_request_path_and_url(
 103                %Plug.Conn{params: %{}, request_path: "/some/path"},
 104                "https://instance.com/file.jpg"
 105              ) == :ok
 106
 107       assert MediaProxy.verify_request_path_and_url(
 108                %Plug.Conn{params: %{}, request_path: "/path/to/file.jpg"},
 109                "https://instance.com/file.jpg"
 110              ) == :ok
 111     end
 112
 113     test "`verify_request_path_and_url/2` preserves the encoded or decoded path" do
 114       test_verify_request_path_and_url(
 115         "/Hello world.jpg",
 116         "http://pleroma.social/Hello world.jpg",
 117         :ok
 118       )
 119
 120       test_verify_request_path_and_url(
 121         "/Hello%20world.jpg",
 122         "http://pleroma.social/Hello%20world.jpg",
 123         :ok
 124       )
 125
 126       test_verify_request_path_and_url(
 127         "/my%2Flong%2Furl%2F2019%2F07%2FS.jpg",
 128         "http://pleroma.social/my%2Flong%2Furl%2F2019%2F07%2FS.jpg",
 129         :ok
 130       )
 131
 132       test_verify_request_path_and_url(
 133         "/my%2Flong%2Furl%2F2019%2F07%2FS",
 134         "http://pleroma.social/my%2Flong%2Furl%2F2019%2F07%2FS.jpg",
 135         {:wrong_filename, "my%2Flong%2Furl%2F2019%2F07%2FS.jpg"}
 136       )
 137     end
 138
 139     test "encoded url are tried to match for proxy as `conn.request_path` encodes the url" do
 140       # conn.request_path will return encoded url
 141       request_path = "/ANALYSE-DAI-_-LE-STABLECOIN-100-D%C3%89CENTRALIS%C3%89-BQ.jpg"
 142
 143       assert MediaProxy.verify_request_path_and_url(
 144                request_path,
 145                "https://mydomain.com/uploads/2019/07/ANALYSE-DAI-_-LE-STABLECOIN-100-DÉCENTRALISÉ-BQ.jpg"
 146              ) == :ok
 147     end
 148
 149     test "uses the configured base_url" do
 150       clear_config([:media_proxy, :base_url], "https://cache.pleroma.social")
 151
 152       url = "https://pleroma.soykaf.com/static/logo.png"
 153       encoded = MediaProxy.url(url)
 154
 155       assert String.starts_with?(encoded, Config.get([:media_proxy, :base_url]))
 156     end
 157
 158     # Some sites expect ASCII encoded characters in the URL to be preserved even if
 159     # unnecessary.
 160     # Issues: https://git.pleroma.social/pleroma/pleroma/issues/580
 161     #         https://git.pleroma.social/pleroma/pleroma/issues/1055
 162     test "preserve ASCII encoding" do
 163       url =
 164         "https://pleroma.com/%20/%21/%22/%23/%24/%25/%26/%27/%28/%29/%2A/%2B/%2C/%2D/%2E/%2F/%30/%31/%32/%33/%34/%35/%36/%37/%38/%39/%3A/%3B/%3C/%3D/%3E/%3F/%40/%41/%42/%43/%44/%45/%46/%47/%48/%49/%4A/%4B/%4C/%4D/%4E/%4F/%50/%51/%52/%53/%54/%55/%56/%57/%58/%59/%5A/%5B/%5C/%5D/%5E/%5F/%60/%61/%62/%63/%64/%65/%66/%67/%68/%69/%6A/%6B/%6C/%6D/%6E/%6F/%70/%71/%72/%73/%74/%75/%76/%77/%78/%79/%7A/%7B/%7C/%7D/%7E/%7F/%80/%81/%82/%83/%84/%85/%86/%87/%88/%89/%8A/%8B/%8C/%8D/%8E/%8F/%90/%91/%92/%93/%94/%95/%96/%97/%98/%99/%9A/%9B/%9C/%9D/%9E/%9F/%C2%A0/%A1/%A2/%A3/%A4/%A5/%A6/%A7/%A8/%A9/%AA/%AB/%AC/%C2%AD/%AE/%AF/%B0/%B1/%B2/%B3/%B4/%B5/%B6/%B7/%B8/%B9/%BA/%BB/%BC/%BD/%BE/%BF/%C0/%C1/%C2/%C3/%C4/%C5/%C6/%C7/%C8/%C9/%CA/%CB/%CC/%CD/%CE/%CF/%D0/%D1/%D2/%D3/%D4/%D5/%D6/%D7/%D8/%D9/%DA/%DB/%DC/%DD/%DE/%DF/%E0/%E1/%E2/%E3/%E4/%E5/%E6/%E7/%E8/%E9/%EA/%EB/%EC/%ED/%EE/%EF/%F0/%F1/%F2/%F3/%F4/%F5/%F6/%F7/%F8/%F9/%FA/%FB/%FC/%FD/%FE/%FF"
 165
 166       encoded = MediaProxy.url(url)
 167       assert decode_result(encoded) == url
 168     end
 169
 170     # This includes unsafe/reserved characters which are not interpreted as part of the URL
 171     # and would otherwise have to be ASCII encoded. It is our role to ensure the proxied URL
 172     # is unmodified, so we are testing these characters anyway.
 173     test "preserve non-unicode characters per RFC3986" do
 174       url =
 175         "https://pleroma.com/ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz1234567890-._~:/?#[]@!$&'()*+,;=|^`{}"
 176
 177       encoded = MediaProxy.url(url)
 178       assert decode_result(encoded) == url
 179     end
 180
 181     test "preserve unicode characters" do
 182       url = "https://ko.wikipedia.org/wiki/위키백과:대문"
 183
 184       encoded = MediaProxy.url(url)
 185       assert decode_result(encoded) == url
 186     end
 187   end
 188
 189   describe "when disabled" do
 190     setup do: clear_config([:media_proxy, :enabled], false)
 191
 192     test "does not encode remote urls" do
 193       assert MediaProxy.url("https://google.fr") == "https://google.fr"
 194     end
 195   end
 196
 197   describe "whitelist" do
 198     setup do: clear_config([:media_proxy, :enabled], true)
 199
 200     test "mediaproxy whitelist" do
 201       clear_config([:media_proxy, :whitelist], ["google.com", "feld.me"])
 202       url = "https://feld.me/foo.png"
 203
 204       unencoded = MediaProxy.url(url)
 205       assert unencoded == url
 206     end
 207
 208     test "does not change whitelisted urls" do
 209       clear_config([:media_proxy, :whitelist], ["mycdn.akamai.com"])
 210       clear_config([:media_proxy, :base_url], "https://cache.pleroma.social")
 211
 212       media_url = "https://mycdn.akamai.com"
 213
 214       url = "#{media_url}/static/logo.png"
 215       encoded = MediaProxy.url(url)
 216
 217       assert String.starts_with?(encoded, media_url)
 218     end
 219
 220     test "ensure Pleroma.Upload base_url is always whitelisted" do
 221       media_url = "https://media.pleroma.social"
 222       clear_config([Pleroma.Upload, :base_url], media_url)
 223
 224       url = "#{media_url}/static/logo.png"
 225       encoded = MediaProxy.url(url)
 226
 227       assert String.starts_with?(encoded, media_url)
 228     end
 229   end
 230 end